Some possibilities

Doug Meade — Tue, 03 Jun 2008 17:17:01 Z

Your question is not very detailed, so I have to make some assumptions about what you are trying to do. At the simplest level, I would suggest doing something like the following:

eq_C := y=x^2;
                                        2
                                   y = x 
eq_P := [x=t,eval(eq_C,x=t)];
                               [            2]
                               [x = t, y = t ]

If your cartesian form does not explicitly define y in terms of x, then you might have more success with something like:

eq_C := y=x^2+y^2;
                                      2    2
                                 y = x  + y 
eq_P := [x=t,isolate(eval(eq_C,x=t),y)];
                     [                           (1/2)]
                     [           1   1 /       2\     ]
                     [x = t, y = - - - \1 - 4 t /     ]
                     [           2   2                ]

Of course, in some situations choosing to make x the parameter is not the most efficient. I doubt Maple can reliably predict the "best" choice of parameter (because I doubt there is always a "best" choice). If you want to make y the parameter, then the second example becomes:

eq_P2 := [isolate(eval(eq_C,y=t),x),y=t];
                      [          /  2        2\       ]
                      [x = RootOf\_Z  - t + t /, y = t]
allvalues( % );
           [            (1/2)       ]  [             (1/2)       ]
           [    /     2\            ]  [     /     2\            ]
           [x = \t - t /     , y = t], [x = -\t - t /     , y = t]

For a different choice of paramter, the following could be of use:

q := x+y=t;
                                  x + y = t
Q := algsubs(x+y=t,eq_C);
                                   2            2
                            y = 2 y  - 2 t y + t 
Y := isolate( Q, y );
                                                    (1/2)
                        1   1     1 /             2\     
                    y = - + - t - - \1 + 4 t - 4 t /     
                        4   2     4                      
eq_P3 := [eval(isolate(q,x),y=Y),Y];
             [        /                                (1/2)\  
             [        |    1   1     1 /             2\     |  
             [x = t - |y = - + - t - - \1 + 4 t - 4 t /     |, 
             [        \    4   2     4                      /  

                                               (1/2)]
                   1   1     1 /             2\     ]
               y = - + - t - - \1 + 4 t - 4 t /     ]
                   4   2     4                      ]

Are any of these close to what you need?

Doug

---------------------------------------------------------------------
Douglas B. Meade  <><
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu       
Phone:  (803) 777-6183         URL:    http://www.math.sc.ed

thats all i want !!..one small thing..

mikewinifred — Tue, 03 Jun 2008 19:46:27 Z

thank you prof...it helped me a great deal..infact im exactly expecting the same...one small question..

in eq_p2 what is that RootOf(_Z.........)..this is the second time im askin abt this..the other day someone told its kind of variable to represent root....but why maple dont directly give out the roots?....what is the catch in using tht statement?...and actually what it mean !!!

thanks

Parametrization

Robert Israel — Tue, 03 Jun 2008 20:48:30 Z

This might be more sophisticated than what you want, but there is a procedure parametrization in the algcurves package that will provide a rational parametrization of an algebraic curve when that exists. For example:

> eq_C := y=x^2+y^2;
  algcurves[parametrization](lhs(eq_C)-rhs(eq_C), x, y, t);

[(-1+t^2)/(2+2*t^2), (1-2*t+t^2)/(2+2*t^2)]

The <maple> tag is acting up again: that should be

[(-1+t^2)/(2+2*t^2), (1-2*t+t^2)/(2+2*t^2)]

In other words, the curve can be parametrized as x = (-1+t^2)/(2+2*t^2),
y = (1-2*t+t^2)/(2+2*t^2) (except for the point [1/2, 1/2] which is the limit as t -> infinity).

MaplePrimes - answers and comments on Question, cartesian eqns to parametric eqns

Some possibilities

thats all i want !!..one small thing..

Parametrization