MaplePrimes - answers and comments on Question, Determining an Equation's Accuracy

idea

acer — Sun, 27 Jan 2008 11:33:41 Z

It sounds to me as if you would like to compute the residuals and the sum of squares of the residuals, given a forced least-squares function (model). You could of course compute the sums of squares of the residuals easily in Maple. Simply evaluate the model at each X value, and square the difference with the Y value, and add those up. That's probably one or two lines of Maple code. But you asked whether the Statistics routines could be used for the purpose, in a canned way. You could specify a parameter that doesn't actually appear in your candidate model equation. And then use the solutionmodule output to get the extra details. Here's an example, based on one from the ?Statistics,Fit help-page. Notice that the variable `dummy` doesn't appear in the model, which is the basis of the trick. The model equation is thus fully supplied by the user, with no parameters to actually be estimated (except some incidental estimation of the dummy, which is of no consequence).

> X := Vector([1, 2, 3, 4, 5, 6], datatype=float):
> Y := Vector([2, 3, 4.8, 10.2, 15.6, 30.9], datatype=float):
> Digits:=trunc(evalhf(Digits)):

> # Here is the forced model.

> eq:=0.887576142919275224+0.606352318207692531*exp(0.649251558313310717*t):

> # Here are the simple commands to get the results,
> # without using Statistics.

> add( (eval(eq,t=X[i])-Y[i])^2, i=1..op(1,X) );

                               2.29446465108687
 
> seq( (eval(eq,t=X[i])-Y[i]), i=1..op(1,X) );

0.04819978094862, 0.10913477921538, 0.33987862305974, -1.17305895930964,
 
    0.8671971243695, -0.1913514547231

> # And here is Statistics:-Fit computing those results.

> sol := Statistics:-Fit( eq, X, Y, t, parameternames=[dummy], output=solutionmodule):

> sol:-Results(["residualsumofsquares","residuals"]);

2.29446465108658, [0.0481997809486180984, 0.109134779215386946,
 
    0.339878623059754581, -1.17305895930959636, 0.867197124369345929,
 
    -0.191351454723299952]

acer

residual mean square

DJKeenan — Sun, 27 Jan 2008 18:29:28 Z

I suggest using the residual sum of squares or the residual mean square. Further to acer's comment, the Statistics package has options to return these directly. For example, if the function that you are fitting is a+b*t+c*t^2, then try

Statistics:-LinearFit([1,t,t^2], X, Y, t, output = 'residualmeansquare');

For more information, see the Options section in ?LinearFit.

Question

Evan — Sun, 27 Jan 2008 11:59:05 Z

Thank you so much for your help and time. I tried it and it worked. However, I don't quite understand everything that is going on here. As a matter of fact, I don't really understand anything that is going on here. I am only a high school student and have not taken Statistics. What does everything mean, and what is relevant for me to look at? All I know (or think I know) is that the closer an r^2 value is to one, the closer the equation is to fitting the points. Could you enlighten me? Thank you for all your help already, and sorry for my ignorance. Also, on a related but different topic, is it possible to define the X and Y values in one fell swoop? For example, I have them in a 8X2 Matrix, would it be possible to define X as one column of this Matrix and Y as another, instead of having to break up the Matrix into an X Vector and a Y Vector, as I am doing now?

coefficient of determination

acer — Sun, 27 Jan 2008 12:57:49 Z

So, you may be interested in the so-called "coefficient of determination", or R^2. See this link for details and explanations. What I showed before is the residual sum of squares, which that page describes as its SS_err term. That pages also gives some formulae for R^2. Perhaps you would like to use the formula which computes R^2 via regression sum of squares. If your X and Y data lie in the first and second columns of Matrix M, then in your code you can access the entries as M[i,1] instead of X[i] and M[i,2] instead of Y[i]. That saves your having to form the X and Y Vectors explicitly. acer

Is there any way to compute

Evan — Sun, 27 Jan 2008 23:59:57 Z

Is there any way to compute the R^2 value directly in maple? Or have it give me the SStot so I can calculate the R^2 value myself? If not, what would be the syntax to calculate the SStot using my values from a Matrix?

Maple implementation for R^2

acer — Tue, 29 Jan 2008 02:52:07 Z

The procedure Rsquared below could allow you to compute R^2 for data appearing in the first and second columns of a Matrix and for a given fitting formula in variable t.

Rsquared := proc( formula, T::symbol,  m::Matrix )
local N, ybar, SS_err, SS_tot, SS_reg;
  Digits:=trunc(evalhf(Digits));
  N := op([1,1],m);
  ybar := add( m[i,2], i=1..N )/N;
  SS_tot := add( ( m[i,2] - ybar )^2, i=1..N );
  SS_reg := add( ( eval(formula,T=m[i,1]) - ybar )^2, i=1..N );
  SS_err := add( ( m[i,2] - eval(formula,T=m[i,1]) )^2, i=1..N );
  return 1-SS_err/SS_tot;
end proc:

M := Matrix(6,2, [[1,2],[2,3],[3,4.8],[5,10.2],[6,30.9]] );

form := 0.888 + 0.606*exp(0.649*t);

Rsquared( form, t, M );

You could fix it up to do proper argument checking and validation. Comments could be added to the code. Or you could just examine it and compare to the formulas on that web-page, and try and figure out a bit more of how the Maple programming language works. acer