MaplePrimes - answers and comments on Question, Extract the argument of a trig function

selectfun

djc — Mon, 24 Sep 2007 14:58:26 Z

If y is your expression: var:=op(op(selectfun(y,arctan)));

patmatch

Doug Meade — Mon, 24 Sep 2007 16:47:40 Z

Here's an approach to this problem that does not use any op's.

restart;
y := A+B*arctan(x);
                            y := A + B arctan(x)
patmatch( y, a::anything+b::anything*arctan(x), 's' );
                                    true
s;
                               [b = B, a = A]
assign( s );
a,b;
                                    A, B
unassign( 'a', 'b' );
a,b;
                                    a, b
y2 := (x^2+3)+sin(x)*cos(x)*arctan(x);
                          2                              
                    y2 = x  + 3 + sin(x) cos(x) arctan(x)
patmatch( y2, a::anything+b::anything*arctan(x), 's' );
                                    true
s;
                       [                            2]
                       [b = sin(x) cos(x), a = 3 + x ]
assign( s );
a,b;
                                 2               
                            3 + x , sin(x) cos(x)

Note that if you do assign values to the names used in the patmatch command then you will need to unassign them before they can be used in another patmatch. You can get much fancier with the arguments to patmatch, if you so choose. See the online help for complete details. Does this fit your needs? Doug

---------------------------------------------------------------------
Douglas B. Meade
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu       
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu/~meade/

no op

brian abraham — Mon, 24 Sep 2007 18:47:32 Z

Thank you djc and Doug. I can not quite see how patmatch extracts x from A+B*arctan(x) where x is any expression. Am I missing something? My original interest in this came from a wish to express arctan(A/B) as arctan(A,B) where A and B are any expressions. I should have asked that specfically.

not well defined

Doug Meade — Mon, 24 Sep 2007 20:50:48 Z

Brian, First, let me apologize for misreading your original message. The question as you have refined it does not have a unique solution. What should be returned for arctan( -1 )? Do you want arctan( -1, 1 ) or arctan( 1, -1 )? Even positive arguments cause problems: arctan( 1 ) = arctan( 1, 1 ) and arctan( 1 ) = arctan( -1, -1 ). What do you know about the arguments to arctan? Are they always numeric? Are they always a fraction? Depending on your answers to the above, it's still possible to use patmatch to come close to what you are describing.

> y := arctan(11,15);
                                         /11\
                              y := arctan|--|
                                         \15/
> patmatch( y, arctan(AB::rational), 's' );
                                    true
> s;
                                  [     11]
                                  [AB = --]
                                  [     15]
> [numer,denom]( eval( AB, s ) )[];
                                   11, 15
> arctan( [numer,denom]( eval( AB, s ) )[] );
                                       /11\
                                 arctan|--|
                                       \15/

> 'arctan'( [numer,denom]( eval( AB, s ) )[] );
                               arctan(11, 15)

Unfortunately, Maple will automatically convert the two argument arctan to a one argument arctan. The above works only when the argument to arctan is a numerical fraction. This idea could be modified for arguments of a different form. I hope this gives you some (useful) ideas. Doug

---------------------------------------------------------------------
Douglas B. Meade
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu       
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu/~meade/

simpler extraction with typematch

JacquesC — Mon, 24 Sep 2007 21:25:58 Z

patmatch can be quite flaky, indets and typematch are safer. Just for robustness, I would use

extract := proc(expr)
    local atans;
    atans := convert(indets(expr, 'arctan(anything)'), list);
    map2(op, 1, atans);
end proc;

This uses op, and that is what most Maplers would do. Now, without op:

extract := proc(expr)
    local atans;
    atans := convert(indets(expr, 'arctan(anything)'), list);
    map(proc(aa) local arg; typematch(aa, 'arctan'(arg::anything)); arg; end, atans);
end proc;

My actual expression

brian abraham — Tue, 25 Sep 2007 23:35:14 Z

Thank you as always, most informative. My actual expression was of the form A arctan(B/C) where A = -1 or 1, and B and C are variables and not functions. I am glad I did not make that clear at the start; I might have missed some of the discussion!