MaplePrimes - answers and comments on Question, Kronecker/Tensor Products

Kronecker / tensor products

bfauser — Tue, 21 Nov 2006 07:52:03 Z

Hi, what kind of objects do you like to tensor? A rather general way to produce variouse tensor products (though only tested in a particular realm) come with the Clifford/Bigebra packages, see http://www.math.tntech.edu/rafal/ If you just need a tensor product for matrices, that ships with maple, see the linalg (or newer Matrix) packages. In principle maple should provide via the 'define' mechanism a way to produce a multilinear operator (aka tensor product) However, till now maples ability in this direction is very limited, since you canne e.g. specify over which domain (base field) your tensor product is linear. Using the define which ships with Clifford/Bigebra you can e.g. define a tenor product linear over polynomails in x with integer coefficients etc. If you are interested in characters of the general linear groups (Schur functions) I can mail you a package which does that (see the old version at http://clifford.physik.uni-konstanz.de/~fauser/) I hope to finish the new version (over 50 procedures) by end of teh jear and post it on the web page of Rafal Ablamowicz (see link above) ciao BF.

simple matrix tensor product with linalg in maple 9?

cottrell — Sun, 03 Dec 2006 22:41:35 Z

uh, you didn't really answer the question. using linalg, define two matrices using "matrix". How do you take the tensor product of these in maple 9? I've looked online and through help but am not finding it as quick as I should be as usual. Maybe Maple 10 is better.

Matrix tensor product

alec — Mon, 04 Dec 2006 11:10:26 Z

For Vectors and Matrices (but not for Arrays), the tensor product can be defined as

TensorProduct:=module()
export `*`;
option package;
`*`:=overload([proc(A::rtable,B::rtable) option overload; 
rtable(<seq(seq(`*`(A[i,[rtable_dims(A)][2..-1][]],
B[j,[rtable_dims(B)][2..-1][]]),
j=[rtable_dims(B)][1]),i=[rtable_dims(A)][1])>, 
select(has,{rtable_options(A)} intersect {rtable_options(B)},
{datatype,subtype,order,rectangular,sparse})[]) end,
:-`*`]) end:

with(TensorProduct):

For example,

A:=<<1 | 2> , <3 | 4>>;
                            Matrix([[1,2],[3,4]])
     
B:=<<1 | 2 | 3> , <4 | 5 | 6> , <7 | 8 | 9>>;

                         Matrix([[1, 2, 3], [4, 5, 6], [7, 8, 9]])

A*B;

                 Matrix([[1, 2, 3, 2, 4, 6], [4, 5, 6, 8, 10, 12], [7, 8, 9, 14, 16, 18], [3, 6, 9, 4, 8, 12], [12, 15, 18, 16, 20, 24], [21, 24, 27, 28, 32, 36]])

I didn't test it with all possible options, and it might give wrong results for some of them, but it seems to work OK with dense matrices with rectangular storage. If there is a need of using other options, the procedure should be correspondingly adjusted. In particular, it is not optimized for sparse matrices (but neither do many other procedures in LinearAlgebra package). __________ Alec Mihailovs http://mihailovs.com/Alec/

Kronecker Product

boirac — Wed, 20 Dec 2006 21:57:57 Z

Inspired on one Alain Le Stang wrote, I wrote a little procedure that makes the Kronecker/Direct/Tensor product between any two matrices. As long as it is declared as a Matrix, it can also make the Kronecker product between Vectors and Matrices. The vector, however would have to be declared for example as V := Matrix([[1],[2], [0], [a]]); it uses the package LinearAlgebra,


Kron:=proc(A::Matrix,B::Matrix)
local M,P,i,j;
M:=Matrix(RowDimension(A)*RowDimension(B),ColumnDimension(A)*ColumnDimension(B)):
P:=Matrix(RowDimension(B),ColumnDimension(B)):
for i to RowDimension(A) do
for j to ColumnDimension(A) do
P:=ScalarMultiply(B,A[i,j]):
M[1+(i-1)*RowDimension(B)..(i-1)*RowDimension(B)+RowDimension(B),1+(j-1)*ColumnDimension(B)..(j-1)*ColumnDimension(B)+ColumnDimension(B)]:=P:
od
od:
M;
end proc:


for example

A := Matrix([[1, 0], [2, 1]]);

and

B := Matrix([[a, b], [c, d]]);

returns for 

Kron(A, B);


 Matrix(4, 4, {(1, 1) = a, (1, 2) = b, (1, 3) = 0, (1, 4) = 0, (2, 1) = c, (2, 2) = d, (2, 3) = 0, (2, 4) = 0, (3, 1) = 2*a, (3, 2) = 2*b, (3, 3) = a, (3, 4) = b, (4, 1) = 2*c, (4, 2) = 2*d, (4, 3) = c, (4, 4) = d});



Faster version of Kronecker product
JacquesC — Wed, 20 Dec 2006 23:27:47 Z
This code which I believe is more idiomatic is asymptotically faster:

Kron := proc(A::Matrix, B::Matrix)
    local rA, cA, rB, cB;
    (rA, cA) := LinearAlgebra:-Dimensions(A);
    (rB, cB) := LinearAlgebra:-Dimensions(B);
    Matrix(rA*rB, cA*cB, proc(i,j) local iA,jA,iB,jB;
        iB := irem(i-1,rA,'iA');
        jB := irem(j-1,cA,'jA');
        A[iA+1,jA+1]*B[iB+1,jB+1] end);
end;


It is too bad that one has to play indexing games (irem is 0-based, Matrix is 1-based) as it obscures the result.  Also I really wish there was a side-effect free version of commands like irem!


More versatile
Mariner — Thu, 21 Dec 2006 00:38:07 Z
Jacques,

May I suggest that kronprod in Robert Israel's Maple Advisor Database is more versatile - it handles matrices, Matrices, vectors and Vectors. Moreover matrices need not be square and it seems to be very nearly as fast as your code.

J. Tarr