MaplePrimes - answers and comments on Question, help migrating old maple code with "stats" commands

empirical

Robert Israel — Tue, 29 Jun 2010 07:11:11 Z

If L is a list of n elements with all L[j] >= 0 and sum(L[j], j=1..n) = 1, empirical[L] is a discrete distribution with
Probability(X = j) = L[j] for j in [1,2,...,n], 0 otherwise. The equivalent in Statistics is ProbabilityTable (not Empirical). What this Maple code is doing is simulating a Markov chain with transition matrix P and states labelled S,C,R. I might implement it in a more modern Maple (and in a somewhat more efficient way) like this:


with(Statistics):
P1:= [[.6,.3,.1],[.4,.5,.1],[.3,.4,.3]]:
X:= [seq(Sample(ProbabilityTable(P1[i]),51),i=1..3)]:
R:= Array(1..51):
R[1]:= 1:
for j from 2 to 51 do R[j]:= X[R[j-1]][j] end do: 
S:= cat(op(convert(subs(1="S",2="C",3="R",R),list)));

Thanks!

pvrbik — Tue, 29 Jun 2010 15:59:52 Z

Thanks Robert,

That's exactly what I needed to know.

It's for the undergrads though; so I may put the for loop back in (although your version is definitely more efficient). In this case exposition is more important than speed.

Thanks again,

Paul

exposition

Robert Israel — Tue, 29 Jun 2010 22:18:16 Z

@pvrbik : I agree, exposition is important, but one aspect of good Maple exposition is to avoid "anti-patterns" such as building up a string one character at a time.

@Robert Israel Completely agree. However,

pvrbik — Tue, 29 Jun 2010 23:16:59 Z

@Robert Israel

Completely agree. However, this is a stochastic process course (for non-programmers and non-mathematicians) and most of the students will only be able to use maple as a "symbolic calculator". We're trying to be very verbose with our code so they know exactly what happens. Although I think functional (or semi-functional in the case of maple) is more elegant; it is notoriously difficult to decipher.

I did something like this instead:

interface(quiet=true):
with(Statistics):
states := [ "S", "C", "R" ]:

#The probability distributions from transitioning OUT of a state

dist["S"] := ProbabilityTable([0.6, 0.3, 0.1]):

dist["C"] := ProbabilityTable([0.4, 0.5, 0.1]):

dist["R"] := ProbabilityTable([0.3, 0.4, 0.3]):

TransitionFrom := state -> states[ Sample( dist[state], 1)[1] ];

#starting from the 'sunny' state is arbritrary

TodaysWeather := "S";

WeatherHistory := NULL;

for i from 1 to 50 do

    NextWeather := TransitionFrom( TodaysWeather );

    WeatherHistory := WeatherHistory, NextWeather;

    TodaysWeather := NextWeather;

end do:

cat(WeatherHistory);

As a side note. I'm having a lot of difficulty posting code into these windows. It doesn't format properly, and everything seems to want to double space. Advise?

@pvrbik There is noting particularly more

John May — Wed, 30 Jun 2010 20:03:44 Z

@pvrbik There is noting particularly more intuitive about using an exprseq or list instead of an Array or Table.

WeatherHistory := Array(1..50); # or table();

for i from 1 to 50 do    
    NextWeather := TransitionFrom( TodaysWeather );    
    WeatherHistory[i] := NextWeather;   
    TodaysWeather := NextWeather;
end do:

cat(entries(WeatherHistory, 'nolist'));

This is, arguably, even easier to read and has the bonus of not teaching students very bad habits in Maple.

@John May I'm inclined to

pvrbik — Wed, 30 Jun 2010 20:55:26 Z

@John May

I'm inclined to agree with you John.