MaplePrimes - answers and comments on Question, Custom lib can't call other libs

don't use `with` for this

pagan — Sun, 12 Sep 2010 19:11:17 Z

Using with(MyLib) as a way to resolve the name `h` as used inside the already authored or loaded package AnotherPackage is bad form (and this is an example of why). Also, it really matters which version (global, or export of MyLib) of the name `h` is bound when AnotherPackage is defined and saved,

I suggest that you write AnotherPackage using the syntax MyLib:-h() inside the code of AnotherPackage, whenever you need to call export `h` of MyLib.

If done that way, properly, you shouldn't even have to with(MyLib) in order to `with` or use AnotherPackage. You'd just have to make sure that MyLib is accessible in the libname path whenever you used AnotherPackage.

You might also utilize `use`, but there are some caveats abour which form works I think (and `uses` might not be ok at all).

Doesn't work

hanswurst — Sun, 12 Sep 2010 20:57:39 Z

I'm not sure, I understood correctly: So you suggest I replace each occurance of h() inside the code of f1 of the package MyLib with "AnotherPackage:-h()"? I think this is the same as I've done via "AnotherPackage[h]".

I tried it that way and it didn't work either.

Maybe I should clarify:

There are 2 Packages: MyLib and AnotherPackage.
Mylib contains a function f1 which calls AnotherPackage[h]
I try to run everything via "with(MyLib);" and "with(AnotherPackage)" (while the latter might be unnecessary as pointed out by pagan).

code

pagan — Mon, 13 Sep 2010 04:43:47 Z

It's not clear (yet) whether you intend to create AnotherPackage before or after you create MyLib, and whether you intend on savelib'ing AnotherPackage so as to access it in a new session or recreate it on the fly. Is this code sample below enough to get you going?

Notice that I never issue the command with(AnotherPackage).

> restart;  
> try
>  FileTools:-Remove("c:/tmp/MyLib.lib"):
>  FileTools:-Remove("c:/tmp/MyLib.ind"):
> catch:
> end try:
> march('create', "c:/tmp/MyLib.lib"):

> MyLib:= module()
> export f1;
> local g1, g2; 
> option package;
>  f1 := proc(x)
>         AnotherPackage:-h(x);
>        end proc: 
> end module:

> savelibname:="c:/tmp":
> savelib( `MyLib` );

> AnotherPackage := module()
> export h;
>  h := proc(x)
>        x^2+sin(x);
>       end proc:
> end module:

>MyLib:-f1(z);
                           2         
                          z  + sin(z)

>restart:

>libname:=libname,"c:/tmp":
> MyLib:-f1(z); # expect an error here
Error, (in MyLib:-f1) `AnotherPackage` does not evaluate to a module

> AnotherPackage := module()
>  export h;
>  h := proc(x)
>        x^2+sin(x);
>       end proc:
> end module:

> MyLib:-f1(z);
                           2         
                          z  + sin(z)

> savelibname:="c:/tmp":
> savelib( `AnotherPackage` );

> restart:
> libname:=libname,"c:/tmp":
> MyLib:-f1(z);
                           2         
                          z  + sin(z)