MaplePrimes - answers and comments on Question, Plotting Gaussian Primes Connected by Steps k

Book by André Heck

gkokovidis — Sun, 31 Oct 2010 20:25:43 Z

See page 465 of Introduction to Maple By André Heck.

Regards,

Georgios Kokovidis

Dräger Medical

One way

Alec Mihailovs — Sun, 31 Oct 2010 20:48:03 Z

One way of doing that is

f:=proc(r,k)
local primes;
uses GaussInt, plots;
primes:=(c,rad)->select(x->GInorm(x-c)<=rad^2,
    select(GIprime,[seq(seq(c+i+I*j,j=-ceil(rad)..ceil(rad)),i=-ceil(rad)..ceil(rad))]));
print(display(plottools:-circle([0,0],r,thickness=3, color=blue),map(complexplot,
    [seq(seq([i,j],j in primes(i,k)), i in primes(0,r-k))]),axes=none))
end;

It is not very fast. For example, f(100,2) took more than 1 minute.

f(10,2);

f(100,2);

f(100,sqrt(8.));

_______________
Alec Mihailovs, PhD
Maplesoft Member

Another way

Robert Israel — Sun, 31 Oct 2010 23:49:47 Z

Here's my try:

> nb:= proc(r) local i,j,nb1; nb1:={seq(seq(i+I*j,j=0..floor(sqrt(r^2-i^2))),i=0..r)};
 map(t -> (t,I*t,-t,-I*t),nb1 minus {0}) end proc;;
   myF:= proc(R,r) 
      local G, nbd, E;
      G:= map(g -> (g,I*g,-g,-I*g),
              select(GaussInt[GIprime],{seq(seq(x+I*y,y=0 .. floor(sqrt(R^2 - x^2))),x=0..R)}));
      nbd:= nb(r);
      E:= `union`(seq(map(t -> [[Re(g),Im(g)],[Re(t),Im(t)]],select(member,map(t -> t+ g,nbd),G)),g=G));
      plots[display](PLOT(CURVES(op(E),COLOUR(RGB,1,0,0))),plottools[circle]([0,0],R,colour=blue),axes=none);
   end proc;

myF(100, 3);

Connected component

Robert Israel — Mon, 01 Nov 2010 00:52:26 Z

And here's a version of the procedure that plots the connected component containing 1+i in black.

nb:= proc(r) local i,j,nb1; nb1:={seq(seq(i+I*j,j=0..floor(sqrt(r^2-i^2))),i=0..r)};
  map(t -> (t,I*t,-t,-I*t),nb1 minus {0}) end proc;;
    myF:= proc(R,r)
       uses GraphTheory;
       local nbd,G,E,Gs,Es,CC1, G1, E1, E2, Gr, CC;
       G:= map(g -> (g,I*g,-g,-I*g),
               select(GaussInt[GIprime],{seq(seq(x+I*y,y=0 .. floor(sqrt(R^2 - x^2))),x=0..R)}));
       nbd:= nb(r);
       Gs:= convert(map(convert,G,string),list);
       E:= `union`(seq(map(t -> {g,t},select(member,map(t -> t+ g,nbd),G)),g=G));
       Es:= map(e -> map(convert,e,string), E);
       Gr:= Graph(Gs,Es);
       CC:= ConnectedComponents(Gr);
       G1:= map(parse,op(select(has,CC,"1+I")));
       E1,E2:= selectremove(e -> member(e[1],G1),E);
       E1:= map(e -> [[Re(e[1]),Im(e[1])],[Re(e[2]),Im(e[2])]], E1);
       E2:= map(e -> [[Re(e[1]),Im(e[1])],[Re(e[2]),Im(e[2])]], E2);
       plots[display](PLOT(CURVES(op(E1),COLOUR(RGB,0,0,0))),
                      PLOT(CURVES(op(E2),COLOUR(RGB,1,0,0))),
 plottools[circle]([0,0],R,colour=blue),axes=none);
    end proc;

> myF(100,3);