Home › Forums › General Discussion › Maple Commons general technical discussions

A hypergeom challenge

edgar's picture
Posted on 2008-08-24 15:16 By edgar (Maple Rating 2 176)
Categories:
W := (81/539)*42^(1/2)*hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], -1/6): evalf(W,50); 0.99999999999999999999999999999999999999999999999996 Show W is 1
‹ Funny behavior with int Eval help page ›
JacquesC's picture

Very tough

Comment on 2008-08-25 10:00 from JacquesC (Maple Rating 4 1697)

My attempts to crack this have not worked, but perhaps some of my ideas might be useful to someone else.

My favourite tactic is to transform such problems into DE problems, so

K := (81/539)*42^(1/2)*hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], -x/6):
de := collect(numer((lhs-rhs)(op([1,1],PDEtools[dpolyform](y(x)=K,no_Fn)))),diff,factor);

-507*y(x)+(3334*x+18468)*diff(y(x),x)+32*x*(211*x+1134)*diff(diff(y(x),x),x)+1408*x^2*(6+x)*diff(diff(diff(y(x),x),x),x)

3rd order, as expected (but the stupid display of the <maple> tag is annoying here). The coefficients are not too nasty, and nicely the sqrt(42) has magically disappeared. Taking a look at the solution:

ans := rhs(dsolve(de));

_C1/x^(11/8)*(-1+x)+_C2*Int((6+x)^(1/2)*(-81+25*x)*x^(3/8)/(-1+x)^2,x)*(-1+x)/x^(11/8)+_C3*Int(Int(1/x^(81/88)*(-1+x)/(-81+25*x)^2/(6+x)^(3/2),x)*(6+x)^(1/2)*(-81+25*x)*x^(3/8)/(-1+x)^2,x)*(-1+x)/x^(11/8)

[Again, the output in Classic is much nicer than here]  Where does this come from? Well, the DE, as an operator, factors:

> DEtools[DFactor](DEtools[de2diffop](de,y(x),[Dx,x]),[Dx,x]);

                                      2
          2         3       48 (2875 x  + 5911 x - 27378) x
  [(8448 x  + 1408 x ) Dx + -------------------------------,
                                      -81 + 25 x

                             2       3
               -1863 x + 82 x  + 25 x  + 972          -11 + 3 x
        Dx + ---------------------------------, Dx + ------------]
             2 x (-1 + x) (6 + x) (-81 + 25 x)       8 x (-1 + x)

Trying to figure out the values of the constants _C1, _C2 and _C3 turns out to be very hard since all 3 terms are singular at 0, so one would have to find out how to 'match' those singularities, which I have not been able to do. However, it might be useful to know that the problem is "reduced" to one involving algebraic integrals.

I have not tried to use any of the contiguity relations or quadratic transformations formulas for the 3F2 to see if somehow that can cause some of the arguments to 'collapse' and thereby simplify the problem. It's too bad that Maple does not have a 'transformations' package with these formulas as transformations one can apply.

Axel Vogt's picture

thought similar

Comment on 2008-08-25 10:22 from Axel Vogt (Maple Rating 4 948)

and run into the 3rd oder DE (without splitting), it would not help to provide initial conditions here, but have not tried in points different from 0

BTW the task seems to stem from the problems seen in www.mapleprimes.com/forum/thomascalculus5615exercisegetshypergeom
where it was unclear how to simplify the 2F1

oh

Comment on 2008-08-25 10:26 from pagan (Maple Rating 2 99)

When seeing Edgar's challenge problem, my first thought was convert(W,Int) and to try working from there.

Axel Vogt's picture

has not worked for me

Comment on 2008-08-25 10:30 from Axel Vogt (Maple Rating 4 948)

has not worked for me, got just a double integral, it should stand for 3F2 =Int(2F1) = Int(Int(...)) using Euler's integral I guess ... and similar for trying sums :-(

guess

Comment on 2008-08-25 10:35 from pagan (Maple Rating 2 99)

My guess was that, somehow, the inner integrand might be the simplified result of adding two terms (perhaps each of which would then work in `int`, while the sum might not). I guessed this on the weak grounds that I thought that I saw hints in Edgar's posts in the other thread that you cited.

edgar's picture

where it comes from

Comment on 2008-08-25 13:21 from edgar (Maple Rating 2 176)

The guesses on where it comes from are both right.

I started with the problem in
www.mapleprimes.com/forum/thomascalculus5615exercisegetshypergeom
which is a sum of two terms, both involving 2F1's, then converted to Int, combined them, and evaluated. Voila, a new problem, now involving a 3F2.

My guess is that although
hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], -1/6)
has a nice closed form,
hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], z)
doesn't. But that's just a guess.
---
G A Edgar

gkokovidis's picture

"Cheating?" w/ Maple

Comment on 2008-08-25 11:38 from gkokovidis (Maple Rating 4 677)

The challenge was to show that W:=1.  There was no mention as to what available tools one could use to do this.  The methods outlined above are over my head mathematically.   Attached file showing W:=1.

Download 221_hypergeom.mws
View file details

 

Regards,
Georgios Kokovidis

Dräger Medical
edgar's picture

food for thought

Comment on 2008-08-25 13:42 from edgar (Maple Rating 2 176)

You think it is an algebraic trick? Look at this:

A1 := hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], z);
= hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], z)

A2 := subs(z=-1/6,A1);
= hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], -1/6)

identify(evalf(A2,50));
<br /> (77/486)*42^(1/2)

A3 := subs(z=1,A1);
= hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], 1)
<br /> evalf(A3,50);

.78544208367808523114057318033434606661653742464155

identify(%);
<br /> 10*3^(6/7)*ln(2)^7/Zeta(3)^5

Now, if you prove A3 is algebraic, you will be famous!

What I get

Comment on 2008-08-25 22:27 from jakubi (Maple Rating 4 911)

for z=1 is:

A1 := hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], z);
S:=convert(A1,FormalPowerSeries);
S1:=eval(S,z=1);

= Sum(-pochhammer(3/8,k)*pochhammer(169/88,k)*4^(-k)/k!^2/pochhammer(81/88,k)/pochhammer(19/8,k)*(2*k)!/(2*k-1),k = 0 .. infinity); 

value(S1);


                                    3/2
                  11              Pi
                  -- -------------------------------
                  54                           3 Pi
                     GAMMA(5/8) GAMMA(7/8) sin(----)
                                                8

which may be rewritten as 11/54*GAMMA(4/8)*GAMMA(3/8)/GAMMA(7/8) using the reflection formula (by hand).

May be that z=1 is a better point for ICs of the ODE method?

 

edgar's picture

A problem with identify

Comment on 2008-08-26 08:35 from edgar (Maple Rating 2 176)

That thing with the zeta functions from identify: In fact it only agrees to 8 places, so don't believe it.
---
G A Edgar

Axel Vogt's picture

x=1/6

Comment on 2008-08-25 16:21 from Axel Vogt (Maple Rating 4 948) 
One could see the problems in the cited thread in a positive way:
Using the shown variants gives a special identity for some 2F1 :-)

Anyway, I give up (except you are willing (later) to show how you
came up with your task). Concerning x=1/6 the reformulation I got:

-25/343*42^(1/2)*x^(1/2)*
  hypergeom([-15/8, -1/2, -37/88],[-125/88, 1/8],-1/x)
+
81/539*42^(1/2)*
  hypergeom([-1/2, 3/8, 169/88],[81/88, 19/8],-x)
-
3/343*(6*x-1)*Pi^(3/2)*42^(1/2)*2^(1/2)/x^(11/8)/GAMMA(5/8)/GAMMA(7/8)
 
equals 0, so there is an analogous task for x=6.


I have no feeling, how difficult it is, but already Gamma's can be
a mess - here is one given by Bill Gosper: 

2^(1/4)*3^(3/8)*GAMMA(1/4)*GAMMA(1/3) = 
(3^(1/2)-1)^(1/2)*Pi^(1/2)*GAMMA(1/12)

Maple 8 helps some

Comment on 2008-08-25 16:59 from Alex Smith (Maple Rating 3 289)

Although this does not solve the challange, it is interesting that Maple 8 can re-express A1 in terms of some elementary functions and some more simple hypergeometrics...(2,1) instead of (3,2). Maple 12 does not seem to know this.

 A1 := hypergeom([-1/2, 3/8, 169/88], [81/88, 19/8], z);

expand(simplify(A1)); #in Maple8

 

-3/8*hypergeom([-1/2, 11/8],[19/8],z)+15/8*hypergeom([-1/2, 11/8],[19/8],z)*z-319/108/(1-z)^(1/2)*z+341/216/(1-z)^(1/2)*z^2+11/8/(1-z)^(1/2)+121/1026*hypergeom([1/2, 19/8],[27/8],z)*z-55/342*hypergeom([1/2, 19/8],[27/8],z)*z^2

problem with simplify/hypergeom/baseHG?

Comment on 2008-08-25 18:16 from jakubi (Maple Rating 4 911)

Comparison of tracing by Maple  8 and Maple 12 shows that both get the same up to close to the end  of the calculation where, apparently, 'simplify/hypergeom/baseHG' produces a different result.

acer's picture

from before

Comment on 2008-08-26 01:46 from acer (Maple Rating 4 1359)

Knowing a1 and a2 below makes it easier, to then show that a linear combination of them is equal both to W and to 1.

> a1 := hypergeom([-1/2, 11/8], [19/8], -1/6):
> a2 := hypergeom([-1/2, 3/8], [11/8], -1/6):

> W := 81/539*42^(1/2) * (5/27*a1+22/27*a2);
     81    1/2 /
W := --- 42    |5/27 hypergeom([-1/2, 11/8], [19/8], -1/6)
     539       \
 
       22                                     \
     + -- hypergeom([-1/2, 3/8], [11/8], -1/6)|
       27                                     /
 

> value(simplify(combine(convert(convert(W,MeijerG),Sum))));
            81    1/2                       169    81
            --- 42    hypergeom([-1/2, 3/8, ---], [--, 19/8], -1/6)
            539                             88     88
 

> Z := simplify(combine(convert(W,Int)));
                                1
                               /              1/2
                         1/2  |   (36 + 6 _t1)    (5 _t1 + 6)
            Z := 1/784 42     |   --------------------------- d_t1
                              |                5/8
                             /              _t1
                               0
 

> op(1,Z)*op(2,Z) *Int(IntegrationTools:-GetIntegrand(op(3,Z)),
>                       IntegrationTools:-GetVariable(op(3,Z)));
                             /             1/2
                       1/2  |  (36 + 6 _t1)    (5 _t1 + 6)
               1/784 42     |  --------------------------- d_t1
                            |               5/8
                           /             _t1
 
> Q := value(%);
                         1/2              3/8             1/2
                       42    (_t1 + 6) _t1    (36 + 6 _t1)
                  Q := --------------------------------------
                                        294
 

> (a,b) := op(IntegrationTools:-GetRange(op(3,Z)));
                                 a, b := 0, 1
 
> 1/(eval(Q,_t1=b)-eval(Q,_t1=a));
                                       1

acer

Comment viewing options

Select your preferred way to display the comments and click "Save settings" to activate your changes.
}