tomleslie

Maybe...

Answered: tomleslie 13876

April 28 2019

1 2

something like the attached

>

restart;

>	interface(rtablesize=10):

>

  getR:= proc( Ra, Rb, Rc, connect )
               if   connect=series
               then return Ra+Rb+Rc
               elif connect=parallel
               then return expand(simplify(1/((1/Ra)+(1/Rb)+(1/Rc))))
               fi;
         end proc:
  getR(R1, R2, R3, series);
  getR(R1, R2, R3, parallel);
#
# with values
#
  getR(10, 10, 10, series);
  getR(10, 10, 10, parallel);

(1)

>

Download Rcalc.mw

Something like...

Answered: tomleslie 13876

April 28 2019

3 3

the attached - maybe?

This worksheet

generates a random graph (G) and a "test" subgraph (T)
selects all subgraphs of G which have the same number of edges as the subgraph T
checks whether any of these subgraphs is actually isomorphic to the subgraph T
as an illustration (and assuming that at least one isomorphic subgraph exists), draw the graph G and the first subgraph which is isomorphic to the "test" subgraph T

A warning! Depending on the vertex/edge counts for the graphs, the number of isomorphisms to be checked can "explode" very quickly, with consequent (serious) increase in execution time - so be careful!!!

>

restart;

>

  with(combinat):
  with(GraphTheory):
  with(RandomGraphs):
  interface(rtablesize=10):
#
# Uncomment the following 'randomize' to
# generate a different random graph each
# time this worksheet is executed
#
  randomize():

#
# As a trial produce a random graph with
# for example, eight vertexes and twelve
# edges
#
  G:= RandomGraph(8, 12):
#
# Define a particular "test" sub-graph -
# for example a cycle of six
#
  T:= CycleGraph(6):
#
# Produce all subgraphs of G which have the same
# number of edges as the "test" sub-graph T
#
  gL:= Graph~(choose(Edges(G),NumberOfEdges(T))):

#
# Check whether T is isomorphic to any of the elements
# in gL
#
# Output the index(es) of entries in gL for which the
# isomorphism is true
#
  ans:= [ seq
          ( `if`
            ( IsIsomorphic( T, gL[j] ),
              j,
              NULL
            ),
            j=1..numelems(gL)
          )
        ];

(1)

>	if numelems(ans)>0 then HighlightSubgraph( G, gL[ans[1]], edgestylesheet=[thickness=4, color="Red"]); DrawGraph(G, style=spring); fi;

>

Download isSub.mw

Whilst agreeing...

Answered: tomleslie 13876

April 26 2019

2 3

with others that your approach *ought* to work, the desired effects can be obtained if you are prepared to try hard enough. Generally speaking, I can't be bothered - I'm more interested in answers, rather than the "color" of answers!

Anyhow, FWIW, see the attached - this will produce (honest) a "pretty" table in a Maple worksheet, but for some reason will not display here

>

restart;

>	with(DocumentTools): with(DocumentTools:-Layout): interface(rtablesize=10):

>

  M:= Matrix(2, 2, (i,j)->i+j);
  tabents:= Worksheet
            ( Table
              ( Row
                ( Equation
                  ( sqrt(x)/Pi,
                    typesetcolor=green
                  ),
                  Equation
                  ( M[1,1],
                    `if`( M[1,1]>3,
                          typesetcolor=green,
                          typesetcolor=red
                        )
                  ),
                  TextField
                  ( Font
                    ( "Some Text",
                      color=green,
                      background=grey
                    )
                  )
                ),
                Row
                ( Equation
                  ( M[2,2],
                    `if`( M[2,2]>3,
                          typesetcolor=green,
                          typesetcolor=red
                        )
                  ),
                  TextField
                  ( Font
                    ( "More Text",
                      color=red,
                      background=yellow
                    )
                  ),
                 Cell
                 ( Equation
                   ( sqrt(x)/Pi,
                     typesetcolor=blue
                   ),
                   fillcolor=cyan
                  )
                ),
                width=25,
                alignment=center
           )
) :
InsertContent(tabents):

Matrix(2, 2, {(1, 1) = 2, (1, 2) = 3, (2, 1) = 3, (2, 2) = 4})

(1)

>

Download pretty.mw

Reproducible problem...

Answered: tomleslie 13876

April 25 2019

1 4

I haven't had any real issue installing Physics package updates. I just do it from the cloud icon thingummy in the upper right hand corner of the Maple worksheet interface, and it just "works". I do (usually) restart Maple after performing one of these updates.
Running OP's code produces (for me) exactly the same error
OP suggests issue might be a Windows 10 update?? Since I'm running 64-bit Windows 7 to generate the same error, the OS would *seem* to be irrelevant
Running "ECTerrab code" produces the same error at the same point in the execution of the pdsolve() command - as determined by setting infolevel(pdsolve):=2

See the attached

>	restart; # # OP's original code with the addition # of version statements, infolevel(pdsolve) # and the rtablesize() "kludge" #

>	kernelopts(version); Physics:-Version(); infolevel[pdsolve]:=2: interface(rtablesize=10);

$"C:\Users\TomLeslie\maple\toolbox\2019\Physics Updates\lib\Physics Updates.maple", `2019, April 24, 8:39 hours, version in the MapleCloud: 348, version installed in this computer: 348.`$

(1)

>	unassign('r,u,t'); pde:=diff(u(r,t),t)= 1/rdiff(ru(r,t),r$2); #Laplacian in spherical ic:=u(r,0)=1; bc := u(1,t) =0; pdsolve([pde,ic,bc],u(r,t),HINT =boundedseries(r=0)) assuming t>0

diff(u(r, t), t) = (2*(diff(u(r, t), r))+r*(diff(diff(u(r, t), r), r)))/r

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs
   -> trying "LinearInXT"
* trying method "SpecializeArbitraryConstants" for 2nd order PDEs
* trying method "Wave" for 2nd order PDEs
   -> trying "Cauchy"
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Heat" for 2nd order PDEs
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Series" for 2nd order PDEs
   -> trying "TwoBC"

Error, (in assuming) when calling 'ln'. Received: 'when calling 'ln'. Received: 'numeric exception: division by zero''

>

restart;
#
# ECTerrab version with the addition of
# infolevel(pdsolve) and the rtablesize() "kludge"
#
# Works without the boundedseries() option on
# the dsolve() command.
#
# Either version of the boundedseries() command
# causes failure - apparently at the same point
# as the OP's original code
#

>	kernelopts(version); Physics:-Version(); infolevel[pdsolve]:=2: interface(rtablesize=10);

$"C:\Users\TomLeslie\maple\toolbox\2019\Physics Updates\lib\Physics Updates.maple", `2019, April 24, 8:39 hours, version in the MapleCloud: 348, version installed in this computer: 348.`$

(2)

>

diff(u(r, t), t) = (2*(diff(u(r, t), r))+r*(diff(diff(u(r, t), r), r)))/r

(3)

>

(4)

>

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs
-> trying "LinearInXT"
* trying method "SpecializeArbitraryConstants" for 2nd order PDEs

* trying method "Wave" for 2nd order PDEs
   -> trying "Cauchy"
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Heat" for 2nd order PDEs
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Series" for 2nd order PDEs
   -> trying "TwoBC"

   -> trying "ThreeBCsincos"
   -> trying "FourBC"
   -> trying "ThreeBC"
   -> trying "ThreeBCPeriodic"
   -> trying "WithSourceTerm"
      * trying method "SpecializeArbitraryFunctions" for 2nd order PDEs
         -> trying "LinearInXT"
      * trying method "SpecializeArbitraryConstants" for 2nd order PDEs

      * trying method "Wave" for 2nd order PDEs
         -> trying "Cauchy"
         -> trying "SemiInfiniteDomain"
         -> trying "WithSourceTerm"
      * trying method "Heat" for 2nd order PDEs
         -> trying "SemiInfiniteDomain"
         -> trying "WithSourceTerm"
      * trying method "Series" for 2nd order PDEs
         -> trying "TwoBC"
         -> trying "ThreeBCsincos"
         -> trying "FourBC"
         -> trying "ThreeBC"
         -> trying "ThreeBCPeriodic"
         -> trying "WithSourceTerm"
         -> trying "ThreeVariables"
         -> trying "TwoBC"
         -> trying "ThreeBCsincos"
         -> trying "FourBC"
         -> trying "ThreeBC"
         -> trying "ThreeBCPeriodic"
         -> trying "ThreeVariables"
         * trying a linear change of variables
            -> trying "ThreeBCsincos"
            -> trying "FourBC"
            -> trying "ThreeBC"
            -> trying "ThreeBCPeriodic"
            -> trying "WithSourceTerm"
            -> trying "ThreeVariables"
            -> trying "ThreeBCsincos"
            -> trying "FourBC"
            -> trying "ThreeBC"
            -> trying "ThreeBCPeriodic"
            -> trying "ThreeVariables"
      * trying method "Laplace" for 2nd order PDEs
         -> trying a Laplace transformation

         <- Laplace transformation successful
      <- method "Laplace" for 2nd order PDEs successful
   <- submethod "WithSourceTerm" successful
<- method "Series" for 2nd order PDEs successful

u(r, t) = (-invlaplace(sinh(s^(1/2)*r)/(sinh(s^(1/2))*s), s, t)+r)/r

(5)

Note r = [0]

>

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

   -> trying "LinearInXT"
* trying method "SpecializeArbitraryConstants" for 2nd order PDEs
* trying method "Wave" for 2nd order PDEs
   -> trying "Cauchy"
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Heat" for 2nd order PDEs
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Series" for 2nd order PDEs
   -> trying "TwoBC"

Error, (in assuming) when calling 'ln'. Received: 'when calling 'ln'. Received: 'numeric exception: division by zero''

It works with r = 0 but the flow goes through a different path

>

* trying method "SpecializeArbitraryFunctions" for 2nd order PDEs

   -> trying "LinearInXT"
* trying method "SpecializeArbitraryConstants" for 2nd order PDEs
* trying method "Wave" for 2nd order PDEs
   -> trying "Cauchy"
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Heat" for 2nd order PDEs
   -> trying "SemiInfiniteDomain"
   -> trying "WithSourceTerm"
* trying method "Series" for 2nd order PDEs
   -> trying "TwoBC"

Error, (in assuming) when calling 'ln'. Received: 'when calling 'ln'. Received: 'numeric exception: division by zero''

I will adjust the syntx r = 0 to map into r = [0].

>

Download pdeProb.mw

Revised answer...

Answered: tomleslie 13876

April 23 2019

3 1

Simple answers to your questions - actually recommend reading teh help for (much) more detail.

The -> operator just allows you to construct a simple function so for example f:=x-> x² means that a subsequent call such as f(2) will return 4.

The ~ operator just allows you to apply an operation to every element in a 'container'. So, for example if M is a Matrix, then (with 'f' defined as above f~(M) will just square every element in the matrix.

Easy to reduce the amount the data. In the attached

I have reduced the number of columns being read by the EcelTools:-Import() statement to 50. This number is arbitrary

When doing the filtering operation, instead of returning the complete row of 50 columns I only return the first 41 columns - again this number is arbitrary, and just for "illustration"

The seq() function

op([1,1],SD) returns the number of rows in SD, so i=2..op([1,1],SD) part just generates all row numbers from 2 to the end of the Matrix. (The first row is omitted because it only contains "labels".

the 'if' statement just checks the condition in which you are interested: if satisfied the relevant row is returned. If the condition is not satisfied then nothing is returned (Ie NULL)

When done this way, the output is a sequence of row vectors: the scan=columns option just stacks these back into a matrix

If M is a matrix, then op(1, M) will just return the row and column dimension of M, as a sequence. op[[1,1],M) will return the first entry in the sequence - so you get the the row dimension. There are other ways to get matrix dimensions: I just find this way "convenient".

I don't see any particular memory issue here - you will have to explain further

In the attachd, just as an exercise, I have converted the input to a dataframe. The only real benefit this gives is allowing access/filtering operation to be done using labels, rather than row/column indexes. This may (or may not!) be more convenient

>

restart;

>	# # Load the LinearAlgebra package # with(ExcelTools): with(LinearAlgebra): # # Ignore this, only needed to make stuff display # properly on the Maple primes web site # interface(rtablesize=10)

(1)

>

#
# Import the data. OP will need to change the
# file path to something appropriate for his/her
# machine.
#
# Just for illustration, read in all rows, but only
# the first 50 columns
#
# Convert the "blank" entries given by "-" to 0.0
#
  Steel_data:= Import
               ( "C:/Users/Tomleslie/Desktop/db.xlsx",
                 "Database v15.0",
                 "A1:AX2094"
               ):
  f:= x->`if`(x="–", 0.0, x):
  SD:=f~(Steel_data):

>

#
# Extract rows, which match a particular condition
#
# Don't keep the whole row, just keep columns 1..41
# to show how thi might be done
#
  S_mod__min:= 11.66666667;
  M2:= Matrix( [ SD[1,1..41],
                 seq
                 ( `if`
                   ( S_mod__min < SD[i,41] and SD[i,7] <= 10.5,
                     SD[i,1..41],
                     NULL
                   ),
                   i=2..op([1,1],SD)
                 )
               ],
               scan=columns
            );

_rtable[18446744074348896494]

(2)

>	# # Quick check on max/min entries in column 41 of the # output Matrix # min(M2[2..,41]); max(M2[2..,41]); # # Quick check on max/min entries in column 7 of the # output Matrix # min(M2[2..,7]); max(M2[2..,7]);

(3)

>

#
# Using a select() function to produce the same
# thing
#
  M3:= SD[ select
           ( i-> `or`
                 ( i=1,
                   `and`
                   ( S_mod__min < SD[i, 41],
                     SD[i,7] <= 10.5
                   )
                 ),
                 [$1..op([1,1],SD)]
            ),
            1..41
         ];
#
# Check that this produces the same matrix
# as the previous method
#
  Equal(M2, M3);

_rtable[18446744074348886006]

(4)

>

#
# Construct the input as a DataFrame. Use entries in column 3
# as labels for the rows and entries in row 1 as the column
# labels
#
  df:= DataFrame
       ( SD[2..-3,4..],
         rows=SD[2..-3,2],
         columns=convert~(SD[1,4..], symbol)
       );
#
# Extract only those rows for which Sx>S_mod__min and
# d<=10.5. These labels correspond to the column numbers
# specified in the matrix-based implementation above, but
# may(?) be easier to remember
#
  dfsub:=df[ df[Sx]>~S_mod__min and df[d]<=~10.5 ];

(5)

>	# # Quick check on the max and min entries in the # relevant columns # max( dfsub[Sx] ); min( dfsub[Sx] ); max( dfsub[d] ); min( dfsub[d] );

(6)

>

Download steel2.mw

A "rough" start...

Answered: tomleslie 13876

April 22 2019

1 4

just to show what is possible is given in the attached.

If I was doing a lot of such queries, it might be more convenient to address rows/columns, by their labels, rather than index numbers - so conversion to a dataframe might be a good idea.

Meanwhile the attached will output a matrix whose entries are the rows where your selection criteria is met

>

restart;

>	# # Ignore this, only needed to make stuff display # properly on the Maple primes web site # interface(rtablesize=10)

(1)

>

#
# Import the data. OP will need to change the
# file path to something appropriate for his/her
# machine
#
# Convert the "blank" entries given by "-" to 0.0
#
  Steel_data:=ExcelTools:-Import("C:/Users/Tomleslie/Desktop/db.xlsx", "Database v15.0");
  f:= x->`if`(x="–", 0.0, x);
  SD:=f~(Steel_data);

_rtable[18446744074372974518]

_rtable[18446744074375875510]

(2)

>

#
# Extract rows, which match a particular condition
#
  S_mod__min:= 11.66666667;
  M2:= Matrix( [ SD[1,..],
                 seq
                 ( `if`
                   ( S_mod__min < SD[i,41] and SD[i,7] <= 10.5,
                     SD[i,..],
                     NULL
                   ),
                   i=2..op([1,1],SD)
                 )
               ],
               scan=columns
            );

_rtable[18446744074397220726]

(3)

>	# # Quick check on max/min entries in column 41 of the # output Matrix # min(M2[2..,41]); max(M2[2..,41]); # # Quick check on max/min entries in column 7 of the # output Matrix # min(M2[2..,7]); max(M2[2..,7]);

(4)

>

Download steel.mw

Some kludges...

Answered: tomleslie 13876

April 21 2019

0 0

which (more-or-less) work in Maple 18.

It seems as if the 'colorscheme' enhancements were only introduced in Maple 18 and (in that release) only worked either with

"surfaces" (typically 3-D structures, but also 2-D "density" plots), or
"points" - defined either in 2-D or 3-D

but not simple 2-D curves.

For your case, one can get around the above limitation by considering the desired "curve" as a collection of closely-spaced points and using the pointplot() command.

However, as far as I can tell, the "simple" use of pointplot() only allows coloring to vary with the value of the dependent variable (ie y-coordinate), rather than by the value of both x- and y-coordinates. This is (probably?) not what you want, but is included in the attached anyway.

In order to color by a parameter affecting both x- and y-coordinates, the only method I have found is to generate a separate pointplot() command for each individual point to be plotted! This is do-able, but really ugly! I also found it slightly easier to write the colorscheme using the "HSV" colorspace, rather than the default "RGB" space, although the attached shows both versions

The output in the attached render "much better" in a Maple environment, than they do on this site - honest

>

restart;

>	with(plots): with(ColorTools): kernelopts(version);

(1)

>

#
# First possibility - essentially colors
# by the value of the y-coordinate. I'm
# (nearly?) certain that this is how the
# "valuesplit" option works in later Maple
# versions
#
  pointplot
  ( [ seq
      ( [ sin(x), cos(x) ],
        x=0..2*evalf(Pi), evalf(Pi/500)
      )
    ],
    colorscheme=["Blue", "Green", "Yellow", "Red"]
  );

>

#
# Second possibility. Color by the value of
# the supplied parameter. In order to generate
# a "linear" parameter for the colorspaces,
# it is (slightly) more convenient to plot
#
#     [cos(2*Pi*x), sin(2*Pi*x)] with 0<=x<=1
#
# rather than
#
#     [cos(x), sin(x)] with 0<=x<=2*Pi
#
# It is also slightly easier(?) to write the
# colorspec using the "HSV" colorspace, which
# is used in the first example
#
  display
  ( [ seq
      ( pointplot
        ( [ cos(2*Pi*x), sin(2*Pi*x) ],
          color= Color
                 ( "HSV",
                   [ piecewise
                     ( x<=1/2,
                       x,
                       1-x
                     ),
                     1.0,
                     1.0
                   ]
                 )
        ),
        x=0..1, 0.001
      )
    ],
    title="Uses HSV colorspace",
    titlefont=[times, bold, 20],
    scaling=constrained
  );
#
# Although it is possible to use the "default"
# RGB colorspace
#
  display
  ( [ seq
      ( pointplot
        ( [ cos(2*Pi*x), sin(2*Pi*x) ],
          color= Color
                 ( [ piecewise
                     ( x<=1/3,
                       1-3*x,
                       x<=2/3,
                       0,
                       x<=1,
                       3*(x-2/3)
                     ),
                     piecewise
                     ( x<=1/3,
                       3*x,
                       x<=2/3,
                       1-3*(x-1/3),
                       x<=1,
                       0
                     ),
                     piecewise
                     ( x<=1/3,
                       0,
                       x<=2/3,
                       3*(x-1/3),
                       x<=1,
                       1-3*(x-2/3)
                     )
                   ]
                 )
        ),
        x=0..1, 0.001
      )
    ],
    title="Uses RGB colorspace",
    titlefont=[times, bold, 20],
    scaling=constrained
  );

>

Download colCircle.mw

Seem to have...

Answered: tomleslie 13876

April 20 2019

0 5

quite a lot of "spurious" charactersin the string to be converted - eg \[ ]. Why do these exist? Some sort of copy/paste issue maybe? No idea how the translator may interpret these characters.

Maybe also have a problem with capitalisation??

The attached seems to work as I would expect

>

restart:

>	with(MmaTranslator): interface(rtablesize=10):

(1)

>	MM:=Matrix(convert("{{1/2 (-2 kappa - 4 lambda), -2 Sqrt[2] g, 0}, {g/Sqrt[ 2], -Gamma - kappa/2 - lambda, -Sqrt[2] g}, {0, Sqrt[2] g, -2 Gamma}}", FromMma)); simplify~(MM);

Matrix(3, 3, {(1, 1) = -kappa-2*lambda, (1, 2) = -2*sqrt(2)*g, (1, 3) = 0, (2, 1) = g/sqrt(2), (2, 2) = -GAMMA-(1/2)*kappa-lambda, (2, 3) = -sqrt(2)*g, (3, 1) = 0, (3, 2) = sqrt(2)*g, (3, 3) = -2*GAMMA})

Matrix(%id = 18446744074370869238)

(2)

>

Download mmaToMaple.mw

Do you just want to plot the data?...

Answered: tomleslie 13876

April 20 2019

0 0

In the attached, you will need to convert the filepath to something appropriate for your installation.

There are many options which can be added to the "pointplot()" command

Download xlPlot.mw

Possibly...

Answered: tomleslie 13876

April 19 2019

1 3

You have three independent variables (x, y, t). The help page for pdsolve/numeric states clearly (my emphasis)

PDEsys
-
single or set or list of time-dependent partial differential equations in two independent variables

So you will not be able to solve your system numerically (unless some kind of symmetry allows you to reduce it to two independent variables).

So numerical solution is (probably) a non-starter.

You *may* be able to solve the system analytically - but if you want anyone to work on this, then upload your worksheet using the big green up-arrow in the Mapleprimes toolbar. Life is too short fro anyone here to retype your worksheet from a picture!

I'm puzzled"...

Answered: tomleslie 13876

April 19 2019

0 1

There is no "valuesplit" option associated with "colorscheme" in Maple 18 (which you state you are using). In fact the "colorscheme" capability in Maple 18 seems to be very, very limited.

So where did you get the idea of using "valuesplit" with "colorscheme"???? Maybe you are using Maple 2018, not Maple 18???

The attached shows a few options for graph coloring with "colorscheme". I'm not really sure what coloring you are trying to achieve, so the contents of the attached are pretty much "guesses".

Interestingly, the color variation in the various graphs is not reproduced when they are rendereed on this site, so you will have to download the worksheet to examine

>

restart:

>	with(VectorCalculus): kernelopts(version); interface(rtablesize=10):

(1)

>

  a := 1.0:
  q := a*cos(b):
  p := a*sin(b):
  R1 := PositionVector([q, p], cartesian[x, y]):
  PlotPositionVector( R1,
                      b = 0 .. 2*Pi,
                      curveoptions=[ colorscheme=[ "valuesplit",
                                                   [ -1..-1/2="Red",
                                                     -1/2..1/2="Green",
                                                      1/2..1="Blue"
                                                   ]
                                                 ]
                                   ]
                    );
  PlotPositionVector( R1,
                      b = 0 .. 2*Pi,
                      curveoptions=[ colorscheme=[ "linear",
                                                   ["Red","Blue"]
                                                 ]
                                   ]
                    );
  PlotPositionVector( R1,
                      b = 0 .. 2*Pi,
                      curveoptions=[ colorscheme=[ "linear",
                                                   ["Red", "Yellow", "Blue"]
                                                 ]
                                   ]
                    );

>

Download colsch.mw

Easy way...

Answered: tomleslie 13876

April 19 2019

1 0

just pass the index as an extra parameter. After all does it really matter to ou whether you call

f[3](x, y) or

f(x, y, 3)

If you can accept the latter as a calling sequence, then the function definition becomes

f := (x, y, i) -> a[i]*x + b[i]*y;

What exactle is the problem...

Answered: tomleslie 13876

April 19 2019

0 6

As far as I can tell, pretty much everything is working - so what exactly is the problem. See the attached

>

restart;

>

  with(plots):
  interface(rtablesize=10):
  c1:= 1: c2:= 1: nu:= 3: Ra:= 2: sc:= 1: K:= [black, red, green]:
  A:= c2/(nu*c1): R:= Ra: N:= [0, 1, 2]: pr:= 1: S:= sc: g:= 0.5: k:= 1:
  for j to nops(N) do
      sol1:= dsolve
             ( [ diff(f(eta), eta$3)
                 +
                 A*( 3/4*f(eta)*diff(f(eta), eta$2)
                     -
                     1/2*diff(f(eta), eta)^2
                   )
                 +
                 R*( theta(eta) + N[j]*phi(eta) )
                 -
                 k*( 2*diff(f(eta), eta)
                     +
                     c1*diff(f(eta), eta$2)*diff(f(eta), eta$2)
                     -
                     3*diff(f(eta), eta)*diff(f(eta), eta$4)
                   )
                 = 0,
                 diff(theta(eta), eta$2)/pr + 3/4*f(eta)*diff(theta(eta), eta) = 0,
                 diff(phi(eta), eta$2)/S + 3/4*f(eta)*diff(phi(eta), eta) = 0,
                 f(0) = 0, D(f)(0) = 1, D(f)(3) = 1, (D@@2)(f)(3) = 0, phi(0) = 1,
                 phi(3) = 0, theta(0) = D(theta)(0)/g + 1, theta(3) = 0
               ],
               numeric,
               method = bvp[middefer]
             );
      fplt[j]:= odeplot(sol1, [eta, f(eta)], color = K[j], axes = boxed);
      tplt[j]:= odeplot(sol1, [eta, theta(eta)], color = K[j], axes = boxed);
      fplt[j]:= odeplot(sol1, [eta, diff(f(eta), eta)], color = K[j], axes = boxed);
      phiplt[j]:= odeplot(sol1, [[eta, phi(eta)]], color = K[j], axes = boxed);
  end do:
  display([seq(fplt[j], j = 1 .. nops(N))]);
  display([seq(tplt[j], j = 1 .. nops(N))]);
  display([seq(phiplt[j], j = 1 .. nops(N))]);

>

#
# OP's second(?) problem
#
  sol2:= dsolve
         ( [ diff(f(eta), eta$3)+ f(eta)* diff(f(eta), eta$2)=0,
             diff(theta(eta), eta$2)+ f (eta)* diff(theta(eta), eta)=0,
             f(0) = 0, (D(f))(0) = 0, (D(f))(5) = 1,
             theta(0) = 1, theta(5) = 0
           ],
           numeric,
           method=bvp[midrich]
         ):
  odeplot( sol2,
           [ [eta, f(eta)],
             [eta, theta(eta)]
           ],
           eta=0..3,
           color=[red, green]
         );

>

Download odeProb.mw

Cannot reproduce...

Answered: tomleslie 13876

April 18 2019

0 0

using Maple2018.2 (Build ID 1362973) on Windows 7.

See the attached

Download timeSer.mw

Observation...

Answered: tomleslie 13876

April 17 2019

0 3

Not so much a singularity, more the fact that the system is inconsistent.

Each differential in 'odesys' is multiplied by the factor sqrt(t). Hence at t=0, all of these differential terms disappear, and you are left with a set of linear equations in S(0), M(0)., N(0)., U(0). Into these equations just substitute your boundary conditions, using

eval([eval(odesys, t=0)], [ICS])

which will return

[32.619 = 0, -5.19 = 0, -22.81 = 0, -0.30 = 0]

This is definitely not good!

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

Ask a Question

Create a Post

13876 Reputation

20 Badges

MaplePrimes Activity

These are answers submitted by tomleslie

Maybe...

Something like...

Whilst agreeing...

Reproducible problem...

Revised answer...

A "rough" start...

Some kludges...

Seem to have...

Do you just want to plot the data?...

Possibly...

I'm puzzled"...

Easy way...

What exactle is the problem...

Cannot reproduce...

Observation...

Save this setting as your default sorting preference?

Ask a Question

Create a Post

Generating PDF…

Save this setting as your default sorting preference?
Note: You can change your preference any time in your account settings
Don't show this again