tomleslie

As Carl said...

Answered: tomleslie 13876

April 17 2019

2 1

see the attached

>

restart;

>	interface(rtablesize=10):

>

with(Groebner):
Jugdement := proc (F, P)
                   local f, N1, N2, i, j, k, q, LTF, LTPj, F__loc:=F;
                   N1 := nops(F__loc);
                   N2 := numelems(P);
                   for i to N1 do
                       LTF := LeadingTerm(F__loc, plex(w, t, s, x, y, z));
                       for j to N2 do
                           LTPj := LeadingTerm(P[j], plex(w, t, s, x, y, z));
                           f := divide(LTF[2], LTPj[2], 'q');
                           if   f = true
                           then k := j;
                                break
                           end if
                       end do;
                       if   f = true
                       then break
                       end if;
                       if   f = false
                       then F__loc := F__loc-LTF[1]*LTF[2]
                       end if
                   end do;
                   return k, f, q, P[k], LTF[1]
             end proc:
F := x^2+y^2+z^2;
P := {z, x*z, y*x};
Jugdement(F, P);

(1)

>

Download formPar.mw

Can't be done...

Answered: tomleslie 13876

April 16 2019

1 6

The GraphTheory() package does not permit Graphs with loops.

From the help page of ?GraphTheory (with my emphasis)

The GraphTheory package is a collection of routines for creating graphs, drawing graphs, manipulating graphs, and testing graphs for properties. The graphs are sets of vertices (nodes) connected by edges. The package supports both directed and undirected graphs but not multigraphs or graphs with loops (self-incident vertices). The edges in the graphs can be weighted or unweighted.

You can do a coordinate transformation...

Answered: tomleslie 13876

April 16 2019

0 0

- but you don't have to!

The attached generates the desired plot from the original expresssion (ie using Cartesian coordinates)
Then uses changecoords() to convert the expression to spherical polars, and produces the "same" plot using the polar coordinates

>

restart:

>	interface(rtablesize=10): with(plots):

>

#
# Produce plot using cartesian coordinates
#
  expr1:=x^2+y^2/4+z^2/9=1:
  implicitplot3d( expr1,
                  x=-4..4,
                  y=-4..4,
                  z=-4..4,
                  axes=none,
                  style=surface,
                  scaling=constrained,
                  grid=[ 40, 40, 40]
               )

>

#
# Convert expression to spherical polars
#
  expr2:= :-changecoords( expr1,
                          [ x, y, z ],
                          spherical,
                          [ r, theta, phi ]
                        );
#
# Produce plot using spherical coordinates
#
  implicitplot3d( expr2,
                  r=0..4,
                  theta=0..2*Pi,
                  phi=0..Pi,
                  style=surface,
                  coords=spherical,
                  axes=none,
                  scaling=constrained,
                  style=surface,
                  grid=[40, 40, 40]
                );

r^2*sin(phi)^2*cos(theta)^2+(1/4)*r^2*sin(phi)^2*sin(theta)^2+(1/9)*r^2*cos(phi)^2 = 1

>

Download elliPlot.mw

What am I missing??...

Answered: tomleslie 13876

April 16 2019

2 0

The attached "just works" - and it isn't a version issue, becuase I've checked it in Maple 2018, Maple 2017 ,Maple 2016, Maple 2015, and Maple 18.

>

restart;

>	kernelopts(version); Physics:-Version(); interface(rtablesize=10):

$"C:\Users\TomLeslie\maple\toolbox\2019\Physics Updates\lib\Physics Updates.maple", `2019, April 16, 8:7 hours, version in the MapleCloud: 344, version installed in this computer: 344.`$

(1)

>	PDE:=[ diff(f(x,xp),x)=-(1/2)(Lxp+2x)kl, diff(f(x,xp),xp)=-(1/4)klL(Lxp+2*x) ]; sol:=pdsolve(PDE); pdetest(sol[], PDE);

${f(x, xp) = -(1/8)*(L*xp+2*x)^2*kl+_C1}$

(2)

>

Download pdprob.mw

A couple of typos...

Answered: tomleslie 13876

April 14 2019

0 0

which are fixed in the attached

>	# # Restar should be in its own execution group # restart;

>	# # redefining built-in variables is really not # advisable! # local gamma; local I; local pi ;

Warning, The imaginary unit, I, has been renamed _I

(1)

>	# # Added this execution group so worksheet displays # correctly on Mapleprimes website # interface(rtablesize=10):

>

#
# Set up numerical values for all problem parameters
#
# Changed beta[*] to beta[star] in this execution group
# (and everywhere subsequently).
#
# rmoved excess comma character after final entry in params
#
  params:=[       psi=0.142,        mu[1]=0.112,      phi=0.4e-3,
                 mu[v]=0.002, beta[o]=0.081, M[h]=10,
            omega=0.2e-2,     eta=0.5e-1, mu[e]=0.092,
                pi=0.598e-2,    beta[star]=.5,      eta=0.213

          ]:

>	# # Define main function # R:= sqrt((psi+mu[1]+phi)(mu[1])^(2)mu[v]psibeta[o](M[h])^(2)(omega+mu[1]+eta)mu[e]pibeta[star]/(psi+mu[1]+phi)(omega+mu[1]+eta)mu[v]mu[e]*(mu[1])^2);

(2)

>

#
# Compute "all" derivatives and evaluate numerically.
#
# For the purposes of this calculation "all"
# derivatives, means the derivatives with respect to
# every variable returned by indets(R, name)
#
# Output a list of two element lists where each of
# the latter is
#
# [ varName,
# eval( diff( R, varName), params )
# ]
#
[ seq( [j, eval( diff( R, j), params )],j in indets(R, name))];

[[eta, 0.1353555737e-6], [omega, 0.1353555737e-6], [pi, 0.1856046329e-5], [psi, 0.7816307780e-7], [M[h], 0.2219831409e-8], [beta[o], 0.1370266302e-6], [beta[star], 0.2219831409e-7], [mu[1], 0.5317540395e-6], [mu[e], 0.2412860227e-6], [mu[v], 0.1109915705e-4]]

(3)

>

#
# Compute all "sensitivities" (where the sensitivity
# is as defined in Rouben Rostamian response to the
# OP's earlier post) and evaluate numerically.
#
# For the purposes of this calculation "all" sensitivities
# means the sensitivity with respect to every variable
# returned by indets(R, name)
#
# Output a list of two element lists where each of
# the latter is
#
# [ varName,
# eval( varName*diff( R, varName)/R, params )
# ]
#
seq( [j, eval( j*diff( R, j)/R, params )],j in indets(R, name));

[eta, .3048780488], [omega, 0.1219512195e-1], [pi, 1/2], [psi, 1/2], [M[h], 1], [beta[o], 1/2], [beta[star], 1/2], [mu[1], 2.682926826], [mu[e], 1], [mu[v], 1]

(4)

>

Download sens.mw

Supplied worksheet has two problems...

Answered: tomleslie 13876

April 12 2019

0 0

You have used x both as the independent variable in all of the ODEs, but also as an index in a for-loop. The latter use will result on 5.2 being assigned to 'x' after the loop has executed. This will effectively substitute 5.2 everywhere you use 'x' in your ODEs. You really do not want this, so I have changed the offending loop index at the point highlighted in the attached
Second problem is more subtle. Location is also highlighted in the attached. The loop which solves the ODEs for coefficients of p⁰, p¹,p²,...etc. For p⁰ one gets an explicit expression fro c[0](x), whihc is good. However for p¹, the relevant ODE contains c[0](x) (which will be correctly substituted from the previous loop iteration), c[1](x) and f(x). It is therefore not possible to get an explicit expression for c[1](x). Maple will provide a 'formal' solution for c[1](x) in terms of double integrals of the unknown f(x) - but I'm guessing that this is not what you want! It gets worse! This formal soultion for c[1](x) is used in the ODE for p² which also contains the two unknowns c[2](x) and f(x). Maple will provide another 'formal' solution, but this contains the previous 'formal' solution for c[1](x) - so ones gets an even more complicated formal solution containing a formal solution. This situation gets worse at each loop iteration, and the expression complexity "explodes". I'm guessing thsat this is not what you want, but it is an inevitable consequence of the way the problem is formulated. Can only suggest that you check the logic of your algorithm very carefully

>	# # added restart, just because it's always a good idea # restart;

>	# # Added this just so that worksheet will display # correctly ion the MApleprimes website # interface(rtablesize=10):

>

(1-p)*(diff(diff(diff(f(x), x), x), x))+p*(diff(diff(diff(f(x), x), x), x)+(1/2)*f(x)*(diff(diff(f(x), x), x)))

(1)

>

(1-p)*(diff(diff(g(x), x), x))/Pr+p*((diff(diff(g(x), x), x))/Pr+(1/2)*f(x)*(diff(g(x), x)))

(2)

>

ibvc := f(0), (D(f))(0), (D(f))(5)-1, g(0)-1, g(5); n := 5; F := unapply(add(b[k](x)*p^k, k = 0 .. n), x); G := unapply(add(c[k](x)*p^k, k = 0 .. n), x)

(3)

>

DE1 := series(eval(de1, f = F), p = 0, n+1)

(4)

>

series((diff(diff(c[0](x), x), x))/Pr+((diff(diff(c[1](x), x), x))/Pr+(1/2)*f(x)*(diff(c[0](x), x)))*p+((diff(diff(c[2](x), x), x))/Pr+(1/2)*f(x)*(diff(c[1](x), x)))*p^2+((diff(diff(c[3](x), x), x))/Pr+(1/2)*f(x)*(diff(c[2](x), x)))*p^3+((diff(diff(c[4](x), x), x))/Pr+(1/2)*f(x)*(diff(c[3](x), x)))*p^4+((diff(diff(c[5](x), x), x))/Pr+(1/2)*f(x)*(diff(c[4](x), x)))*p^5+O(p^6),p,6)

(5)

>

[b[0](0), b[1](0), b[2](0), b[3](0), b[4](0), b[5](0), (D(b[0]))(0), (D(b[1]))(0), (D(b[2]))(0), (D(b[3]))(0), (D(b[4]))(0), (D(b[5]))(0), (D(b[0]))(5)-1, (D(b[1]))(5), (D(b[2]))(5), (D(b[3]))(5), (D(b[4]))(5), (D(b[5]))(5), g(0)-1, g(5)]

[f(0), (D(f))(0), (D(f))(5)-1, c[0](0)-1, c[1](0), c[2](0), c[3](0), c[4](0), c[5](0), c[0](5), c[1](5), c[2](5), c[3](5), c[4](5), c[5](5)]

(6)

>

for k from 0 to n do IBVC1 := select(has, CO, b[k]); slv := dsolve({coeff(DE1, p, k), op(IBVC1)}); b[k] := unapply(rhs(slv), x) end do

>

(7)

>

for k from 0 by .2 to 5 do NM1 := subs[eval](p = 1, F(k)) end do

>

for k from 0 to 1 do IBVC2 := select(has, CT, c[k]); sol := dsolve({coeff(DE2, p, k), op(IBVC2)}); c[k] := unapply(rhs(sol), x) end do

c[1](x) = Int(Int((1/10)*f(_z1)*Pr, _z1 = 0 .. _z1), _z1 = 0 .. x)-(1/5)*(Int(Int((1/10)*f(_z1)*Pr, _z1 = 0 .. _z1), _z1 = 0 .. 5))*x

proc (x) options operator, arrow; Int(Int((1/10)*f(_z1)*Pr, _z1 = 0 .. _z1), _z1 = 0 .. x)-(1/5)*(Int(Int((1/10)*f(_z1)*Pr, _z1 = 0 .. _z1), _z1 = 0 .. 5))*x end proc

(8)

>

Download hpm2.mw

Since you have an IVP,...

Answered: tomleslie 13876

April 09 2019

1 0

it is possible to use the 'parameters' option with the dsolve/numeric command.

This will produce a solution module with explicit values of 'p', 'lambda' and 'rho' as yet unspecified

These parameters can be subsequently given values, and relevant outputs obtained, as in the following.

Note that depending on the parameter values which are used, the ode system may (or may not) exhibit a singularity in the solution process

>

restart;

>	with(plots): interface(rtablesize=10):

>

  N:= 10:
  beta:= 1:
  alpha:= (N + 2)/(N - 2):
  ics:= {U(0) = beta, V(0) = 1, X(0) = 0, Y(0) = 1}:
  sys_ode:= { diff(U(r), r) = r^(N - 1)*rho^(N - 2)*p*X(r),
              diff(V(r), r) = r^(N - 1)*rho^(N - 2)*p*Y(r),
              diff(X(r), r) = -r^(N - 1)*rho^N*(U(r)^(alpha - 1) + lambda*U(r)),
              diff(Y(r), r) = -r^(N - 1)*rho^N*(lambda + (2^alpha - 1)*U(r)^(alpha - 2))*V(r)
            }:
  sol:= dsolve( [ sys_ode[], ics[] ],
                  numeric,
                  parameters = [lambda, p, rho]
              ):

>

#
# List the unknown parameters (just as a check!)
#
  sol(parameters);
#
# Supply one set of parameter values. Note
# this is dependent on order.
#
# Then plot the solution
#
  sol( parameters = [1, 1, 1] ):
  odeplot( sol,
           [ [r, U(r)], [r, V(r)], [r,X(r)], [r, Y(r)] ],
             r=0..1,
             color=[red, blue, green ,black]
         );
#
# Supply another set of parameter values and
# plot the solution
#
  sol( parameters = [2, 2, 2] ):
  odeplot( sol,
           [ [r, U(r)], [r, V(r)], [r,X(r)], [r, Y(r)]],
             r=0..1,
             color=[red, blue, green ,black]
         );
#
# Supply another set of parameter values and
# plot the solution
#
  sol( parameters = [1, 2, 3] ):
  odeplot( sol,
           [ [r, U(r)], [r, V(r)], [r,X(r)], [r, Y(r)]],
           r=0..1,
           color=[red, blue, green ,black]
         );

Warning, cannot evaluate the solution further right of .64415942, probably a singularity

Warning, cannot evaluate the solution further right of .45598040, probably a singularity

>

Download odePars.mw

.

Not convinced...

Answered: tomleslie 13876

April 08 2019

0 2

that this PDE is separable, in either the original or simplified (with supplied time dependency) versions.

Output of the PDETools:-separability() command suggests otherwise.

This command returns the conditions which have to be satisfied in order for the PDE to be separable. So if it returns exactly 0 conditions, then PDE is separable. For your case the original PDE returns 3 (lengthy) conditions: the "simplified" version returns 1 condition

See the attached

>

>	interface(rtablesize=10):

>

Do := proc (f) options operator, arrow; diff(f, r, r)+(diff(f, phi, phi))/r^2-cos(phi)*(diff(f, phi))/(r^2*sin(phi)) end proc

>

diff(diff(f(t, r, phi), r), r)+(diff(diff(f(t, r, phi), phi), phi))/r^2-cos(phi)*(diff(f(t, r, phi), phi))/(r^2*sin(phi))

(1)

>

PDE := Do(Do(f(t, r, phi))-(diff(f(t, r, phi), t))/alpha)+sin(phi)*(diff(f(t, r, phi), r))*(diff(Do(f(t, r, phi))/(r^2*sin(phi)^2), phi))/alpha-(diff(f(t, r, phi), phi))*(diff(Do(f(t, r, phi))/(r^2*sin(phi)^2), r)) = 0

>

>	# # Check separability of original PDE. Returns # three conditions which would have to be met # for PDE to be separable # sep:=[PDETools:-separability(PDE, f(t,r,phi), `*`)]: numelems(sep);

(2)

>

#
# Simplify the PDE using an explicit time function
#
  PDE2:=simplify(expand(subs( f(t,r,phi)=exp(-lambda^2*alpha*t)*g(r,phi), PDE))):
#
# Check the separability of this simplified PDE
#
# Still doesn't separate - one condition left
#
  sep:=[PDETools:-separability(PDE2, g(r,phi), `*`)]:
  numelems(sep);

(3)

>

Download PDEIssue.mw

You cannot use...

Answered: tomleslie 13876

April 08 2019

1 0

the boundary condition

theta(infinity) = 0

when looking for the nummeric solution to an ODE. Just change it ot something like

theta(100) = 0

as in the attached

>

restart;

>	interface(rtablesize=10):

>	BVP1 := { diff( theta(eta), eta, eta) +2 * eta * diff(theta(eta), eta), theta(infinity) = 0, theta(0) = 1 }; #Analytically: sol1 := dsolve(BVP1); plot( rhs(sol1), eta=0..10);

{diff(diff(theta(eta), eta), eta)+2*eta*(diff(theta(eta), eta)), theta(0) = 1, theta(infinity) = 0}

>

#
# Define "infinity" as 100 to make
# the boundary condition
#
# theta(infinity) = 0
#
# usable in a "numerical" context
#
  inf:=100:
  BVP2 := { diff( theta(eta), eta, eta) +2 * eta * diff(theta(eta), eta), theta(inf) = 0, theta(0) = 1 }:
  sol:=dsolve(BVP2, numeric, maxmesh=1024);
  plots:-odeplot(sol, [eta, theta(eta)], eta=0..10);

>

Download odeProb.mw

Code executes...

Answered: tomleslie 13876

April 08 2019

0 5

with no errors - see the attached

Problem *may* be a Maple version issue. What version are you running?

>

restart:

>

interface(rtablesize=10):
kernelopts(version);
Physics:-Version();
with(geometry):
with(plots):
S:=segment:
L:=line:
Per:=PerpendicularLine:
R:=5: xA:=0: yA:=0:
point(A,xA,yA):
xI:=R/3:
yI:=0:
point(I1,xI,yI):
circle(C,[A,R]):
quadri:=proc(t)
              local xM,yM,xN,yN,xE,yE,dr1:
              xM:=evalf(R*cos(t)):
              yM:=evalf(R*sin(t)):
              point(M,xM,yM):
              L(lMI,[M,I1]):
              intersection('h',C,lMI,[M,N]):
              L(lAM,[A,M]):
              L(lAN,[A,N]):
              Per(lME,M,lAM):
              Per(lNE,N,lAN):
              intersection(E,lME,lNE):
              S(sAM,[A,M]):
              S(sAN,[A,N]):
              S(sME,[M,E]):
              S(sNE,[N,E]):
              dr1:=draw({lMI(color=blue),sAM(color=black),sAN(color=black),
                         sME,sNE}):
              display({dr1}):
         end:

dr:=draw({C},view=[-6..17,-10..6]):
display([dr,quadri(0.7),quadri(1),quadri(1.2)],view=[-6..17,-10..6]);

$"C:\Users\TomLeslie\maple\toolbox\2019\Physics Updates\lib\Physics Updates.maple", `2019, March 18, 10:15 hours, version in the MapleCloud: 344, version installed in this computer: 333.`$

>

Download geo.mw

A Caveat...

Answered: tomleslie 13876

April 08 2019

0 1

The help page at ?fsolve/details states (my emphasis), for the option 'fulldigits'

fulldigits
Prevent fsolve from decreasing Digits for intermediate calculations at high settings of Digits. With this option, fsolve may escape ill-conditioning problems, but is slower.

without specifying how "high" the setting of "Digits" has to be before reduction of accuracy for intermediate calculations is applied. I doubt that this is likely to affect your calculations, but it is probably safer to use the 'fulldigits' for fsolve() in your calculation.

Based on the desired number of digits (ND) , you can define an acceptable "tolerance" as 1.0*10^-ND, but this will no take account of "rounding" in intermediate calculations, so a better definition of the tolerance might be 1.0*10^-ND-2.

The just keep incrementing the setting of Digits until the difference between the value obtained with the current setting and that obtained with the previous setting is less than the specified tolerance. Once this criterion is met, round the value obtained to the desired number of digits. See the attached.

>

restart:

>

  interface(rtablesize=10):
#
# Specify required number of digits numDig
# so the "best case error" will be
#
# 1.0*10^(-numDig)
#
# However the worst case error may be
# substantially greater than this, due to
# rounding at every stage of the calculation
# so define the "desired" error to be a couple
# of digits better, as in
#
  numDig:= 10:
  eps:= 1.0*10^(-numDig-2):

  f:= 2*sin(x^2/2)-sin(1*x/2)^2:
  df:= diff(f,x):
  dff:= diff(f,x,x):
#
# Define a function whih computes the required
# quantity.Use the 'fulldigits' option to ensure
# that fsolve() is always using the current
# setting of Digits internally
#
  do_dff:= ()-> eval
                ( dff,
                  x = fsolve
                      ( df,
                        x = 1..2,
                        fulldigits
                      )
                ):
#
# Compute the desired answer using default
# Digits setting.
#
  old:= do_dff():
#
# Increment 'Digits' and repeat the calculation
# until the difference between the value on the
# current setting of Digits and that on the previous
# setting is less than the desired error
#
  for j from 1 do
      Digits:= Digits+1:
      new:= do_dff();
      if   abs(new-old) < eps
      then break
      else old:= new:
      fi:
  od:
#
# Out of idle curiosity, check the value of Digits
# where the error criterion was met, and the value
# obtained.
#
  Digits;
  new;
#
# Round the obtained value to the required number
# of Digits
#
  evalf[numDig](new);

(1)

>

Download dff10.mw

Version issue...

Answered: tomleslie 13876

April 07 2019

1 0

the code

assume(x, posint);
binomial(x, -1);
assume(x, Non(integer));
binomial(x, -1);

returns

0
0

in Maple 2017 and later versions: but returns

0
binomial(x~, -1)

in earlier versions. Before investigating furthr for a workaround, it would be useful to know precisely which Maple version your are running

As well as checking the addresses...

Answered: tomleslie 13876

April 07 2019

0 0

you can use the about() function which will show (for your example) that the two instances of the variable 'b' have different associated assumptions.

Should additionally() work this way - well I can think of arguments for and against. But it is certainly a trap for the unwary!

A couple of useful general rules

If you are going to make assumptions on variables in a worksheet, do all of them right at the start
Certain commands (such as solve() ) will ignore pre-existing assumptions unless you invoke the 'useassumptions' option

Like this ?...

Answered: tomleslie 13876

April 05 2019

0 1

>

restart;

>	# # Ignore this execution group. It is only necessary # to ensure that the worksheet displays "inline" on # the Mapleprimes website # interface(rtablesize=10):

>

#
# Define a vector of data. Becuase it is being
# generated one has to specify a "length" for the
# vector. However all subsequent commands in
# this worksheet work for any "length" of vector
#
# Note that rather than generating data, one could
# import a vector from Excel using ExcelTools:-Import(),
# or from a lot of other formats using ImportVector()
#
  V:=LinearAlgebra:-RandomVector(2880):
#
# Do it the easy way with commands from the
# statistics package
#
  Statistics:-Mean(V);
  Statistics:-Variance(V);
  Statistics:-StandardDeviation(V);
#
# Do it the hard way - from "first principles"
#
  evalf(add(V)/numelems(V));
  evalf(add((i-%)^2, i in V)/(numelems(V)-1));
  sqrt(%);

(1)

Download stats1.mw

In order to have a matrix with "blank" entries, you need to use 'NULL', as in th following

>

restart:

>	# # Ignore this execution group. It is only necessary # to ensure that the worksheet displays "inline" on # the Mapleprimes website # interface(rtablesize=10):

>	# # Define a matrix with 'NULL' entries # M:=Matrix(3,3,(i,j)->`if`(i=j,i+j, NULL));

"[[[2,,],[,4,],[,,6]]]"

(1)

>	# # Access entries of M # M[1,1]; # returns 2 M[1,2]; # returns nothing at all

(2)

>

Download nullMat.mw

Errrrrr...

Answered: tomleslie 13876

April 03 2019

0 0

and you can display results within a Maple worksheet, or (assuming that they are 2-dimensional) can be easily exported to Excel, so I don't really understand the issue. A few possible pointers

If commands are terminated with a colon character (ie ':') then output will be generated but not displayed, which controls the problem of "screenfuls" of output. If you definitely want out to be displayed then terminate commands with a semicolon character (ie ';')
By default Maple will not display 2D structures grater than 10 X 10. Again this is to avoid the issue of "screenfuls" of output. This limit can be overridden by using the interface(rtablesize) command
The ExcelTools:-Export() command will export most 2-D data structures in Excel format

What else do you need??

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

Ask a Question

Create a Post

13876 Reputation

20 Badges

MaplePrimes Activity

These are answers submitted by tomleslie

As Carl said...

Can't be done...

You can do a coordinate transformation...

What am I missing??...

A couple of typos...

Supplied worksheet has two problems...

Since you have an IVP,...

Not convinced...

You cannot use...

Code executes...

A Caveat...

Version issue...

As well as checking the addresses...

Like this ?...

Errrrrr...

Save this setting as your default sorting preference?

Ask a Question

Create a Post

Generating PDF…

Save this setting as your default sorting preference?
Note: You can change your preference any time in your account settings
Don't show this again