tomleslie

Observation...

Answered: tomleslie 13876

March 04 2019

1 0

Your examples *seem* to be working for me using Maple 2018.2, Physics Version 319 on 64-bit Windows 7 (see attached). Solutions are obtained, in reasonable time although they are a bit "ugly"

You refer to Maple 2018.2.1. Is that a typo? If I "check for updates" my Maple 2018.2 appears to be the "latest and greatest."

>

kernelopts(version);
Physics:-Version();
#now not solved or hangs, before it was solved in 7 seconds
pde := diff(u(x, t), t) = (1/20)*(diff(u(x, t), x$2))+t;
bc := u(0, t) = 5, (u(1, t)+ eval( diff(u(x,t),x),x=1)) = 10;
ic:= u(x, 0) = -40*x^2/3+45*x/2+5;
pdsolve([pde, bc,ic], u(x, t));

#now it hangs, before it was solved in 0.2 seconds
pde := (A*y^2+B*x^2-a^2*B)*diff(w(x,y),x)+(C*y^2+2*B*x*y)*diff(w(x,y),y) = 0;
pdsolve(pde,w(x,y));

#now hangs when it was solved before in 5 seconds
pde := 2*diff(w(x,y),x)+((lambda+a-a*sin(lambda*x))*y^2 +lambda -a -a*sin(lambda*x))*diff(w(x,y),y) = 0;
pdsolve(pde,w(x,y));

#now hangs when it was solved before in 1.8 seconds
pde := diff(w(x,y),x)+((lambda+a*sin(lambda*x)^2)*y^2 + lambda -a +a*sin(lambda*x)^2)*diff(w(x,y),y) = 0;
pdsolve(pde,w(x,y));

$"C:\Users\TomLeslie\maple\toolbox\2018\Physics Updates\lib\Physics Updates.maple", `2019, March 4, 8:53 hours, version in the MapleCloud: 319, version installed in this computer: 319.`$

diff(u(x, t), t) = (1/20)*(diff(diff(u(x, t), x), x))+t

u(0, t) = 5, u(1, t)+eval(diff(u(x, t), x), {x = 1}) = 10

$u(x, t) = `casesplit/ans`(Sum((80/3)*exp(-(1/20)*lambda[n]^2*t)*sin(lambda[n]*x)*(lambda[n]^2*cos(lambda[n])+lambda[n]*sin(lambda[n])+4*cos(lambda[n])-4)/(lambda[n]^2*(sin(2*lambda[n])-2*lambda[n])), n = 0 .. infinity)+Int(Sum(4*exp(-(1/20)*lambda[n]^2*(t-tau))*sin(lambda[n]*x)*tau*(cos(lambda[n])-1)/(sin(2*lambda[n])-2*lambda[n]), n = 0 .. infinity), tau = 0 .. t)+(5/2)*x+5, {And(tan(lambda[n])+lambda[n] = 0, 0 < lambda[n])})$

(1)

>

Download pdeProbs.mw

Refinements...

Answered: tomleslie 13876

March 03 2019

2 8

Pretty much the same as before, except that

pointplots are "normalised", you may or may not want this but it is useful/necessary when comparing with Statistics:-Histogram() plots
tidied up the Statistics:-Histogram() plots provided by mmcdara to remove the inconsistent gaps
overlay pointplots and histograms to show that it doesn't really matter which way you do it - it's all down to personal preference

Check the attached

>

  restart;
  with(plots):
#
# Define the number of faces on the dice
# (obvously 6 is a good bet, but you can
# have any number you want), and the number
# of trials (ie number of times you are going
# to throw the dice
#
  nFaces:= 10:
  nTrials:= 10000:
#
# Randomize the seed so that we don't get the
# the same answer every time this code is run
#
  randomize:
#
# Set up a couple of random variables
#
  dice1:= rand(1..nFaces):
  dice2:= rand(1..nFaces):
#
# Define some 'functions' of these random
# variables
#
  f:= ()-> [ dice1(), dice2() ]:
  g:= ()->   dice1()+dice2():
  h:= ()->   dice1()^2+dice2():
#
# run a lot of trials with these functions
#
  s0:= [seq( f(), j=1..nTrials)]:
  s1:= [seq( g(), j=1..nTrials)]:
  s2:= [seq( h(), j=1..nTrials)]:
#
# Plot the results of these trials in a
# more-or-less meaningful way
#
  p0:= pointplot
       ( s0,
         symbol=solidcircle,
         symbolsize=14,
         color=red,
         size=[1000, 500]
       );
p1:= pointplot
      ( [ seq
          ( [j, numboccur(s1, j)/nTrials],
            j = min(s1)..max(s1)
          )
        ],
        symbol=solidcircle,
        symbolsize=14,
        color=red,
        size=[1000, 500]
      );
p2:= pointplot
      ( [ seq
          ( [ j, numboccur(s2, j)/nTrials ],
            j = min(s2)..max(s2)
          )
        ],
        symbol=solidcircle,
        symbolsize=12,
        color=red,
        size=[1000, 500]
      );

>	with(Statistics): statplot:= z-> Histogram( z, binbounds=[seq( j+1/2, j=min(z)-1..max(z))]): display([p1,statplot(s1)]); display([p2,statplot(s2)]);

>

Download probStuff2.mw

Keeping it simple...

Answered: tomleslie 13876

March 03 2019

2 4

You can achieve all of the requirements of your post without even invoking the Statistics() package. I'm not knocking the latter, you should just be aware of the alternatives in the attached.

Before you get excited about the following, it was run with 10-faced dice (I was testing!) . Just set nFaces:=6 and re-execute if you want to be boring and conventional :-)

>

  restart;
  with(plots):
#
# Define the number of faces on the dice
# (obvously 6 is a good bet, but you can
# have any number you want), and the number
# of trials (ie number of times you are going
# to throw the dice
#
  nFaces:= 10:
  nTrials:= 10000:
#
# Randomize the seed so that we don't get the
# the same answer every time this code is run
#
  randomize:
#
# Set up a couple of random variables
#
  dice1:= rand(1..nFaces):
  dice2:= rand(1..nFaces):
#
# Define some 'functions' of these random
# variables
#
  f:= ()-> [ dice1(), dice2() ]:
  g:= ()->   dice1()+dice2():
  h:= ()->   dice1()^2+dice2():
#
# run a lot of trials with these functions
#
  s0:= [seq( f(), j=1..nTrials)]:
  s1:= [seq( g(), j=1..nTrials)]:
  s2:= [seq( h(), j=1..nTrials)]:
#
# Plot the results of these trials in a
# more-or-less meaningful way
#
  pointplot
  ( s0,
    symbol=solidcircle,
    symbolsize=14,
    color=red,
    size=[1000, 500]
  );
  pointplot
  ( [ seq
      ( [j, numboccur(s1, j)],
        j = min(s1)..max(s1)
      )
    ],
    symbol=solidcircle,
    symbolsize=14,
    color=red,
    size=[1000, 500]
  );
  pointplot
  ( [ seq
      ( [ j, numboccur(s2, j) ],
        j = min(s2)..max(s2)
      )
    ],
    symbol=solidcircle,
    symbolsize=12,
    color=red,
    size=[1000, 500]
  );

>

Download probStuff.mw

Workaround(?)...

Answered: tomleslie 13876

March 03 2019

0 0

Mutable sets seem to be one of these curious entities which work better with a "ModuleIterator".

The attached code will perform the operation you want in reasonable time (~ 5secs) on my machine

>

  N:=900000:
  C := CodeTools:-Usage(MutableSet(seq(i^2, i = 1 .. N))):
  manIP:= proc( CC )
                local hasNext, getNext, old, new, ans;
                hasNext, getNext := ModuleIterator(CC);
                old := getNext();
                ans := MutableSet();
                while hasNext() do
                      new := getNext();
                      insert(ans, new-old);
                      old := new
                end do;
                return ans;
         end proc:
  res:=CodeTools:-Usage(manIP(C));

memory used=116.60MiB, alloc change=35.35MiB, cpu time=1.79s, real time=1.49s, gc time=702.00ms

memory used=130.48MiB, alloc change=0 bytes, cpu time=6.33s, real time=5.57s, gc time=2.25s

(1)

>

Download mutSet.mw

I made it to the third line before my ey...

Answered: tomleslie 13876

March 02 2019

1 1

So let us just consider what it is intended by the line

D[0](y):=1;

If this were instead D[1](y):=1; it would mean diferentiate 'y' with respect to its first argument (eg if y=y(p,q,r), then differentiate with respect to p) and assign '1' to the result.

This gives a problem with D[0](y):=1; Do you want to differetniate 'y' with respect to its zeroth argument??? Does any function have a 'zeroth' argument. If this is difficult for you to understand then consider y(p,q,r): 'p' is the first argument, 'q' is the second argument and 'r' is the third argument - so explain clearly, what is the 'zeroth' argument.

So why doesn't this staement produce a syntax error? Well, Maple is being kind! It assumes that you want to supply the argument 'y' to the 'zeroth' entry of the indexable quantity (ie table or array) 'D'. Now it is possible to do this, although since 'D' is a protected name in Maple, creating an indexable quantity 'D' containing functions which accept arguments is possible (but undesirable unless you really know what you are doing - which you obviously don't)

The supplied code goes downhill from this point onwards: I simply have no idea what you are trying to achieve. As I see it you have two options

Explain your problem in English (ie no code) and someone may come up with an answer
Learn enough basic coding to distinguish between assignments, equations, expressions and functions (cos they are all different). Then rewrite your code; if it still doesn't work, post it here: if it has improved sufficiently, someone may be able to work out what you are trying to do

By far the fast way to solve this proble...

Answered: tomleslie 13876

March 01 2019

0 4

is to apply a little thought!

The attached shows the results of "thinking" and the results of "simulating" (ie not thinking). The latter takes considerably longer to execute, and only provides an approximation. NB if you re-execute this code multiple times, the 'simulation' part will give a (slightly) different answer each time

>	restart; # # Using logical thought # sum(6/k, k=1..6);

(1)

>

#
# Using a simulation to roll the dice and counting
# how many throws until all 6 values have appeared
#
  randomize():
  roll:= rand(1..6):
  nthrows:= NULL;
  for k from 1 by 1 to 10000 do
      throws:= {};
      for j from 1 do
          throws:= throws union {roll()};
          if   numelems(throws)=6
          then break
          fi
      od:
      nthrows:= nthrows, j;
  od:
  evalf(add([nthrows])/numelems([nthrows]));

(2)

>

Download diceProb.mw

Missing commas...

Answered: tomleslie 13876

March 01 2019

0 0

in the definition of params:=[];

See the attached

A warning - it is generally bad practice to use the same name with and without indexing, as in mu[c] and mu^(2)[1]. I also doubt that the latter will return what you actually want - check it !!

>

Warning, The imaginary unit, I, has been renamed _I

>

#
# Set up numerical values for all problem parameters
#
  params:=[       gamma=0.142,        tau=0.112,      mu[1]=0.4e-3,
                  beta[1]=0.081, b[h]=10, psi=0.011, phi=0.05,
            epsilon=0.2e-2,     rho=0.5e-1, beta[2]=0.092, beta[o]=0.034,
                    q=.5,      eta=0.213,   M[h]=100,
              delta=0.021,       alpha=0.57e-1,   p=.2,   beta[k]=0.025,
               omega=0.056,      mu[c]=0.0019, (mu)^(2)[1]=0.091
          ];

[gamma = .142, tau = .112, mu[1] = 0.4e-3, beta[1] = 0.81e-1, b[h] = 10, psi = 0.11e-1, phi = 0.5e-1, epsilon = 0.2e-2, rho = 0.5e-1, beta[2] = 0.92e-1, beta[o] = 0.34e-1, q = .5, eta = .213, M[h] = 100, delta = 0.21e-1, alpha = 0.57e-1, p = .2, beta[k] = 0.25e-1, omega = 0.56e-1, mu[c] = 0.19e-2, mu^2[1] = 0.91e-1]

(1)

>	# # Define main function # R := sqrt((omega+mu[1]+eta)mu[1]mu[c]psibeta[o]M[h]^2(delta+mu[1]+eta+phi[1])(`ε`+mu[1])omegabeta[k] (1/((omega+mu[1]+eta)(`ε`+mu[1])mu^2)))

>	# # Compute "all" derivatives and evaluate numerically.

>

Download missingCommas.mw

First of all...

Answered: tomleslie 13876

February 27 2019

3 0

I would advise against doing this - the following are (probably?) better options

If you want Matlab code - write it in Matlab.
If you want Maple code - write it in Maple
If you need a symbolic capability in Matlab (and don't want to pay for the Matlab Symbolic Toolbox) then you can install a ("stripped-down") version of Maple as a symbolic toolbox within Matlab. To do this you need to run the toolbox installer file MapleToolbox2018.0WindowsX64Installer.exe which is located within your Maple install directory (probably C:\Program Files\Maple 2018 on a Windows machine). You can check for successful installation of this toolbox, by starting Matlab, accessing the Matlab help and checking the left-hand "Contents" pane. Under the "Supplemental Software" sub-heading, you should see "Maple Toolbox". Clicking on this will take you to the help for the Maple toolbox within Matlab

Having said all of the above if you really, really, REALLY want to write code in Maple and translate it to Matlab, then it is possible, provided you are careful about what can and cannot be successfully translated. I don't have an exhaustive list for this, just some pointers to areas which (often?) cause issues

Output to terminal: I would stick with very simple 'printf' statements, and don't even attempt to use anything "graphic" such as a Maple plot() function
Lists: anything in Maple enclosed in '[]' is probably going to causee problems

When I tried to translate your code, I got warning messages about both of the above, so in the attached I have "lightly" edited your code to remove all translation error/warning messages. Whether or not the resulting function will actually now run in Matlab is probably dependent on how you are going to define/supply the first argument to the procedure. In Maple, this argument is a symbolic function - so how do plan to supply a 'symbolic function' to the Matlab procedure?? A second issue is that within Maple, your procedure contains no "return" statements, so the procedure never returns anything (although it will "print"). Obtaining results from a procedure in either Maple or Matlab by "printing" them rather than "returning" them is seriously sloppy

Anyhow for what it is worth, the attached is probably about as far as I can go for now.

>

  restart:
  with(plots):
  bisect:= proc( f, intbeg::numeric, intend::numeric, ss::float, del::float)
                 local Num_points,limit1,approx,i,x1,x2,a,b,flag1,pet,A,B,NewApprox,CheckIt,newDelta,
                       interval_begin,interval_end,step_size,delta, y_approx, y_A, y_New;

                 interval_begin:=intbeg:
                 interval_end:=intend:
                 step_size:=ss:
                 delta:=del:
                 Num_points:=0:
                 printf("%12s %12s\n", x,y);
                 limit1:=200:

                 for i from interval_begin by step_size to interval_end do
                     x1:=i:
                     x2:=i+step_size:
                     if   x1=0
                     then x1:=-10^(-5)
                     fi:
                     if   x2=0
                     then x2:=-10^(-5)
                     fi:
                     a := evalf( f(x1) ):
                     b := evalf( f(x2) ):
                     if   a=0
                     then a:=-10^(-5)
                     fi:
                     if   b=0
                     then b:=-10^(-5)
                     fi:
                     flag1:=0:

                     if   evalf(a*b) <= 0
                     then approx := (x1+x2)/2:
                          y_approx := evalf( f(approx) ):
                          if   abs(y_approx) < delta
                          then printf("%12.8f %12.8f\n", approx, y_approx):
                               Num_points:=Num_points+1:
                          else pet:=0:
                               A:=x1:
                               B:=x2:
                               while pet=0 do
                                     NewApprox:=(A+B)/2:
                                     y_A := evalf( f(A) );
                                     y_New := evalf( f(NewApprox) );
                                     CheckIt := y_A * y_New:
                                     newDelta:=abs( y_A - y_New ):
                                     flag1:=flag1+1:

                                     if   newDelta <= delta
                                     then printf( "%12.8f %12.8f\n", NewApprox, y_New):
                                          pet:=1:
                                          Num_points:=Num_points+1:
                                     elif CheckIt > 0 then
                                          A:=NewApprox;
                                     else B:=NewApprox;
                                     fi:
                                     if   flag1 > limit1
                                     then pet:=1:
                                          printf("*** Exceeds limits****");
                                     fi:
                               od:
                          fi:
                     fi:
                 od:
                 printf("Number of Roots Found = %d\n",Num_points):
             end:

>	f:=x->2-x^2: int1:=1.0: int2:=2.0: bisect( x-> 2-x^2, int1, int2, 0.1, 0.1); plot(f, int1..int2, color=red, thickness=1);

x y
1.42500000 -0.03062500
Number of Roots Found = 1

>	# # do the same calculation the "easy" way # just as a check # fsolve( f, 1..2); plot(f, 1..2);

>	# # Generate Matlab code and output to the terminal, just # to make sure that all errors/warnings have been cleared # CodeGeneration:-Matlab(bisect);

function bisectreturn = bisect(f, intbeg, intend, ss, del)
  interval_begin = intbeg;
  interval_end = intend;
  step_size = ss;
  delta = del;

  Num_points = 0;
  disp(sprintf('%12s %12s
',x,y));
  limit1 = 200;
  for i = interval_begin:step_size:interval_end
    x1 = i;
    x2 = i + step_size;
    if (x1 == 0.0e0)
      x1 = -0.1e1 / 0.100000e6;
    end
    if (x2 == 0.0e0)
      x2 = -0.1e1 / 0.100000e6;
    end
    a = (f(x1));
    b = (f(x2));
    if (a == 0.0e0)
      a = -0.1e1 / 0.100000e6;
    end
    if (b == 0.0e0)
      b = -0.1e1 / 0.100000e6;
    end
    flag1 = 0;
    if ((a * b) <= 0.0e0)
      approx = x1 / 0.2e1 + x2 / 0.2e1;
      y_approx = (f(approx));
      if (abs(y_approx) < delta)
        disp(sprintf('%12.8f %12.8f
',approx,y_approx));
        Num_points = Num_points + 1;
      else
        pet = 0;
        A = x1;
        B = x2;
        while (pet == 0)
          NewApprox = A / 0.2e1 + B / 0.2e1;
          y_A = (f(A));
          y_New = (f(NewApprox));
          CheckIt = y_A * y_New;
          newDelta = abs(y_A - y_New);
          flag1 = flag1 + 1;
          if (newDelta <= delta)
            disp(sprintf('%12.8f %12.8f
',NewApprox,y_New));
            pet = 1;
            Num_points = Num_points + 1;
          elseif (0.0e0 < CheckIt)
            A = NewApprox;
          else
            B = NewApprox;
          end
          if (limit1 < flag1)
            pet = 1;
            disp(sprintf('*** Exceeds limits****'));
          end
        end
      end
    end
  end
  disp(sprintf('Number of Roots Found = %d
',Num_points));

>	# # Generate Matlab code and output to the specified file # OP will have to change filepath to something appropriate # for his/her machine # CodeGeneration:-Matlab(bisect, output="C:/Users/TomLeslie/Desktop/bisect.m");

>

Download toMat.mw

I'm not completely clear on this...

Answered: tomleslie 13876

February 26 2019

2 0

I am assuming that if you start with {1, 19, 23, 29} , then after one iteration you want {1, 13, 17, 23, 29} and then {1, 7, 11, 13, 17, 19, 23, 29}, then stop

If this is the case then the attached shows two ways to do it. The firstalgorithm follows (more-or-less) the logic you describe, so should be relatively easy to understand. However, depending on values in the starting set, the execution time can get a little painful.

The second algorithm is somewhat(?) less obvious way to do the same calculation, but is a *lot* faster and uses way less memory.

The choice is yours!!

>	restart; # # Define a couple of sets for test purposes # set1:={1, 19, 23, 29}: set2:={1, 19, 23, 10001}:

>

#
# Procedure which performs required operation
# using the (more-or-less) the logical process
# which OP specified
#
  getSet:= proc( S::set)
                 local f:= (aSet::set) ->`union`(aSet, remove( i->i<6, aSet-~6)),
                       oldSet:= S,
                       newSet;
                 while true do
                       newSet:= f(oldSet);
                       if   newSet minus oldSet={}
                       then return newSet
                       else oldSet:= newSet;
                       fi;
                 od:
           end proc:
#
# Run tests (suppress output from the second
# becuase it's a bit lengthy
#
  ans1:=CodeTools:-Usage(getSet( set1));
  ans2:=CodeTools:-Usage(getSet( set2 )):

memory used=5.20KiB, alloc change=0 bytes, cpu time=0ns, real time=1000.00us, gc time=0ns

memory used=117.66MiB, alloc change=88.49MiB, cpu time=764.00ms, real time=746.00ms, gc time=78.00ms

>

#
# A somewhat "less obvious" way to get the same results
#
# Note that (for the second test set) this is much faster,
# less memory, etc. Just all round more "efficient"
#
  f:= z-> {seq( r+j*6, j=1..iquo(z, 6, 'r'))}:
  ans3:=CodeTools:-Usage(`union`( set1, f~( set1 )[]));
  ans4:=CodeTools:-Usage(`union`( set2, f~( set2 )[])):

memory used=2.54KiB, alloc change=0 bytes, cpu time=0ns, real time=1000.00us, gc time=0ns

memory used=28.38KiB, alloc change=0 bytes, cpu time=0ns, real time=1000.00us, gc time=0ns

>	# # Verify that both methods give the same results # ans3 minus ans1; ans4 minus ans2;

(1)

>

Download setProb.mw

Welll...

Answered: tomleslie 13876

February 25 2019

2 0

You will still have to supply all values for the variable 'n_i' and the right-hand sides of the equations, because they seem to be fairly random integers, but you can still save a lot of typing of equations by using something like the attached

Download solEq.mw

Guessed from your username...

Answered: tomleslie 13876

February 24 2019

1 1

that you might be running Maple 2015, so I checked in this version after downloading your datafile to my desktop. No problems reading the file or executing your code. To re-execute the attached you will have to change the filepath in the ReadFile() command to something appropriate for your machine

Rather oddly, the interface(displayprecision=10) command is obeyed when this worksheet is executed in Maple, but after uploading here, the displayed precision reverts to that determined by the setting of Digits. No idea why this happens - quirk of this website

>

restart;

>	# # Show version # kernelopts(version);

(1)

>	# # Do calculations to the precision set by Digits # Digits:=150:

>	# # But control the output display so that it only # shows ten digits - just because displaying 150 # digits is a bit painful # interface(displayprecision=10):

>	# # Read file, do sums # M:=parse(FileTools[Text][ReadFile]("C:/Users/TomLeslie/Desktop/data1.txt")): LinearAlgebra:-Determinant(M): fsolve(%,P=0..0.5)*100;

(2)

>

Download detRoots.mw

Your worksheet...

Answered: tomleslie 13876

February 24 2019

1 5

has 14 equations in 15 unknowns - I demonstarte this in the attached

I have added an execution group at the end, where I have (crudely) modified you for-loop so that I can get all the equations into a single list. First good sign is that I now have 15 equations in 15 unknowns

I also added an fsolve() command which returns floating point values for all variables

>

(1)

>

X := sum(sum(a[n][m]*phi[n][m](x), m = 0 .. M-1), n = 1 .. 2^(k-1))

(2)

>

H[1] := sum(sum(b[n][m]*phi[n][m](x), m = 0 .. M-1), n = 1 .. 2^(k-1))

(3)

>

H[2] := sum(sum(C[n][m]*phi[n][m](x), m = 0 .. M-1), n = 1 .. 2^(k-1))

(4)

>

Y := sum(sum(e[n][m]*phi[n][m](x), m = 0 .. M-1), n = 1 .. 2^(k-1))

(5)

>

Z := sum(sum(g[n][m]*phi[n][m](x), m = 0 .. M-1), n = 1 .. 2^(k-1))

(6)

>

(7)

>

(8)

>

(9)

>

(10)

>

(11)

>

2.655811239*a[1][1]-8.683397306*a[1][2]+.3*(a[1][0]-1.154700539*a[1][1]+.372677997*a[1][2])*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2])-.2*e[1][0]+.2309401078*e[1][1]-0.745355994e-1*e[1][2]+.7*a[1][0] = .5

2.309401077*b[1][1]-8.571593907*b[1][2]-.3*(a[1][0]-1.154700539*a[1][1]+.372677997*a[1][2])*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2])+.3*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2])*(C[1][0]-1.154700539*C[1][1]+.372677997*C[1][2])+1.0*b[1][0] = 0

.461880215*C[1][1]-7.975309112*C[1][2]-.3*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2])*(C[1][0]-1.154700539*C[1][1]+.372677997*C[1][2])+2.6*C[1][0] = 0

3.464101616*a[1][1]+.3*(a[1][0]-1.118033988*a[1][2])*(b[1][0]-1.118033988*b[1][2])-.2*e[1][0]+.2236067976*e[1][2]+.7*a[1][0]-.7826237916*a[1][2] = .5

3.464101616*b[1][1]-.3*(a[1][0]-1.118033988*a[1][2])*(b[1][0]-1.118033988*b[1][2])+.3*(b[1][0]-1.118033988*b[1][2])*(C[1][0]-1.118033988*C[1][2])+1.0*b[1][0]-1.118033988*b[1][2] = 0

3.464101616*C[1][1]-.3*(b[1][0]-1.118033988*b[1][2])*(C[1][0]-1.118033988*C[1][2])+2.6*C[1][0]-2.906888369*C[1][2] = 0

4.272391993*a[1][1]+9.205146509*a[1][2]+.3*(a[1][0]+1.154700539*a[1][1]+.372677998*a[1][2])*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2])-.2*e[1][0]-.2309401078*e[1][1]-0.745355996e-1*e[1][2]+.7*a[1][0] = .5

4.618802155*b[1][1]+9.316949908*b[1][2]-.3*(a[1][0]+1.154700539*a[1][1]+.372677998*a[1][2])*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2])+.3*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2])*(C[1][0]+1.154700539*C[1][1]+.372677998*C[1][2])+1.0*b[1][0] = 0

6.466323017*C[1][1]+9.913234705*C[1][2]-.3*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2])*(C[1][0]+1.154700539*C[1][1]+.372677998*C[1][2])+2.6*C[1][0] = 0

(12)

>

#
# OP's original equations definition
#
equns:={2.655811239*a[1][1]-8.683397306*a[1][2]+(.3*(a[1][0]-1.154700539*a[1][1]+.372677997*a[1][2]))*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2])-.2*e[1][0]+.2309401078*e[1][1]-0.745355994e-1*e[1][2]+.7*a[1][0] = .5,2.309401077*b[1][1]-8.571593907*b[1][2]-(.3*(a[1][0]-1.154700539*a[1][1]+.372677997*a[1][2]))*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2])+(.3*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2]))*(C[1][0]-1.154700539*C[1][1]+.372677997*C[1][2])+1.0*b[1][0] = 0,.461880215*C[1][1]-7.975309112*C[1][2]-(.3*(b[1][0]-1.154700539*b[1][1]+.372677997*b[1][2]))*(C[1][0]-1.154700539*C[1][1]+.372677997*C[1][2])+2.6*C[1][0] = 0,1.039230484*e[1][1]-8.161648110*e[1][2]-.4*C[1][0]+.4618802156*C[1][1]-.1490711988*C[1][2]+2.1*e[1][0] = 0,2.655811239*g[1][1]-8.683397306*g[1][2]-1.2*e[1][0]+1.385640647*e[1][1]-.4472135964*e[1][2]+.7*g[1][0] = 0,2.655811239*g[1][1]-8.683397306*g[1][2]-1.2*e[1][0]+1.385640647*e[1][1]-.4472135964*e[1][2]+.7*g[1][0] = 0,3.464101616*b[1][1]-(.3*(a[1][0]-1.118033988*a[1][2]))*(b[1][0]-1.118033988*b[1][2])+(.3*(b[1][0]-1.118033988*b[1][2]))*(C[1][0]-1.118033988*C[1][2])+1.0*b[1][0]-1.118033988*b[1][2] = 0,3.464101616*C[1][1]-(.3*(b[1][0]-1.118033988*b[1][2]))*(C[1][0]-1.118033988*C[1][2])+2.6*C[1][0]-2.906888369*C[1][2] = 0,3.464101616*e[1][1]-.4*C[1][0]+.4472135952*C[1][2]+2.1*e[1][0]-2.347871375*e[1][2] = 0,3.464101616*g[1][1]-1.2*e[1][0]+1.341640786*e[1][2]+.7*g[1][0]-.7826237916*g[1][2] = 0,4.272391993*a[1][1]+9.205146509*a[1][2]+(.3*(a[1][0]+1.154700539*a[1][1]+.372677998*a[1][2]))*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2])-.2*e[1][0]-.2309401078*e[1][1]-0.745355996e-1*e[1][2]+.7*a[1][0] = .5,4.618802155*b[1][1]+9.316949908*b[1][2]-(.3*(a[1][0]+1.154700539*a[1][1]+.372677998*a[1][2]))*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2])+(.3*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2]))*(C[1][0]+1.154700539*C[1][1]+.372677998*C[1][2])+1.0*b[1][0] = 0,6.466323017*C[1][1]+9.913234705*C[1][2]-(.3*(b[1][0]+1.154700539*b[1][1]+.372677998*b[1][2]))*(C[1][0]+1.154700539*C[1][1]+.372677998*C[1][2])+2.6*C[1][0] = 0,5.888972748*e[1][1]+9.726895706*e[1][2]-.4*C[1][0]-.4618802156*C[1][1]-.1490711992*C[1][2]+2.1*e[1][0] = 0,4.272391993*g[1][1]+9.205146509*g[1][2]-1.2*e[1][0]-1.385640647*e[1][1]-.4472135976*e[1][2]+.7*g[1][0] = 0};
NumberOfEquations:=numelems(equns);
NumberOfUnknowns:=numelems(indets( equns));

(13)

>

{C[1][0] = 2.105295203, C[1][1] = .2909548367, C[1][2] = -.3502342475, a[1][0] = 0.9889801377e-1, a[1][1] = 0.4274378516e-1, a[1][2] = 0.4516101720e-2, b[1][0] = 11.01185501, b[1][1] = -4.973895862, b[1][2] = .8941055143, e[1][0] = -0.9631802686e-1, e[1][1] = .3014882510, e[1][2] = -0.6671128517e-1, g[1][0] = -8.985367719, g[1][1] = 1.782331021, g[1][2] = -.1143622028}

(14)

Download solEqs.mw

In Maple 2017 - just use solve()...

Answered: tomleslie 13876

February 22 2019

0 1

expression is polynomial, so solve should return all roots - it is a good idea to then use evalc() to check for potentailly complex roots.

See the attached

>	Student:-Calculus1:-Roots((x-1)(x^3-9x^2+4), x); evalf(%);

[1, 6*cos((1/3)*arctan((2/25)*26^(1/2)))+3]

(1)

>	restart; # # Verify Maple 2017 # kernelopts(version); # # Straightforward solution of OP's expression # - it's a polynomial sol solve() ought to return # all 'roots' solve((x-1)(x^3-9x^2+4)); evalc~([%]); evalf~(%);

1, (25+(2*I)*26^(1/2))^(1/3)+9/(25+(2*I)*26^(1/2))^(1/3)+3, -(1/2)*(25+(2*I)*26^(1/2))^(1/3)-(9/2)/(25+(2*I)*26^(1/2))^(1/3)+3+((1/2)*I)*3^(1/2)*((25+(2*I)*26^(1/2))^(1/3)-9/(25+(2*I)*26^(1/2))^(1/3)), -(1/2)*(25+(2*I)*26^(1/2))^(1/3)-(9/2)/(25+(2*I)*26^(1/2))^(1/3)+3-((1/2)*I)*3^(1/2)*((25+(2*I)*26^(1/2))^(1/3)-9/(25+(2*I)*26^(1/2))^(1/3))

[1, 6*cos((1/3)*arctan((2/25)*26^(1/2)))+3, -3*cos((1/3)*arctan((2/25)*26^(1/2)))+3-3*3^(1/2)*sin((1/3)*arctan((2/25)*26^(1/2))), -3*cos((1/3)*arctan((2/25)*26^(1/2)))+3+3*3^(1/2)*sin((1/3)*arctan((2/25)*26^(1/2)))]

(2)

>

Download getRoots.mw

If I save your excel shhet to my desktop...

Answered: tomleslie 13876

February 21 2019

1 0

which is "C:/Users/TomLeslie/Desktop" and then execute

ExcelTools:-Import("C:/Users/TomLeslie/Desktop/Excell_Sheet.xlsx");

I can read the Excel data into Maple - so I am not sure exactly what the problem is??

A caveat: the Excel worksheet you supply contains lots of "merged" cells which are tricky to deal with if you are importing to a Matrix format. Maple will essentially un-merge (is that a word??) the cells and "pack" the "missing" entries with zeros. This could(?) make subsequent data access to the Matrix a bit awkward.

See the attached worksheet for what works - obviously the file path will have to be changed to something appropriate for your machine. (BTW the double 'l' on the end of the string Excel inthe file name is a neat touch - I'd be embarrassed if I had to admit how long it took me to spot why loading "Excel_Sheet.xlsx" didn't work, because I needed "Excell_Sheet.xlsx"

Download getXL.mw

It's a version issue...

Answered: tomleslie 13876

February 21 2019

0 0

By default in Maple 2015 and 2016 'Typesetting level' is set to 'Standard' and 'infinity' is returned

By defualt in Maple 2017 and 2018 'Typesettinglevel is set to 'Extended' and the symbol for infinity is returned

So if you are using Maple 2015 or 2016 change the menu setting at

Tools->Options->Display->TypeSetting level to 'Extended'

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

Ask a Question

Create a Post

13876 Reputation

20 Badges

MaplePrimes Activity

These are answers submitted by tomleslie

Observation...

Refinements...

Keeping it simple...

Workaround(?)...

I made it to the third line before my ey...

By far the fast way to solve this proble...

Missing commas...

First of all...

I'm not completely clear on this...

Welll...

Guessed from your username...

Your worksheet...

In Maple 2017 - just use solve()...

If I save your excel shhet to my desktop...

It's a version issue...

Save this setting as your default sorting preference?

Ask a Question

Create a Post

Generating PDF…

Save this setting as your default sorting preference?
Note: You can change your preference any time in your account settings
Don't show this again