Interesting. I am still doubtful this will do what I need, but I'm willing to give it a try.

Consulting the online help, I come across the following example in the help for InstallerBuilder,General,Panels:

with(InstallerBuilder):
Build( "SampleToolbox",
    'uninstaller' = false,
    'author'      = "Some Maple User",
    'welcome'     = ['text' = "Welcome to the SampleToolbox installer"],
    'validation'  = [
         'text'     = "Enter the code below:",
         'validate' = proc()
              local code;
              code := ToolboxInstaller:-Data:-Get("validation_attempt");
              if code = "My Secret Code" then
                  true
              else
                  false
              end if;
         end proc
    ]
);

When I execute this, all I see is the following warning message:

Warning, InstallerBuilder is not a correctly formed package - option `package' is missing

I am running Maple 11.01 with the standard interface, worksheet and 1-D Maple input. Does any of this matter?
Am I missing something? Does this work for anyone?

It's still not clear to me that this will do what I want, but it could be a start. I will try to put together a sammple set of files and see if someone can create a single file to do what I have tried to describe.

More to follow soon,

Doug

---------------------------------------------------------------------
Douglas B. Meade
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu       
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu/~meade/

Now that I have taken a little time to better understand libraries and archives I finally understand acer's post. There were a couple of typos and I believe I have made some (minor) improvements.

Here is my current code:

restart;
if StringTools[Search]( "Linux", interface(version) )>0 then
  DOT := ".//";
else
  DOT := cat(currentdir(),"/");
end if:

try
  FileTools[Remove](cat(DOT,"/SimpleTest.mla"));
catch:
#  WARNING( "There was no previous MLA to remove. Proceeding." );
end try:

LibraryTools:-Create("SimpleTest.mla");
march('addfile', DOT, cat(DOT,"files/PrimesBack.jpg"), "PrimesBack.jpg");

initproc:=proc()
local found, maplet, x, IMAGELOC, TEMPDIR, IsValidDirectory;
    TEMPDIR := getenv(TEMP);
    IsValidDirectory := d -> evalb( d<>"" and FileTools[Exists](d) and FileTools[IsDirectory](d) );
    if not IsValidDirectory(TEMPDIR) then
        TEMPDIR:=cat(kernelopts(homedir),"/Temp/");
        if not IsValidDirectory(TEMPDIR) then
           error "unable to find directory for temp files";
        end if;
    end if;
    IMAGELOC := cat(TEMPDIR,"PrimesBack.jpg");
    found:=false;
    for x in libname while not found do
       try
          march('extractfile', x, "PrimesBack.jpg", IMAGELOC);
          found := true;
        catch:
       end try;
    end do;
    if not found then
        error "a problem occurred while attempting to extract the temp files."
    end if;
    use Maplets[Elements] in
    maplet := Maplet(
     [
       Label(Image(IMAGELOC)),
       "Did this maplet show an image stolen from the MaplePrimes website?",
       [
         HorizontalGlue(),
         Button("Yes", Shutdown("Image was shown")),
         Button("No ", Shutdown("Image was not shown")),
         HorizontalGlue()
       ]
     ] ):
    Maplets[Display](maplet);
    end use;
    try
        FileTools:-Remove(IMAGELOC);
    catch:
        error "a problem occurred while attempting to delete the temp files."
    end try;
end proc:
LibraryTools:-ActivationModule(cat(DOT,"SimpleTest.mla"),initproc);

The main changes I made were:

1. began to provide cross-platform support (not thoroughly tested)
2. fixed spelling of FileTools in Remove
3. add the image with an indexname that is related to the image
4. created local proc to clean up checking for a valid directory

This library archive is now posted on my personal website. It can be accessed at the URL http://www.math.sc.edu/~meade/TEST/SimpleTest.mla.
Compare this to the original MLA created with InstallerBuilder.

Not only is the installation cleaner, but the new MLA file is less than half the size of the original one. (It is still almost twice the size of the two files needed to run the maplet locally.)

I do have one more desire. I would like to have the maplet open without any visual interference from the Maple interface.

FAST FORWARD ONE HOUR

A way to achieve this occurred to me while I was teaching. This is interesting enough that I will post it in a separate blog entry. It will appear as soon as it is composed.

Doug

---------------------------------------------------------------------
Douglas B. Meade
Math, USC, Columbia, SC 29208  E-mail: mailto:meade@math.sc.edu       
Phone:  (803) 777-6183         URL:    http://www.math.sc.edu/~meade/