To reasonably find all integer solutions of the first equation, we first rewrite it in the form  tan(3*Pi/x) + 4*sin(2*Pi/x) = sqrt(x) . Note that for  x>=12  ​​the left side decreases and the right side increases and for  x=12  the right side is greater than the left side. This means that all real roots of this equation (not necessarily integer roots) can only exist in the interval  (0, 12) . Similarly, for the second equation we obtain the interval  (0, 37) . Therefore, all integer roots can be easily found by simple enumeration in these intervals (brute force method). When calculating, we exclude those values ​​of the variable x  for which the tangent does not exist.

restart;
Eq1:=tan(3*Pi/x)+4*sin(2*Pi/x)=sqrt(x);
solve(3*Pi/x=Pi/2+Pi*k, x);
seq(%, k=0..3);
for x in {$1..12} minus {2,6} do
if is(Eq1) then print('x'=x) fi;
od:

x:='x':

Eq2:=tan(13*Pi/x)+4*sin(19*Pi/x)=sqrt(x);
solve(13*Pi/x=Pi/2+Pi*k, x);
seq(%, k=0..13);
for x in {$1..36} minus {2,26} do
if is(Eq2) then print('x'=x) fi;
od:

So we get that the first equation has a unique integer root  x=11  and the second equation has a unique integer root  x=7 .

You can easily find some solutions in a double loop (brute force method). Of course, finding all solutions remains an open question.

restart;
for x from 1 to 1000 do
for y from 1 to 1000 do
if x!+1=y^2 then print(x,y) fi;
od: od:

                                   4, 5
                                   5, 11
                                   7, 71

With Maple 2018.2 :

restart;
A:=-(sqrt(3)*sqrt(-2*C1 - 2*x) - 3)/(3*sqrt(-2*C1 - 2*x)*x);
expand(A);

 nm 11113  You can simplify your expression  A  by reducing it to a polynomial:

restart;
A:=(-8*x - 16)*exp(x/2) + x^2 + 4*x + 16*exp(x) + 4;
B:=subs({exp(x/2)=y,exp(x)=y^2}, A);
simplify(B);
subs(y=exp(x/2), %);

Another way is to use double quotes:

restart;
e:=2*``(a + b + c);
expand(e);

I made 2 corrections: replaced square brackets with round ones and T(x_2)  with T:

Download TSL_bung_9_new.mw

Here an assumption about the signs of the variables is required and the  expand  command:

restart;
simplify(expand(sqrt(cos(a)^(5/3)/sin(2*a)^(5/3)))) assuming sin(a)>0, cos(a)>0;

Explanation: The well-known identities for square roots (for example  sqrt(a*b)=sqrt(a)*sqrt(b) )  are true only if the factors are positive.
Example: sqrt((-2)*(-3))=sqrt(6) and
sqrt(-2)*sqrt(-3) = (sqrt(2)*I) * (sqrt(3)*I) = sqrt(6) * I^2 = -sqrt(6)
I is the imaginary unit.

Maybe you want the system itself to be displayed in the traditional form, i.e. with equations one under the other and a curly bracket on the left. The following procedure does this and also gives the solution in the same form.

restart;

SysTrad:=proc(L::{list(equation), set(equation)})
local Sol;
uses InertForm;
print(Display(%piecewise(seq(op([``, L[i]]), i = 1 .. nops(L))), inert = false));
Sol:=solve(L);
Display(%piecewise(seq(op([``, Sol[i]]), i = 1 .. nops(Sol))), inert = false);
end proc: 

Example of use:

SysTrad([x+y-z = 3, x-y-z = 5, -x-y-z = 7]);

The first equation

restart;
pdsolve({diff(u(x,t),t) + 1/2*diff(u(x,t),x)^2 -diff(u(x,t),x,x) =0, u(x,0)=x});

Output               

Maple doesn't know how to solve the second equation (returns NULL)

pdsolve({diff(u(x,t),t,t) -diff(u(x,t),x,x) +2*diff(u(x,t),x,x)^3 -diff(u(x,t),x$4) =0, u(x,0)= 1/x, D[2](u)(x,0)=- 1/x^2});

Here's a workaround that uses symmetry. Example for n=4:

area := 4*int((1-x^4)^(1/4), x=0..1);
convert(area, GAMMA);
evalf(area);

This approach works in the general case  too:

4*int((1-x^n)^(1/n), x=0..1) assuming n>0;
area:=convert(%, GAMMA);
simplify(area-4*GAMMA(1/n+1)^2/GAMMA(1+2/n)) assuming n>0;

Ronan, your result  23  is correct, but I do not understand the logic of your solution. What similar triangles are you writing about? The triangles in the figure with areas of 2 and 9 are not similar.

Below is the solution in Maple. We specify the coordinates of all the points in the figure above. E and F denote the intersection points of the line  QP  with the lines  BD  and  AC, and  G  denotes the intersection point of the diagonals of the parallelogram.

restart;
with(LinearAlgebra):
local D:
B, A, D, C, Q, P := [0,0], [a,b], [a+c,b], [c,0], [d,0], [a+d,b]:
S:=(X,Y,Z)->1/2*(Determinant(<<X[]>|<Y[]>>)+Determinant(<<Y[]>|<Z[]>>)+Determinant(<<Z[]>|<X[]>>)):
Line:=(X,Y)->(y-X[2])*(Y[1]-X[1])-(x-X[1])*(Y[2]-X[2]):
BD:=Line(B,D): AC:=Line(A,C): PQ:=Line(P,Q):
E:=eval([x,y], solve({PQ,BD},{x,y})):
F:=eval([x,y], solve({PQ,AC},{x,y})):
G:=eval([x,y], solve({AC,BD},{x,y})):
sol:=solve({S(A,F,P)=2,S(E,G,F)=9});
eval(simplify(S(Q,C,F)-9, {S(A,F,P)=2,S(E,G,F)=9}), sol[2]);

PS.  From  sol[2]  we see that any parallelogram can be taken as such, in which the product of the base and the height is equal to 100. The simplest example of such a parallelogram would be a square with a side of 10 (in the figure below  AB=BC=10, AP=2):

The number of tickmarks on the coordinate axes is controlled by the spacing option. The number of animation frames is controlled by the  frames  option. The number of frames is always 1 more than the number of intervals. To make the animation parameter value rational, for example 0.1 , I replaced 6.28 with 6.3, which gives 63 intervals, and the number of frames should then be taken equal to 64 (see your examples below):

PS.  nm  has already answered you how to make the parameters corresponding to individual frames multiples of fractions of Pi .

Download Q_Pi_scaling_new.mw

An easy way to color the area between the graph and the horizontal axis is to use the  filled  option (it works in the oldest versions of Maple). I also added plus and minus signs for the definite integral signs and chose a warmer color for the positive area.
Plotted in Maple 2018.2:

restart;
with(plots):
P:=plot(x^3, x=-1..1, color=black, thickness=3):
P1:=plot(x^3, x=-1..0, color=cyan, filled):
P2:=plot(x^3, x=0..1, color=gold, filled):
T:=textplot([[-0.8,-0.2,"_"],[0.8,0.2,"+"], [0.7,0.6,y=x^3,rotation=Pi/3,font=[times,20]]], font=[times,bold,22]):
plots:-display(P1,P2,P,T, size=[500,500]);

Edit.

Use the AllSolutions  option to get the general solution  Sol  of this equation. We see that the general solution contains 2 variables. _L1  is any integer, and _B1  takes 2 values  0  or  1 . Therefore, the general solution  Sol  can be divided into 2 families of solutions  Sol1  and  Sol2 :

restart;
Sol:=solve(sqrt(2)*sin(2*x-(1/6)*Pi)=1, AllSolutions);
about(_B1);
Sol1:=eval(Sol,[_B1=0,_Z1=k]);
Sol2:=eval(Sol,[_B1=1,_Z1=k]);

PS.  This solution in Maple 2018.2

It's not hard to do, but then you'll have to use different names. One name for calculations and plottings and another name for displaying:

restart;
f:=x->log[2](x);  # f is the name of a procedure for calculations
f(8);
ff:=InertForm:-Display(%log[2](x), inert=false):  # ff is the name for images
plot(f, 0..8, labels=[x,ff], title=typeset("A plot of the function  ", y=ff, "."), titlefont=[times,18], size=[1000,500], scaling=constrained );