We must specify the option  scene , for example  scene=[t, S(t)]  or  scene=[S(t), V(t)]  and etc. But if we do this, then the error appears about the existence of a singularity. In fact, since you have zero initial conditions, then we have zeros in the denominators of your system at  t = 0 . 

DEplot(sys, [S(t), V(t), C(t), I(t), R(t)], t = 0 .. 50, S = 0 .. 2, V = 0 .. 2, C = 0 .. 2, I = 0 .. 2, R = 0 .. 2, [[S(0) = 0, V(0) = 0, C(0) = 0, I(0) = 0, R(0) = 0]], stepsize = .1, linecolour = blue, thickness = 4, arrows = slim, scene = [t, S(t)]);
    Warning, plot may be incomplete, the following errors(s) were issued:
   cannot evaluate the solution past the initial point, problem may be complex, initially singular or improperly    set up

PS. You need to think about how correct your model is.

First, you specify the vectors  x  and  y , and then calculate the expressions  px  and  py , using for summation  add  command:

x:=<0, 1, 3>: y:=<2, 3, 4>: n:=3:
px:=x[1]+add((x[j]-x[1])^2, j=2..n)/add(x[j]-x[1], j=2..n);
py:=y[1]+add((x[j]-x[1])*(y[j]-y[1]), j=2..n)/add(x[j]-x[1], j=2..n);

restart;
PDEtools[declare]((f, g)(x), prime = x);
de1 := diff(f(x), x, x, x, x)-(H*H)*(diff(f(x), x, x))-R*(diff(f(x), x, x))*(diff(f(x), x))+R*(diff(f(x), x, x, x))*f(x);
de2 := diff(g(x), x, x)-(H*H)*g(x)-R*(diff(f(x), x))*g(x)+R*(diff(g(x), x))*f(x); 
dd1 := {de1 = 0, de2 = 0, f(0) = 0, f(1) = 1, g(0) = 1, g(1) = 1, (D(f))(0) = 0, (D(f))(1) = 0};
r1 := dsolve(eval(dd1, [R = 1, H = 1]),numeric, output = Array([0., 0.5e-1, .10, .15, .20, .25, .30, .35, .40, .45, .50, .55, .60, .65, .70, .75, .80, .85, .90, .95, 1.00]));
r2 := dsolve(eval(dd1, [R = 5, H = 5]),numeric, output = Array([0., 0.5e-1, .10, .15, .20, .25, .30, .35, .40, .45, .50, .55, .60, .65, .70, .75, .80, .85, .90, .95, 1.00]));
A:=plots:-odeplot(r1, [x, f(x)], x=0..5, color=red):
B:=plots:-odeplot(r2, [x, f(x)], x=0..5, color=blue):
plots:-display(A, B);

I had a similar problem with the Maple 2017 a few months ago. Try the following method. After the loading screen appears, open the task manager, then details, then find the processes   jogamp_exe...  and stop them (there are two such processes in my comp).

Formal parameters of the procedure: T  is the list of vertices of the original triangle, n  is the number of steps, C  is the color (optional, by default red).

Sierpinski:=proc(T::list,n::nonnegint,C::symbol:=red)
local Step;
uses plottools, plots;
Step:=L->map(t->op([[t[1],(t[1]+t[2])/2,(t[1]+t[3])/2],[(t[1]+t[2])/2,t[2],(t[2]+t[3])/2],[(t[1]+t[3])/2,(t[2]+t[3])/2,t[3]]]), L);
map(t->polygon(t,style=surface,color=C),(Step@@n)([T]));
display(%, axes=none, size=[600,600]);
end proc:

Example of use (animation):

plots:-display(seq(Sierpinski([[-1,0],[0,sqrt(3)],[1,0]], n)$7, n=0..7), insequence);

Output:

Sierpinski.mw

P:=x*y*z+ x*y^2+x*y-y*z^2;
select(p->degree(p,x)<2 and degree(p,y)<2 and degree(p,z)<2, P);

Use  subsop  command:

restart;
f:=(3*beta[11]^2-4*beta[11]*sigma[11]+6*beta[12]^2-12*beta[12]*sigma[12]+2*sigma[11]^2+6*sigma[12]^2)*(1/sqrt(6*beta[11]^2-8*beta[11]*sigma[11]+12*beta[12]^2-24*beta[12]*sigma[12]+4*sigma[11]^2+12*sigma[12]^2))*(1/omega^2);
subsop(2=1/phi, f);

Maple knows this multiplication rule, only you have to multiply the entire inequality, not its individual operands:

(2<3)*(-1);
(k/m<=2/n)*(-1);

PS. Note that Maple always writes a sign of inequality in one direction, if necessary, rearranging the sides of the inequality. You can make Maple change the direction of the inequality only (as you wish), but it's not so simple, you need a special procedure for this.

I divided your code into 2 parts: the first system and the second system. Maple easily solves the first system and builds graphics. But with the second system there are problems. Probably the second system itself is composed incorrectly.

Download TwoSystems.mw

beta := 1: alpha[1] := 0.5:

f := beta+alpha[1]+sin(x*beta):

plot(f, x = 0 .. Pi, axes = boxed, size = [300, 270], labels = [x, "f ' (x)"], labelfont = ["Arial", 10, Bold], labeldirections = [horizontal, vertical], title=typeset("y                                        ",'beta' = 1,", ", 'alpha[1]' = 0.5), titlefont = ["Arial", 10, bold]);

Or

restart;
beta := 1: alpha[1] := 0.5:
f := beta+alpha[1]+sin(x*beta):
plot(f, x = 0 .. Pi, axes = boxed, size = [300, 270], labels = [x, "f ' (x)"], labelfont = ["Arial", 10, Bold], labeldirections = [horizontal, vertical], title=typeset("\                                                    ",'beta' = 1,", ", 'alpha[1]' = 0.5), titlefont = ["Arial", 10, bold]);

AllPositions  procedure finds a set of all the positions of some element  a  in a multi-dimensional (or one-dimensional) list or rtable  A . The level of nesting can be anything.

AllPositions:=proc(a, A::{list,rtable}, L::list(`=`))
local S, M;
M:={eval(subs(S=seq, foldl(S, '`if`(A[lhs~(L)[]]=a,lhs~(L),NULL)', op(L))))};
if nops(L)>1 then M else op~(M) fi;
end proc:

Example of use:

AllPositions(2, [[1, 2, 3], [2, 3, 5], [2, 4, 5]], [i=1..3, j=1..3]);

Output:             {[1, 2], [2, 1], [3, 1]}

Here is a procedure for this:

restart;
NestedSeq:=proc(Expr::uneval, L::list)
local S;
eval(subs(S=seq, foldl(S, Expr, op(L))));
end proc:

As an example, let's consider the numerological game "Cчастливый билет", known in Russia. A ticket in public transport is called lucky (a ticket is an ordered set of 6 digits, each digit is from 0 to 9), if the sum of the first three digits is equal to the sum of the last three. Below we find the list of all the lucky tickets:

LuckyTickets:=[NestedSeq(`if`(i+j+k=l+m+n,cat(i,j,k,l,m,n),NULL), [i,j,k,l,m,n]=~0..9)]: # List of all the lucky tickets
nops(LuckyTickets); # Total number of lucky tickets
seq(LuckyTickets[i],i=2..%,5000); # Examples of lucky tickets

                                                             55252
100100, 107701, 908791, 728782, 166373, 528654, 593935, 316226, 942807, 748397, 568388, 977689
 

This is impossible even if you know the function, because at the same value of the function, but at different points, the derivatives may differ. For example, cos(Pi/2)=cos(3*Pi/2)=0 , but the derivatives at these points are different. To calculate the derivative at individual points, it is better to use the differential operator  D .

In your example you can just write

diff(f(x),x)*eval(cos(f(x)), f(x)=0);

If you still want to apply  eval  to the whole expression, then the use of  D  operator is the simplest way:

eval(D(f)(x)*cos(f(x)), f(x)=0);  # Or
convert(eval(D(f)(x)*cos(f(x)), f(x)=0), diff);

Download Help_new1.mw

This can be done in several ways. Here are two:

with(plots): with(plottools):
A:=[1, 2, 3]: B:=[4, 5, 6]:
spacecurve(A+t*~B, t=0..1, color=red, thickness=2);
display(line(A, B, color=red, thickness=2));