:

## The Million Dollar Stop Sign: What is the Cost of Stopping Your Car?

Maple An intersection in my neighbourhood, currently controlled by a 2-way stop, is under consideration to become a 4-way stop.  This means the traffic that currently has the right-of-way will be required to come to a complete stop, wheras previously they could have coasted down the hill, and accelerated up the other side.   Politics aside, I was curious to explore the following question:

What is the cost in terms of fuel consumption of coming to a complete stop?

This also provides a nice opportunity to demonstrate the power and flexibility of using units as part of various Maple computations.  To be honest, I would have quickly gotten stuck if I had to worry about how BTU equates to Joules, or even simpler, just dealing with the back and forth between miles-per-gallon fuel economy rating, versus distance in kilometers, and price per Liter.

The full worksheet can be found here:

StopTraffic.mw

We'll start by loading the Units package and setting the default system to SI.

with(Units[Standard]);

UseSystem('SI');

The posted speed limit is 80 km/h.

speed := 80.*Unit('km'/'h');

A quick web search uncovers this link,  http://large.Stanford.edu/courses/2011/ph240/miller1, where a student at Stanford University uses the kinetic energy equation compared to the gas-gallon-equivalent energy value.   I don't think this is a valid method, but it is still worth sharing as a starting point because the numbers come close.

The example uses a typical car, a Toyota Camry, and measures the energy required to stop and start.
The 2013 Toyota Camry L's curb weight is 2676lbs (notably less than the 2012 model, which was 3177lbs).  We'll assume the driver is of average weight for someone in North America (178lbs according to wikipedia), and that there is no cargo of consequential weight.

mass := (2676+178)*Unit(lb);

The Kinetic Energy equation,  E = 1/2*m*v^2, records the energy required to stop (ignoring many factors such as the fact that this stop sign is at the bottom of a hill, wind, etc.), plus the energy required to get back up to full speed again (again ignoring engine efficiency, tire contact, time to reach cruising speed, etc.).

E := 2*(1/2*mass*speed^2);

639285 [[J]]

Gasoline has a GCE rating of 114000 BTU/gallon (http://en.wikipedia.org/wiki/Gasoline_gallon_equivalent).   This is an Energy per Gallon rating, so let's equate that to our computation above of the energy required to stop and start, and let Maple handle all the unit conversions.

The following shows how much gas is consumed by a single start/stop at the new stop sign:

GasConsumedCar := E/(114000*Unit(BTU/gal));

0.000020133 [[m^3]]

In Liters and Gallons, that is:

convert(GasConsumedCar, units, L);

0.02013344296 [[L]]

convert(GasConsumedCar, units, gal);

0.005318692948 [[gal]]

Engine efficiency plays a big role in how reasonable this number is to apply to a car engine.  I am a bit leery about using GCE equivalence to measure fuel consumption, so I felt it would be a good idea to double-check this with an alternate approach.  Using posted fuel economy and physics motion equations, we should be able to compute the same result.

Assuming it takes 12 seconds to accelerate back up to speed, we compute:

t := 12.*Unit(s):

a := speed / t:

Therefore, the distance traveled during this time is:

distance := speed*t - a*t^2/2;

133.3333 [[m]]

The Corolla reports 26mpg for city driving on average.  This is usually several times less than what you would expect to get during a burst of acceleration.  It's hard to get concrete data for this specific car, but for other vehicles like this mpg increases by a factor of 2 - 6 depending on how hard the accelleration is on a flat road.  The 12s to achive 0-80km is a medium-hard accelleration, so we'll put in a 4x multiplier.  Without stopping you would still cover the same distance, so we should subtract 1x multiplier, but for this road, the intersection is in a valley, requiring an up-hill start in both directions.  I think adding back 1x is reasonable.

GasConsumedCar2 := distance/(4*26*Unit(mi/gal)):

convert(GasConsumedCar2, units, L);

0.0030155 [[L]]

convert(GasConsumedCar2, units, gal);

0.0007966 [[gal]]

This is a much more conservative number, which probably is more realistic than the GCE equivalence.  Also, we won't measure fuel consumed due to stopping, which, although it requires energy, it doesn't require fuel.

The current cost of a Liter of gas in this area is:

GasPrice := 1.29 * Unit(dollar/L):

The shocking dollars per gallon equivalent of this is:

convert(GasPrice, units, dollar/gal);

4.883181201 [[USD/gal]]

Using the more conservative fuel use estimate we find that stopping the car costs less than a penny:

GasConsumedCar2*GasPrice;

\$0.0039 [[USD]]

This road is also a main feeder to the key 7/8 expressway which draws commercial traffic from various sources including a local gravel pit.  As a result this road is frequented by many heavy trucks.  Consider the energy calculation for a standard dump truck, carrying a 33,000 pound payload:

GasConsumedTruck := (33000*Unit(lb)*(80*Unit(km/h))^2 / (114000*Unit(BTU/gal));

0.00023279 [[m^3]]

GasConsumedTruck * GasPrice;

\$0.30 [[USD]]

This energy model predicts a whopping 30 cents for a loaded truck to stop and start.

Alternately, we calculate the second method with 3.2 mpg and 0-80km/h in 30 seconds:

t := 30*Unit(s):

a := speed/t:

distance := speed*t - a*t^2/2:

GasConsumedTruck2 := distance/(4*3.2*Unit(mi/gal));

GasConsumedTruck2 * GasPrice;

\$0.079 [[USD]]

Even in the conservative model, a truck stop costs in the neighbourhood of 8 cents.

The following are the numbers I originally worked with as a guess at traffic volume.  These are not unreasonable numbers for some road, but not this particular one.  I left the calculations in just to show that a stop-sign in the face of heavier traffic will result in a huge dollar figure.

TruckCount := 4;

CarCount := 20;

GasInOneMinute := convert(CarCount*GasConsumedCar2+TruckCount*GasConsumedTruck2, units, L);

0.3053 [[L]]

Using a liberal assumption that this snapshot is representative of the daily average, and that there is typically no night traffic:

GasInOneDay := 60*GasInOneMinute*12;

219.83 [[L]]

GasInOneYear := 365*GasInOneDay;

80239 [[L]]

GasInOneYear*GasPrice;

\$103,509.39 [[USD]]

Note that the Stanford estimate is much worse:
60*(365*12)*(CarCount*GasConsumedCar+TruckCount*GasConsumedTruck)*GasPrice;

\$452,193.95 [[USD]]

One hundred thousand to half a million dollars in a year!
Stopping this week to take the picture at the head of this document, I counted a real sample over 5 minutes.

TruckCount := 5;

CarCount := 32;

GasInFiveMinutes := convert(CarCount*GasConsumedCar2+TruckCount*GasConsumedTruck2, units, L);

0.40277 [[L]]

GasInOneDay := 12*(60*GasInFiveMinutes*(1/5)):

GasInOneYear := 365*GasInOneDay;

21169 [[L]]

GasInOneYear*GasPrice;

\$27,308.59 [[USD]]

or

12*(365*12)*(CarCount*GasConsumedCar+TruckCount*GasConsumedTruck)*GasPrice;

\$112,604.16 [[USD]]

Even \$25,000 dollars per year is a surprising number, which adds up over time, and increases each year as traffic volume increases.   Speaking of which, we can calculate the cost over time too.  Let's peg gas-price inflation at a modest 2%, and add in a modest 2% year-over-year increase in traffic.  The standard annuity formula will give us the following consumption and cost over 25 years.

GasInOneYear * ((1+.02)^25-1)/.02;

678,064 [[L]]

GasInOneYear*GasPrice * ((1+.04)^25-1)/.04;

\$1,137,290.96 [[USD]]

Keep in mind that the car part of the fuel consumption estimate was  based on a light-weight fuel-efficient car.  Mixing in the various mid-size cars and SUV's would only elevate this number.  On the other hand an accurate count throughout the course of the day is essential for a more formal study, and would likely lower the total cost number. ﻿