## 7766 Reputation

17 years, 337 days

## Two cones: A puzzle and an animation...

Maple

Some years ago I taught a calculus course for especially talented students. I made up the following problem as an interesting challenge.

Take a circular disk made of paper. Cut out a sector of some angle α from the disk. Roll each of the resulting two pieces into cones. Let V(α) be the sum of the volumes of the two cones. Find the α that maximizes V(α).

Here is an animated statement of the problem, produced in Maple.

## Maple's own perpetual motion machine...

Maple

Some misguided individuals insist that perpetual motion machines are impossible. Here is a proof that they are wrong!

One of these units hooked up to an electrical generator should be enough to supply all your household electrical needs as well as charge your Tesla in the garage.

If you build one and find out that it doesn't work as demonstrated here, then surely you must have misread the specs. Try it again and again until you succeed.

## The strandbeest...

Maple 2020

The strandbeest is a walking machine developed by Theo Jansen. Its cleverly designed legs consist of single-degree-of-freedom linkage mechanisms, actuated by the turning of a wind-powered crankshaft.

His working models are generally large - something of the order of the size of a bus. Look for videos on YouTube.  Commercially made small toy models are also available.  This one sells for under \$10 and it's fun to assemble and works quite well. Beware that the kit consists of over 100 tiny pieces - so assembling it is not for the impatient type.

Here is a Maple worksheet that produces an animated strandbeest. Link lengths are taken from Theo Jansen's video (go to his site above and click on Explains) where he explains that he calculated the optimal link lengths by applying a genetic algorithm.

Here is a Maple animation of a single leg.  The yellow disk represents the crankshaft.

And here are two legs working in tandem:

Here is the complete beest, running on six legs. The crankshaft turns at a constant angular velocity.

The toy model noted above runs on twelve legs for greater stability.

## Eigenfunctions of a multi-span Euler-Ber...

Maple 2020

Question about deflection and vibration of beams occur with some regularity in this forum.  Search for "beam" to see several pages of hits.

In this post I present a general approach to calculating the vibrational modes of a beam that applies to both single-span and multi-span beams.  The code is not perfectly polished, but it is sufficiently documented to enable the interested user to modify/extend it as needed.

Vibrational modes of multi-span Euler-Bernoulli beams

through Krylov-Dunction functions

Rouben Rostamian
2020-07-19

 > restart;

Note:  Maple defines the imaginary unit . We want to use the
symbol  as the beam's cross-sectional moment of inertia.
Therefore we redefine the imaginary unit (for which we have no

use) as  and free up the symbol  for our use.

 > interface(imaginaryunit=II):
 > with(LinearAlgebra):
 >

The Euler-Bernoulli beam equation
.

We wish to determine the natural modes of vibration of

a possibly multi-span Euler-Bernoulli beam.

Separate the variables by setting .   We get
-

whence
.

Let .  Then

and

The idea behind the Krylov-Duncan technique is to express

in terms an alternative (and equivalent) set of basis
functions  through ,, as
,

where the functions  through  are defined in the next section.

In some literature the symbols , are used for these

functions but I find it more sensible to use the indexed function

notation.

The Krylov-Duncan approach is particularly effective in formulating
and finding a multi-span beam's natural modes of vibration.

 >
 >

The Krylov-Duncan functions

The K[i](x) defined by this proc evaluates to the th

Krylov-Duncan function.

Normally the index  will be in the set, however the proc is

set up to accept any integer index (positive or negative).  The proc evaluates

the index modulo 4 to bring the index into the set .   For

instance, K[5](x) and K[-3](x)i are equivalent to K[1](x) .

 > K := proc(x)         local n := op(procname);         if not type(n, integer) then                 return 'procname'(args);         else                 n := 1 + modp(n-1,4);  # reduce n modulo 4         end if;         if n=1 then                 (cosh(x) + cos(x))/2;         elif n=2 then                 (sinh(x) + sin(x))/2;         elif n=3 then                  (cosh(x) - cos(x))/2;         elif n=4 then                 (sinh(x) - sin(x))/2;         else                 error "shouldn't be here!";         end if; end proc:

Here are the Krylov-Duncan basis functions:

 > seq(print(cat(`K__`,i)(x) = K[i](x)), i=1..4);

and here is what they look like.  All grow exponentially for large
but are significantly different near the origin.

 > plot([K[i](x) \$i=1..4], x=-Pi..Pi,         color=["red","Green","blue","cyan"],         thickness=2,         legend=['K[1](x)', 'K[2](x)', 'K[3](x)', 'K[4](x)']);

The cyclic property of the derivatives:
We have .  Let's verify that:

 > diff(K[i](x),x) - K[i-1](x) \$i=1..4;

The fourth derivative of each   function equals itself. This is a consequence of the cyclic property:

 > diff(K[i](x), x\$4) - K[i](x) \$ i=1..4;

The essential property of the Krylov-Duncan basis function is that their

zeroth through third derivatives at  form a basis for :

 > seq((D@@n)(K[1])(0), n=0..3); seq((D@@n)(K[2])(0), n=0..3); seq((D@@n)(K[3])(0), n=0..3); seq((D@@n)(K[4])(0), n=0..3);

As noted earlier, in the case of a single-span beam, the modal  shapes

are expressed as
.

Then, due to the cyclic property of the derivatives of the Krylov-Duncan

functions, we see that:
.
.
.
Let us note, in particular, that
,
,
,
.

 >

A general approach for solving multi-span beams

In a multi-span beam, we write  for the deflection of the th span, where

and where  is the span's length.  The  coordinate indicates the

location within the span, with  corresponding to the span's left endpoint.

Thus, each span has its own  coordinate system.

We assume that the interface of the two adjoining spans is supported on springs

which (a) resist transverse displacement proportional to the displacement (constant of

proportionality of   (d for displacement), and (b) resist rotation proportional to the
slope (constant of proportionality of   (t for torsion or twist). The spans are numbered

from left to right. The interface conditions between spans  and +1 are

 1 The displacements at the interface match: .
 2 The slopes at the interface match (0).
 3 The difference of the moments just to the left and just to the right of the support is due to the torque exerted by the torsional spring:
 4 The difference of the shear forces just to the left and just to the right of the support is due to the force exerted by the linear spring:

The special case of a pinned support corresponds to  and .
In that case, condition 3 above implies that ,
and condition 4 implies that

Let us write the displacements  and  in terms of the Krylov-Duncan

functions as:

Then applying the cyclic properties of the Krylov-Duncan functions described

earlier, the four interface conditions translate to the following system of four
equations involving the eight coefficients .

,

which we write as a matrix equation
.

That  coefficient matrix plays a central role in solving

for modal shapes of multi-span beams.  Let's call it .

Note that the value of  enters that matrix only in combinations with
and .  Therefore we introduce the new symbols

,    .

The following proc generates the matrix .  The parameters  and

are optional and are assigned the default values of infinity and zero, which

corresponds to a pinned support.

The % sign in front of each Krylov function makes the function inert, that is, it
prevents it from expanding into trig functions.  This is so that we can

see, visually, what our expressions look like in terms of the  functions.  To

force the evaluation of those inert function, we will apply Maple's value function,

as seen in the subsequent demos.

 > M_interface := proc(mu, L, {Kd:=infinity, Kt:=0})         local row1, row2, row3, row4;         row1 := %K[1](mu*L), %K[2](mu*L), %K[3](mu*L), %K[4](mu*L), -1,  0, 0, 0;         row2 := %K[4](mu*L), %K[1](mu*L), %K[2](mu*L), %K[3](mu*L),  0, -1, 0, 0;         row3 := %K[3](mu*L), %K[4](mu*L), %K[1](mu*L), %K[2](mu*L),  0, Kt/mu, -1, 0;         if Kd = infinity then                 row4 := 0, 0, 0, 0, 1, 0, 0, 0 ;         else                 row4 := %K[2](mu*L), %K[3](mu*L), %K[4](mu*L), %K[1](mu*L), Kd/mu^3, 0, 0, -1;         end if:                 return < | | | >^+; end proc:

Here is the interface matrix for a pinned support:

 > M_interface(mu, L);

And here is the interface matrix for a general springy support:

 > M_interface(mu, L, 'Kd'=a, 'Kt'=b);

Note:  In Maple's Java interface, inert quantities are shown in gray.

Note:  The  in this matrix is the length of the span to the left of the interface.
Recall that it is  , not , in the derivation that leads to that matrix.

In a beam consisting of  spans, we write the th span's deflection  as

Solving the beam amounts to determining the  unknowns

which we order as

At each of the  interface supports we have a set of four equations as derived
above, for a total of  equations.  Additionally, we have four user-supplied

boundary conditions -- two at the extreme left and two at the extreme right of the

overall beam.  Thus, altogether we have  equations which then we solve for the

unknown coefficients .

The user-supplied boundary conditions at the left end are two equations, each in the
form of a linear combination of the coefficients .  We write  for the
coefficient matrix of that set of equations.  Similarly, the user-supplied boundary
conditions at the right end are two equations, each in the form of a linear combination
of the coefficients .  We write  for the  coefficient matrix of
that set of equations.   Putting these equations together with those obtained at the interfaces,

we get a linear set of equations represented by a  matrix which can be assembled

easily from the matrices , and .  In the case of a 4-span beam the

assembled matrix looks like this:

The pattern generalizes to any number of spans in the obvious way.

For future use, here we record a few frequently occurring  and  matrices.

 > M_left_pinned := <         1, 0, 0, 0;         0, 0, 1, 0 >;

 > M_right_pinned := (mu,L) -> <         %K[1](mu*L), %K[2](mu*L), %K[3](mu*L), %K[4](mu*L);         %K[3](mu*L), %K[4](mu*L), %K[1](mu*L), %K[2](mu*L) >;

 > M_left_clamped := <         1, 0, 0, 0;                 0, 1, 0, 0 >;

 > M_right_clamped := (mu,L) -> <         %K[1](mu*L), %K[2](mu*L), %K[3](mu*L), %K[4](mu*L);         %K[4](mu*L), %K[1](mu*L), %K[2](mu*L), %K[3](mu*L) >;

 > M_left_free := <         0, 0, 1, 0;                 0, 0, 0, 1 >;

 > M_right_free := (mu,L) -> <         %K[3](mu*L), %K[4](mu*L), %K[1](mu*L), %K[2](mu*L);         %K[2](mu*L), %K[3](mu*L), %K[4](mu*L), %K[1](mu*L) >;

The following proc builds the overall matrix in the general case.  It takes
two or three arguments.  The first two arguments are the  matrices
which are called  and  in the discussion above.  If the beam
consists of a single span, that's all the information that need be supplied.
There is no need for the third argument.

In the case of a multi-span beam, in the third argument we supply the
list of the interface matrices  , as in , listed in order
of the supports,  from left to right.   An empty list is also
acceptable and is interpreted as having no internal supports,
i.e., a single-span beam.

 > build_matrix := proc(left_bc::Matrix(2,4), right_bc::Matrix(2,4), interface_matrices::list)         local N, n, i, M;         # n is the number of internal supports         n := 0;         # adjust n if a third argument is supplied         if _npassed = 3 then                 n := nops(interface_matrices);                 if n > 0 then                         for i from 1 to n do                                 if not type(interface_matrices[i], 'Matrix(4,8)') then                                         error "expected a 4x8 matrix for element %1 in the list of interface matrices", i;                                 end if;                         end do;                 end if;         end if;         N := n + 1;                     # number of spans         M := Matrix(4*N);         M[1..2, 1..4] := left_bc;         for i from 1 to n do                 M[4*i-1..4*i+2, 4*i-3..4*i+4] := interface_matrices[i];         end do;         M[4*N-1..4*N, 4*N-3..4*N] := right_bc;                          return M; end proc:

For instance, for a single-span cantilever beam of length  we get the following  matrix:

 > build_matrix(M_left_clamped, M_right_free(mu,L));

For a two-span beam with with span lengths of  and , and all three
supports pinned,  we get the following  matrix:

 > build_matrix(M_left_pinned, M_right_pinned(mu,L[2]), [M_interface(mu, L[1])]);

The matrix  represents a homogeneous linear system (i.e., the right-hand side vector

is zero.)  To obtain a nonzero solution, we set the determinant of  equal to zero.

That gives us a generally transcendental equation in the single unknown .  Normally

the equation has infinitely many solutions.  We call these

Remark: In the special case of pinned supports at the interfaces, that is, when
, the matrix  depends only on the span lengths .
It is independent of the parameters  that enter the Euler-Bernoulli
equations.  The frequencies , however, depend on those parameters.

This proc plots the calculated modal shape corresponding to the eigenvalue .
The params argument is a set of equations which define the  numerical values

of all the parameters that enter the problem's description, such as the span

lengths.

It is assumed that in a multi-span beam, the span lengths are named  etc.,
and in a single-span beam, the length is named .

 > plot_beam := proc(M::Matrix,mu::realcons, params::set)         local null_space, N, a_vals, i, j, A, B, P;         eval(M, params);         eval(%, :-mu=mu);         value(%);  #print(%);         null_space := NullSpace(%);  #print(%);         if nops(null_space) <> 1 then                 error "Calculation failed. Increasing Digits and try again";         end if;         N := Dimension(M)[1]/4;  # number of spans         a_vals := convert([seq(seq(a[i,j], j=1..4), i=1..N)] =~ null_space[1], list);         if N = 1 then                 eval(add(a[1,j]*K[j](mu*x), j=1..4), a_vals);                 P[1] := plot(%, x=0..eval(L,params));         else                 A := 0;                 B := 0;                 for i from 1 to N do                         B := A + eval(L[i], params);                         eval(add(a[i,j]*K[j](mu*x), j=1..4), a_vals);                         eval(%, x=x-A):                         P[i] := plot(%, x=A..B);                         A := B;                 end do;                 unassign('i');         end if;         plots:-display([P[i] \$i=1..N]); end proc:
 >

A single-span pinned-pinned beam

Here we calculate the natural modes of vibration of a single span

beam, pinned at both ends.  The modes are of the form

The matrix  is:

 > M := build_matrix(M_left_pinned, M_right_pinned(mu,L));

The characteristic equation:

 > Determinant(M); eq := simplify(value(%)) = 0;

 > solve(eq, mu, allsolutions);

We conclude that the eigenvalues are .

A non-trivial solution of the system  is in the null-space of :

 > eval(value(M), mu=n*Pi/L) assuming n::integer; N := NullSpace(%);

Here are the weights that go with the Krylov functions:

 > a_vals := convert([a[1,j] \$j=1..4] =~ N[1], set);

and here is the deflection:

 > add(a[1,j]*K[j](mu*x), j=1..4); eval(%, a_vals);       # plug in the a_vals calculated above eval(%, mu=n*Pi/L);    # assert that n is an integer

We see that the shape functions are simple sinusoids.

 >
 >

A single-span free-free beam

Here we calculate the natural modes of vibration of a single span

beam, free at both ends.  The modes are of the form
.

The reasoning behind the calculations is very similar to that in the

previous section, therefore we don't comment on many details.

 > M := build_matrix(M_left_free, M_right_free(mu,L));

The characteristic equation:

 > Determinant(M); simplify(value(%)) = 0; eq_tmp := isolate(%, cos(L*mu));

Let .  Then the characteristic equation takes the form

 > eq := algsubs(L*mu=lambda, eq_tmp);

Here are the graphs of the two sides of the characteristic equation:

 > plot([lhs,rhs](eq), lambda=0..4*Pi, color=["red","Green"]);

The first three roots are:

 > lambda__1, lambda__2, lambda__3 :=         fsolve(eq, lambda=Pi/2..4*Pi, maxsols=3);

 > params := { L=1 };

 > mu__1, mu__2, mu__3 := (lambda__1, lambda__2, lambda__3) /~ eval(L, params);

 > plots:-display([         plot_beam(M, mu__1, params),         plot_beam(M, mu__2, params),         plot_beam(M, mu__3, params)],         color=["red","Green","blue"],         legend=[mode1, mode2, mode3]);

 >
 >

A single-span clamped-free cantilever

We have a cantilever beam of length .  It is clamped at the

left end, and free at the right end.

 > M := build_matrix(M_left_clamped, M_right_free(mu,L));

 > Determinant(M); simplify(value(%)) = 0; eq_tmp := isolate(%, cos(L*mu));

Let .  Then the characteristic equation takes the form

 > eq := algsubs(L*mu=lambda, eq_tmp);

Here are the graphs of the two sides of the characteristic equation:

 > plot([lhs,rhs](eq), lambda=0..3*Pi, color=["red","Green"]);

 > lambda__1, lambda__2, lambda__3 :=         fsolve(eq, lambda=Pi/2..3*Pi, maxsols=3);

 > params := { L=1 };

 > mu__1, mu__2, mu__3 := (lambda__1, lambda__2, lambda__3) /~ eval(L, params);

 > plots:-display([         plot_beam(M, mu__1, params),         plot_beam(M, mu__2, params),         plot_beam(M, mu__3, params)],         color=["red","Green","blue"],         legend=[mode1, mode2, mode3]);

 >
 >

A dual-span pinned-pinned-free cantilever beam

We have a two-span beam of span lengths  and , with the left end of the
first span pinned, the right end of the second span free, and the interface

between the spans on a pinned support.  .

 > M := build_matrix(         M_left_pinned,         M_right_free(mu,L[2]),                 [ M_interface(mu,L[1])] );

The characteristic equation:

 > Determinant(M); eq_tmp1 := simplify(value(%)) = 0;

That equation does not seem to be amenable to simplification.  The special case of , however,

is much nicer:

 > eval(eq_tmp1, {L[1]=L, L[2]=L}): eq_tmp2 := simplify(%*4);

Let :

 > eq_tmp3 := algsubs(L*mu=lambda, eq_tmp2);

That expression grows like , so we divide through by that to obtain

a better-behaved equation

 > eq := eq_tmp3/cosh(lambda)^2;

 > plot(lhs(eq), lambda=0..2*Pi);

Here are the first three roots:

 > lambda__1, lambda__2, lambda__3 :=          fsolve(eq, lambda=1e-3..2*Pi, maxsols=3);

 > params := { L[1]=1, L[2]=1 };

 > mu__1, mu__2, mu__3 := (lambda__1, lambda__2, lambda__3) /~ eval(L[1], params);

 > plots:-display([         plot_beam(M, mu__1, params),         plot_beam(M, mu__2, params),         plot_beam(M, mu__3, params)],         color=["red","Green","blue"],         legend=[mode1, mode2, mode3]);

 >
 >

A dual-span clamped-pinned-free cantilever beam

We have a two-span beam of span lengths  and , with the left end of the
first span clamped, the right end of the second span free, and the interface

between the spans on a pinned support.  This is different from the previous

case only in the nature of the left boundary condition.

 > M := build_matrix(         M_left_clamped,         M_right_free(mu,L[2]),         [ M_interface(mu,L[1])] );

The characteristic equation:

 > Determinant(M); eq_tmp1 := simplify(value(%)) = 0;

That equation does not seem to be amenable to simplification.  The special case of , however,

is much nicer:

 > eval(eq_tmp1, {L[1]=L, L[2]=L}): eq_tmp2 := simplify(%*4);

Let :

 > eq_tmp3 := algsubs(L*mu=lambda, eq_tmp2);

That expression grows like , so we divide through by that to obtain

a better-behaved equation

 > eq := eq_tmp3/cosh(lambda)^2;

 > plot(lhs(eq), lambda=0..2*Pi);

Here are the first three roots:

 > lambda__1, lambda__2, lambda__3 :=          fsolve(eq, lambda=1e-3..2*Pi, maxsols=3);

 > params := { L[1]=1, L[2]=1 };

 > mu__1, mu__2, mu__3 := (lambda__1, lambda__2, lambda__3) /~ eval(L[1], params);

 > plots:-display([         plot_beam(M, mu__1, params),         plot_beam(M, mu__2, params),         plot_beam(M, mu__3, params)],         color=["red","Green","blue"],         legend=[mode1, mode2, mode3]);

 >
 >

A triple-span free-pinned-pinned-free beam

We have a triple-span beam with span lengths of .  The beam is supported

on two internal pinned supports.  The extreme ends of the beam are free.

The graphs of the first three modes agree with those

in Figure 3.22 on page 70 of the 2007 article of
Henrik Åkesson, Tatiana Smirnova, Thomas Lagö, and Lars Håkansson.

In the caption of Figure 2.12 on page 28 the span lengths are given
as 3.5, 5.0, 21.5.

 > interface(rtablesize=12):
 > M := build_matrix(         M_left_free,         M_right_free(mu,L[3]),         [ M_interface(mu,L[1]), M_interface(mu,L[2])] );

 > params := { L[1]=3.5, L[2]=5.0, L[3]=21.5 };

The characteristic equation

 > simplify(Determinant(M)): value(%): eq := simplify(eval(%, params));

 > plot(eq, mu=0..0.4);

That graphs grows much too fast to be useful.  We moderate it by dividing through
the fastest growing cosh term:

 > plot(eq/cosh(21.5*mu), mu=0..0.4);

Here are the first three roots:

 > mu__1, mu__2, mu__3 := fsolve(eq, mu=1e-3..0.4, maxsols=3);

 > plots:-display([         plot_beam(M, mu__1, params),         plot_beam(M, mu__2, params),         plot_beam(M, mu__3, params)],         color=["red","Green","blue"],         legend=[mode1, mode2, mode3]);

 >
 >

A triple-span free-spring-spring-free beam

We have a triple-span beam with span lengths of .  The beam is supported

on two internal springy supports.  The extreme ends of the beam are free.
The numerical data is from the worksheet posted on July 29, 2020 at
https://www.mapleprimes.com/questions/230085-Elasticfoundation-Multispan-EulerBernoulli-Beamthreespan#comment271586

The problem is pretty much the same as the one in the previous section, but the

pinned supports have been replaced by spring supports.

This section's calculations require a little more precision than

Maple's default of 10 digits:

 > Digits := 15;

 > interface(rtablesize=12):
 > M := build_matrix(M_left_free, M_right_free(mu,L[3]),                         [ M_interface(mu, L[1], 'Kd'=kd/(E*I), 'Kt'=kt/(E*I)),                            M_interface(mu, L[2], 'Kd'=kd/(E*I), 'Kt'=kt/(E*I)) ]);

Calculate the determinant of .  The result is quite large, so we terminate the command
with a colon so that not to have to look at the result.  If we bothered to peek,  however, we
will see that the determinant has a factor of .  But that quite obvious by looking at the
entries of the matrix shown above. Two of its rows have  in them and another two have
. When multiplied, they produce the overall factor of .

 > DET := Determinant(M):

Here are the parameters that the determinant depends on:

 > indets(DET, name);   # the parameters that make up M

So we provide values for those parameters:

 > params := {         L[1]=3.5, L[2]=5.0, L[3]=21.5,     kd=4.881e9, kt=1.422e4,     E = 2.05e11, I = 1.1385e-7 };

Here is the characteristic equation.  We multiply it by  to remove the singularity at

 > mu^8 * value(DET): eq := eval(%, params):
 > plot(eq, mu=0..0.6);

We can't see anything useful in that graph.  Let's limit the vertical range:

 > plot(eq, mu=0..0.6, view=-1e8..1e8);

 > mu__1, mu__2, mu__3 := fsolve(eq, mu=1e-3..0.6, maxsols=3);

 > plots:-display([         plot_beam(M, mu__1, params),         plot_beam(M, mu__2, params),         plot_beam(M, mu__3, params)],         color=["red","Green","blue"],         legend=[mode1, mode2, mode3]);

 > Digits := 10;  # restore the default

 >
 >

## Solving multi-span Euler beams with the ...

Maple 2020

Maple's pdsolve() is quite capable of solving the PDE that describes the motion of a single-span Euler beam.  As far as I have been able to ascertain, there is no obvious way of applying pdsolve() to solve multi-span beams.  The worksheet attached to this post provides tools for solving multi-span Euler beams.  Shown below are a few demos.  The worksheet contains more demos.

A module for solving the Euler beam with the method of lines

beamsolve

The beamsolve proc solves a (possibly multi-span) Euler beam equation:

subject to initial and boundary conditions.  The solution  is the

transverse deflection of the beam at point  at time , subject to the load
density (i.e., load per unit length) given by . The coefficient

is the beam's mass density (mass per unit length),  is the Young's modulus of

the beam's material, and  is the beam's cross-sectional moment of inertia

about the neutral axis.  The figure below illustrates a 3-span beam (drawn in green)
supported on four supports, and loaded by a variable density load (drawn in gray)
which may vary in time.  The objective is to determine the deformed shape of the
beam as a function of time.

The number of spans, their lengths, and the nature of the supports may be specified

as arguments to beamsolve.

In this worksheet we assume that  are constants for simplicity. Since only
the product of the coefficients  and  enters the calculations, we lump the two

together into a single variable which we indicate with the two-letter symbol .

Commonly,  is referred to as the beam's rigidity.

The PDE needs to be supplied with boundary conditions, two at each end, each

condition prescribing a value (possibly time-dependent) for one of
(that's 36 possible combinations!) where I have used subscripts to indicate

derivatives.  Thus, for a single-span beam of length , the following is an admissible

set of boundary conditions:
.   (Oops, coorection, that last
condition was meant to be uxxx(L,t) = sin t.)

Additionally, the PDE needs to be supplied with initial conditions which express

the initial displacement and the initial velocity:

The PDE is solved through the Method of Lines.  Thus, each span is subdivided into

subintervals and the PDE's spatial derivatives are approximated through finite differences.

The time derivatives, however, are not discretized.  This reduces the PDE into a set of

ODEs which are solved with Maple's dsolve().

Calling sequence:

beamsolve(, options)

Parameters:

:  List of span lengths, in order from left to right, as in .

The number of subintervals in the shortest span (for the finite difference approximation)

Notes:

 • It is assumed that the spans are laid back-to-back along the  axis, with the left end of the overall beam at .
 • The interior supports, that is, those supports where any two spans meet, are assumed to be of the so-called simple type.  A simple support is immobile and it doesn't exert a bending moment on the beam.  Supports at the far left and far right of the beam can be of general type; see the BC_left and BC_right options below.
 • If the beam consists of a single span, then the argument  may be entered as a number rather than as a list. That is,  is equivalent to .

Options:

All options are of the form option_name=value, and have built-in default values.

Only options that are other than the defaults need be specified.

rho: the beam's (constant) mass density per unit length (default: rho = 1)

EI: the beam's (constant) rigidity (default: EI = 1)

T: solve the PDE over the time interval  (default: T = 1)

F: an expression in  and  that describes the applied force   (default: F = 0)
IC: the list of the initial displacement and velocity,  as
expressions in  (default: IC = [0,0])

BC_left: a list consisting of a pair of boundary conditions at the left end of
the overall (possibly multi-span beam.  These can be any two of
. The right-hand sides of these equations

can be any expression in .  The left-hand sides should be entered literally as indicated.

If a right-hand side is omitted, it is taken to be zero.   (default: BC_left =  which

corresponds to a simple support).

BC_right: like BC_left, but for the right end of the overall beam (default: BC_right =

The returned module:

A call to beamsolve returns a module which presents three methods.  The methods are:

plot (t, refine=val, options)

plots the solution  at time .  If the discretization in the  direction

is too coarse and the graph looks non-smooth, the refine option

(default: refine=1) may be specified to smooth out the graph by introducing

val number of intermediate points within each discretized subinterval.

All other options are assumed to be plot options and are passed to plots:-display.

plot3d (m=val, options)

plots the surface .  The optional  specification requests

a grid consisting of  subintervals in the time direction (default:

Note that this grid is for plotting purposes only; the solution is computed

as a continuous (not discrete) function of time. All other options are assumed

to be plot3d options and are passed to plots:-display.

animate (frames=val, refine=val, options)

produces an animation of the beam's motion.  The frames option (default = 50)

specifies the number of animation frames.  The refine option is passed to plot
(see the description above. All other options are assumed to be plot options and
are passed to plots:-display.

Note:

In specifying the boundary conditions, the following reminder can be helpful.  If the beam

is considered to be horizontal, then  is the vertical displacement,  is the slope,

is the bending moment, and  is the transverse shear force.

 >

A single-span simply-supported beam with initial velocity

The function  is an exact solution of a simply supported beam with

The solution is periodic in time with period .

 > sol := beamsolve(1, 25, 'T'=2/Pi, 'IC'=[0, Pi^2*sin(Pi*x)]): sol:-animate(size=[600,250]);

The initial condition   does not lead to a separable form, and

therefore the motion is more complex.

 > sol := beamsolve(1, 25, 'T'=2/Pi, 'IC'=[0, 1]): sol:-animate(frames=200, size=[600,250]);

 >

A single-span cantilever beam

A cantilever beam with initial condition  where  is the
first eigenmode of its free vibration (calculated in another spreadsheet).  The motion is
periodic in time, with period

 > g := 0.5*cos(1.875104069*x) - 0.5*cosh(1.875104069*x) - 0.3670477570*sin(1.875104069*x) + 0.3670477570*sinh(1.875104069*x): sol := beamsolve(1, 25, 'T'=1.787018777, 'BC_left'=[u,u_x], 'BC_right'=[u_xx,u_xxx], 'IC'=[g, 0]): sol:-animate(size=[600,250]);

If the initial condition is not an eigenmode, then the solution is rather chaotic.

 > sol := beamsolve(1, 25, 'T'=3.57, 'BC_left'=[u,u_x], 'BC_right'=[u_xx,u_xxx], 'IC'=[-x^2, 0]): sol:-animate(size=[600,250], frames=100);

 >

A single-span cantilever beam with a weight hanging from its free end

 > sol := beamsolve(1, 25, 'T'=3.57, 'BC_left'=[u,u_x], 'BC_right'=[u_xx,u_xxx=1]): sol:-animate(size=[600,250], frames=100);

 >

A single-span cantilever beam with oscillating support

 > sol := beamsolve(1, 25, 'T'=Pi, 'BC_left'=[u=0.1*sin(10*t),u_x], 'BC_right'=[u_xx,u_xxx]): sol:-animate(size=[600,250], frames=100);

 >

A dual-span simply-supported beam with moving load

Load moves across a dual-span beam.

The beam continues oscillating after the load leaves.

 > d := 0.4:  T := 4:  nframes := 100: myload := - max(0, -6*(x - t)*(d + x - t)/d^3): sol := beamsolve([1,1], 20, 'T'=T, 'F'=myload): sol:-animate(frames=nframes): plots:-animate(plot, [2e-3*myload(x,t), x=0..2, thickness=1, filled=[color="Green"]], t=0..T, frames=nframes): plots:-display([%%,%], size=[600,250]);

 >

A triple-span simply-supported beam with moving load

Load moves across a triple-span beam.

The beam continues oscillating after the load leaves.

 > d := 0.4:  T := 6: nframes := 100: myload := - max(0, -6*(x - t)*(d + x - t)/d^3): sol := beamsolve([1,1,1], 20, 'T'=T, 'F'=myload): sol:-plot3d(m=50); sol:-animate(frames=nframes): plots:-animate(plot, [2e-3*myload(x,t), x=0..3, thickness=1, filled=[color="Green"]], t=0..T, frames=nframes): plots:-display([%%,%], size=[600,250]);
 > z3d;

 >

A triple-span beam, moving load falling off the cantilever end

In this demo the load move across a multi-span beam with a cantilever section at the right.

As it skips past the cantilever end, the beam snaps back violently.

 > d := 0.4:  T := 8: nframes := 200: myload := - max(0, -6*(x - t/2)*(d + x - t/2)/d^3): sol := beamsolve([1,1,1/2], 10, 'T'=T, 'F'=myload, BC_right=[u_xx, u_xxx]): sol:-animate(frames=nframes): plots:-animate(plot, [1e-2*myload(x,t), x=0..3, thickness=1, filled=[color="Green"]], t=0..T, frames=nframes): plots:-display([%%,%], size=[600,250]);

 >