Here's a solution that does return a Vector. Note that this is a procedure that returns a procedure, which was one of the stated requirements of the exercise. Neither this code nor Kitonum's returns a partition that is uniformly selected at random from the set of partitions. However, this code seems to correspond to the OP's intentions.

Partition:= proc(n::posint)
local Partition:= Vector[row](n);
     proc()
     local i, Integer, Sum:= 0;
          for i while Sum < n do
               Integer:= RandomTools:-Generate(integer(range= 1..n-Sum));
               Partition[i]:= Integer;
               Sum:= Sum+Integer
          end do;
          sort(Partition[1..i-1])
     end proc
end proc:

P:= Partition(5):
'P()' $ 20;

I think that the professor may have intended for a procedure that returned an iterator, i.e., a procedure that cycles through a canonical list of partitions---something akin to combinat:-nextpart. Here's a trivial example of a procedure that returns an iterator procedure:

Partition:= proc(n::posint)
local Partition:= [n];
     proc()   Partition:= `if`(Partition=[n], [1$n], combinat:-nextpart(Partition))  end proc
end proc:

P:= Partition(5):
'P()' $ 20;

[1, 1, 1, 1, 1], [1, 1, 1, 2], [1, 2, 2], [1, 1, 3], [2, 3], [1, 4], [5], [1, 1, 1, 1, 1], [1, 1, 1, 2], [1, 2, 2], [1, 1, 3], [2, 3], [1, 4], [5], [1, 1, 1, 1, 1], [1, 1, 1, 2], [1, 2, 2], [1, 1, 3], [2, 3], [1, 4]

What is the file extension (such as .txt, .m, .mpl, .map, .dat) of the file that you are trying to open? If the extension is something other than .mw or .mws, then it's not really a Maple "document" and probably cannot be opened by Maple by simply clicking on the file. If the extension is .m, .mpl, or, .map, then you need to start Maple by clicking on its own icon. Then open a new worksheet, and use the read command by directly typing

read "filename";

At the point where you are entering this command, you are already "inside" the Maple "package"; there is no need for a with command to get further "inside" or to "load" something. You can start typing your math, such as equations. At some point, you may need to load a package, such as plots. At that point, you would use the command with(plots).

When the prompt appears, type control-T. This removes the prompt and puts you in text mode.

Change seq(X[i],Y[i],Z[i],i=0..1000) to seq([X[i],Y[i],Z[i]], i= 0..1000).

This seems to be an oversight with the newer inert forms (the ones formed by prepending % to the function name). You can still use the older form of the inert limit, Limit. Likewise, Diff, Int, Eval---each spelled with a capital letter---are inert forms of diff, int, eval.

If you want to correct this bug, it is trivial to do so. Simply define a procedure:

`print/%limit`:= ()-> Limit(args);

The command is interface(worksheetdir).

You use the command sign in your for loop. You need to change that to either signum or csgn (which one doesn't matter in this case). The command sign in Maple is something completely different and unrelated. This is a very common error in Maple. If you make the change, you'll get the answer

     sol1 := {y0 = 57.69046866}

from fsolve. See ?signum, ?csgn, and ?sign.

Yes, you convert those equations which contain integrals to differential equations by taking the derivatives with respect to t of each side. You are correct that that makes the initial conditions disappear. They are supplied separately to the dsolve command. So equation A becomes

diff(u[smooth](t), t) = - i[smooth](t)/C[smooth]

and likewise for equation C.

You made two errors: First, you must consistently refer to functions of t as functions of t. So i[komp] in equation B and i[load] in equation D need (t) appended. Second, you have u[loadt] in equation D where you intended (I presume) u[load].

The command to solve this DAE IVP system is dsolve. The specific command is

dsolve(
     {igl, u[smooth](0)=US0, u[ckomp](0) = UC0},
     {u[smooth](t), i[smooth](t), i[komp](t), i[load](t), u[ckomp](t), u[load](t)}
);

Note that I represented the initial conditions as US0 and UC0. This system can be solved symbolically by dsolve, but the solution is much too long to copy here. It's in the attached worksheet:

igl.mw

If you're writing purely numeric Maple code in double precision, it is possible to have that code automatically translated to C, compiled, and linked to your Maple. To the user, it seems just like running an ordinary Maple procedure. See ?Compiler,Compile. It is often possible to run such code in parallel using the Threads package, thereby utilizing 100% of your processor.

If you post some of your code, I may be able to quickly show you how it's done.

That error message is so weak and unhelpful that it's pathetic. What, it can't even detect that you mispelled an option name? You just need to change numerical to numeric.

About your second error, you need to change your decimal constants to exact fractions. You can do that like this:

pdsolve({convert(Selkov[1], rational), convert(Selkov[2], rational)});

I don't know if the above command will ever return an answer---I got tired of waiting---but it won't give you the "general case of floats" error.

The 3/8 rule can be derived in three steps with Maple. We take four arbitrary points with evenly spaced x-coordinates and find the interpolating polynomial. Then integrate that and simplify the result. Like this:

CurveFitting:-PolynomialInterpolation([four x-values], [four y-values], x, form= Newton);
int(%, x= ...);
factor(%);

I leave it to you to fill in the four x-values, the four y-values, and the interval of integration. The results of the first two commands will be surprisingly long and complicated. Let Maple worry about that and don't be discouraged. As you can see, the result of the third command is exactly what you're looking for.

I'm assuming that you have a one-dimensional set of data (a set of real numbers). Then simply compute the mean mu and standard deviation sigma of the data. Then the best fit is Normal(mu, sigma). For the mean, use Statistics:-Mean, and for the standard deviation, use Statistics:-StandardDeviation.

If you have a two-dimensional set of data (a set of pairs of real numbers), let me know.

This will handle most cases, including negative, fractional, decimal, and symbolic exponents and expressions that don't contain the variable.

power:= (E::algebraic, t::name)-> simplify(t*diff(expand(ln(E)),t)):

Example of use:

power(0.5*t^5*r^(-1)*V, t);

     5

Stylistically it's better to define a procedure that takes an expression and a variable rather than one that just takes an expression. It'll give you much more flexibility later on.

Any function can be made inert by prepending a % to the name. The inert function can be converted its non-inert form by value. This is exactly analogous to Int being the inert form of int. 

Any function foo(...) can be made to prettyprint as something else by defining a procedure `print/foo`. This only affects the way that expressions containing the function prettyprint; it doesn't affect the lprint of those expressions, nor does it change their values.

Putting these two ideas together leads, in my opinion, to a more-elegant solution to your problem:

Download Inert_pi.mw

I didn't need to use %pi and pi to do the above; it would've worked had I used %foo and foo. Thus we don't have to rely on the fact that Pi has another expression, pi, that ordinarily prints the same---a fact that is somewhat idiosyncratic to Pi.

By the way, the reason that subs gave you an error message is that r was an expression sequence, not a list. So it looked to subs as if you were passing it four arguments, which would only be valid if the first three were equations. I find expression sequences dangerous to work with and almost always convert them to lists.