The case of a parsing error can be handled by doing the parse before calling dsolve. And you could put that in a try...catch and deal with it as you prefer.

When there is no previous parsing error, there's no hard set of rules that will always allow you to distinguish subsequently between cases like your 1.) and 2.), for arbitrary commands. It varies from command to command.

You can often make some distinctions of case 3) versus the other two, according to lastexception[1] which you have not utilized yet. It will often denote which named procedure emitted the error. So you could programmatically test -- or otherwise distinguish -- between the case that dsolve threw the error or some other procedure did. For example, simply printing it:

Download lastexception1.mw

ps. Please don't delete your question once someone's responded and you've resolved your difficulty, as like last week on stackexchange.

The situation you're describing involves what's called a optional positional parameter.

You should use the quote-protected global name as the default value, to avoid problems such as when the global name is already assigned a value.

Eg,

restart;

sim := proc( x, n,
             o::identical(exactly,maximum,minimum) := ':-exactly' )
          return o;
       end proc:

sim();
                            exactly

exactly := 4:

sim();
                            exactly

That also helps avoid undesirable side-effects even if exactly were an unevaluated function call. (Such situations do occur.) Defensive programming is a good habit -- and I'll advocate it even if I don't always follow my own advice.

Your expectation is not valid.

Perhaps you meant to query   max(abs(Q))  ?

Download suuual_ac.mw 

One way that the error message "bad index into Array" can occur is where Maple tries to access the Array using a non-numeric index.

A typical example would be where Maple tries to access, say, Y[i] where the name i does not yet have an integer value. Eg,

restart;
Y := Array(1..10, i->i):

Y[i];
Error, bad index into Array

The seq command has special evaluation rules, which prevents Y[i] from being evaluated until i gets actual values. So this works.

restart;
Y := Array(1..10, i->i):

seq(Y[i], i=1..10);
               1, 2, 3, 4, 5, 6, 7, 8, 9, 10

But the sum command does not have special evaluation rules. The following produces the same error as does the first example above,

restart;
Y := Array(1..10, i->i):

sum(Y[i], i=1..10);
Error, bad index into Array

What just happened was that Maple tried to evaluate the first argument passed to the sum call before i got any value, which is Maple's usual evaluation rules for procedure calls. But, for what you are trying to accomplish, the Array reference Y[i] was evaluated prematurely.

Here are two alternative ways to do summation involving Array elements:

1) Use the add command instead of the sum command, since the add command also has special evaluation rules.

restart;
Y := Array(1..10, i->i):
add(Y[i], i=1..10);
                           55

2) Delay the indexed Array reference using unevaluation quotes (single right-quotes).

restart;
Y := Array(1..10, i->i):
sum('Y[i]', i=1..10);
                           55

Now, I am guessing that this kind of premature evaluation of an indexed Array reference is your problem, mostly based on your use of the words, "summation index" and the particular error message you cited. If I've guess wrongly then please provide the full example.

I'll note that at least one other Answer seems to be indicating that you've accessed Array entries using invalid numeric values for the index. I suspect that is not your problem, however, mostly because the error message for that situation is different than your Question's title.

restart;
Y := Array(1..10, i->i):

seq(Y[i+1]-Y[i], i=1..10);
Error, Array index out of range

seq(Y[i+1]-Y[i], i=0..9);
Error, Array index out of range

On MS-Windows and Linux you can use the keyboard short-cuts Ctl-r to temporarily switch from text mode to 2D Input mode, and Ctl-t to switch back.

On Mac OS X I believe that it's similar, Cmd-r and Cmd-t .

See the help-pages for more.

In general the solve command does not return all solutions for transcendental equations, while also not returning a warning about solutions being lost. This has some mention on the help-page for topic solve,details .

What that page fails to say is that, when the number of solutions can be determined by Maple as being bound by additional, supplied inequalities, the use of the explicit option as well as the allsolutions option can (sometimes, if it can be worked out by Maple) get an explicit full answer or additional solutions.

Sorry, I only have access to back to Maple 16.02 today, and not Maple 15 which seems to be indicated on your Question.

Download solvert.mw

If you are just trying to get the right-hand sides of the equations in L,

map(rhs, L);
                             {b, f}

If you are trying to use L as a lookup key for a and e,

L := {a = b, e = f};
                      L := {a = b, e = f}

eval({a, e}, L);
                             {b, f}

eval([a, e], L);
                             [b, f]

eval(a, L);
                               b

eval(e, L);
                               f

Perhaps you are looking for a syncronized side-by-side Array of animations.

With the Table borders toggled off (via right-click Table->Properties), and with scaling=constrained, you could get it like so:

animarray.mw

The correct syntax would be Eigenvectors(A) instead of Eigenvectors[A] as you had it. But that seems to take too long.

Download eigs.mw

Since the answer you expected has just F on the left-hand side then it is understandable that people give you answers about isolating or solving for F.

But another way to interpret your question involves cancellation of common factors in the left- and right-hand sides. For your given example that just happens to provide the same result as isolating for F.

But it's not a silly question. The simplify command will not "cancel" such common factors.

I don't promise that the following will work for all kinds of equations. But here's your example as well as another slightly more complicated one.

restart;

fact := (expr::equation) -> frontend(gcd,[numer(lhs(expr)),numer(rhs(expr))])/
                            frontend(gcd,[denom(lhs(expr)),denom(rhs(expr))]):

eq1 := F*R=(1/2*M*R^2)*(a/R);

                                       M R a
                          eq1 := F R = -----
                                         2

eq1/fact(eq1);

                                    M a
                                F = ---
                                     2

eq2 := (F+G)*R/sqrt(W-1)=(1/2*M*R^2)*(a/(R*sqrt(W-1)));

                          (F + G) R       M R a
                   eq2 := ---------- = ------------
                                 1/2            1/2
                          (W - 1)      2 (W - 1)

eq2/fact(eq2);

                                      M a
                              F + G = ---
                                       2

After some simplification the modified expression can become real-valued (eg. for positive omega). fsolve can be used for this example.

ps. Are you using Maple 2016.0, and if so have you considered upgrading to 2016.2?

Download fs.mw

Using Maple 2015.2,

restart;
ee := simplify(expand(exp(-(2*m-4)*exp(t)+t*(m+1))*(t-2*exp(t)))):
f2 := subs(foo=ee,m->evalf(Int(unapply(foo,t),0..infinity))):
plot(f2, 3..20);

or,

restart;
ee := simplify(expand(exp(-(2*m-4)*exp(t)+t*(m+1))*(t-2*exp(t)))):
f2 := subs(foo=ee,m->evalf(Int(foo,t=0..infinity,method=_d01amc))):
plot(f2, 3..20);

Why are you trying for output=Array(...)? And why with so few points? (With more points you could get a much smoother piecewise spline as an interpolation.)

Download fd2x_bvp.mw

This question has come up several times before, and you can find several old posts about it by entering the word colorbar in the Mapleprimes search.

One can manually edit the properties of the GUI Table inserted by plots:-display (to remove borders), and re-size it by dragging the borders. But such edits are lost upon re-execution.

Another possibility is to use the DocumentTools:-Tabulate command. Here is a variant on Adri's pointplot3d example.

tabulate_colorbar.mw

Unfortunately the worksheet renderer of this site is unable to inline the worksheet so that it's properly visible here.

For example here is an old post where I used Tabulate to align a 3d surface and a 2d densityplot for the colorbar. It's also possible to orient the colorbar horizontally, and locate it below/above the 3d plot. Using a 2d densityplot has the advantage that it can be constructed using the size option. However using a 2d densityplot can get tricky since one end of the hue rolls back to red. This may not match that of the 3d plot created with shading=zhue, with hue ending around magenta. So in that post I used,
    color=[f,1,1,colortype=HSV]
instead of
   shading=zhue
for the 3d surface plot.

Using the main menubar you can toggle off the item View -> Status Bar . That removes the status bar, in which the button appears (along with everything else in that bar). This aspect of the GUI's "View" is saved as a preference when the GUI is fully closed.

But I'm unaware of any way only to disable that "editable" button.