Advanced Search

vv

13560 Reputation

20 Badges

9 years, 212 days
Contact vv

MaplePrimes Activity


These are answers submitted by vv

Directly...

vv 13560
April 13 2025
2 0

odetest cannot work with such generalized series. But it is easy to test the solution directly: 

fsol:=series(rhs(maple_sol), x=0):
# series(eval(lhs(ode), y(x)=fsol), x);  # O(x^5)
map(series, map(eval, ode, y(x)=fsol), x)

          O(x^5) = 0

Numerical solution...

vv 13560
April 06 2025
3 3
> 

restart;
> 

X,Y := t->5*cos(t), t->(5+sin(6*t))*sin(t):
> 

with(plots):
> 

P0:=plot([X,Y, 0..2*Pi], color=black):
> 

T:=D(Y)/D(X): # the sloap of the tangent
> 

K:=unapply(VectorCalculus:-Curvature(<X(t),Y(t)>),t):
> 

tt[1],tt[2] := eval( [a,b], fsolve({T(a)-T(b), K(a)-K(b)}, {a, b}, {a=0..1, b=3..5}) )[];

.5465721754, 4.440166423

 (1)
> 

tt[3],tt[4] := eval( [a,b], fsolve({T(a)-T(b), K(a)-K(b)}, {a, b}, {a=2..2.5, b=3..6}) )[];

2.168601832, 3.704639334

 (2)
> 

tt[5],tt[6] := eval( [a,b], fsolve({T(a)-T(b), K(a)-K(b)}, {a, b}, {a=2.5..3, b=3..6}) )[];

2.845163972, 5.737842021

 (3)
> 

col:=[red$2,blue$2,green$2]:
> 

curvatures=seq(K(tt[i]),i=1..6)

curvatures = (1.391345054, 1.391345047, 1.111111250, 1.111111261, 0.3791851261e-1, 0.3791851136e-1)

 (4)
> 

display(P0,
        seq( pointplot([[X(tt[i]),Y(tt[i])]], color=col[i]), i=1..6),
        seq( plot(T(tt[i])*(x-X(tt[i])) + Y(tt[i]), x=-40..40, color=col[i]), i=1..6),
        symbolsize=24, symbol=solidcircle, scaling=unconstrained, view=[-7..7,-7..7],gridlines=false
);

 
> 

 


 

Download equal-sloap-curvature-vv.mw

Solution...

vv 13560
April 05 2025
4 3

The correct syntax for rsolve is:

> 

sol := rsolve({f(n)=sin(f(n-1)), f(0)=a}, f(n));

(sin@@n)(a)

 (1)

Unfortunately Maple cannot compute the following "classical" limit directly:

 

> 

limit(sol*sqrt(n/3), n=infinity) assuming a>0,a<Pi;

limit((1/3)*(sin@@n)(a)*3^(1/2)*n^(1/2), n = infinity)

 (2)

However, it can more than this: it is able to compute the asymptotic expansion!

 

> 

asympt('rsolve'({f(0) = a, f(n) = sin(f(n - 1))}, f(n)), n);

3^(1/2)*(1/n)^(1/2)+(_C-(3/10)*3^(1/2)*ln(n))*(1/n)^(3/2)+O((1/n)^(5/2))

 (3)

So, the limit is 1.

Note however that this is a generic result; for its validity we must add a condition e.g. 0<a, a<Pi.

Simple solution...

vv 13560
April 03 2025
0 1

Using the identity theorem, a very simple solution is possible:

u := sin(2*x)/(cosh(2*y) - cos(2*x)):
f:=eval(u, [y=0,x=z]) + I*C : # C = real constant
simplify(convert(f, cot));

        C*I + cot(z)

Answer...

vv 13560
March 09 2025
5 3
The idea is to expand in power series and then change the order of summation. After that, the limit will be simple.
> 

restart;
> 

f := k*t^k/(1-t^k); # without (1-t)^2

k*t^k/(1-t^k)

 (1)
> 

f := convert(eval(f, t^k=u), FPS, u) assuming k::posint

Sum(k*u^(n+1), n = 0 .. infinity)

 (2)
> 

f := (eval(%, u=t^k)) assuming k>0,t>0

Sum(k*(t^k)^(n+1), n = 0 .. infinity)

 (3)
> 

term := op(1,%)

k*(t^k)^(n+1)

 (4)
> 

F := Sum(sum((1-t)^2*term, k=1..infinity),n=0..infinity) assuming t>0,t<1;

Sum((t-1)^2*t^(n+1)/(t^(n+1)-1)^2, n = 0 .. infinity)

 (5)
> 

limit(F, t=1,left)

Sum(1/(n+1)^2, n = 0 .. infinity)

 (6)
> 

ans = value(%);

ans = (1/6)*Pi^2

 (7)
 

 

Download lim_ser-vv.mw

identify...

vv 13560
March 06 2025
2 1

Maple can guess the result:

s:=sum( arctan(2/n^2), n=1 .. infinity);
ans:=identify(evalf(s));
evalf[200](s - ans);  # check 200 digits, --> 0

                  

PS. Why don't you express the series in Maple, i.e.  sum( arctan(2/n^2), n=1 .. infinity) ?

PS2. Of course this is not a proof.  It is easy to obtain one in Maple, but only if the user knows it mathematically.
I omit it because you probably know it.

Stoltz...

vv 13560
March 04 2025
1 0

Maple cannot compute it, but it's easy with Stoltz-Cesaro theorem:

a:=n -> 2^n/n:
limit(a(n) / (a(n)-a(n-1)), n=infinity);

                    2

By hand with Maple...

vv 13560
February 26 2025
3 1
> 

J:=Int(ln(x)*ln(1 - x), x = 0 .. 1);

Int(ln(x)*ln(1-x), x = 0 .. 1)

 (1)
> 

F2:=convert(ln(1-x), FPS);

Sum(-x^(n+1)/(n+1), n = 0 .. infinity)

 (2)
> 

J1:=Int(ln(x)*op(1,F2), x=0..1);

Int(-ln(x)*x^(n+1)/(n+1), x = 0 .. 1)

 (3)
> 

value(%) assuming n>=0; # by parts

1/((n+1)*(n+2)^2)

 (4)
> 

V1:=convert(%, parfrac);

-1/(n+2)+1/(n+1)-1/(n+2)^2

 (5)
> 

J = sum(V1, n=0..infinity);  # Easy to justify by dominated convergence

Int(ln(x)*ln(1-x), x = 0 .. 1) = 2-(1/6)*Pi^2

 (6)


Download INT1-vv.mw

worksheetdir...

vv 13560
February 23 2025
2 1

Try  (*.mw, not *.mpl):

interface(worksheetdir);

 

A simple "by hand" solution...

vv 13560
February 22 2025
1 3

 1/(1 - x*y) = Sum( (x*y)^k, k=0 .. infinity );
Applying the double integral over (0,1)^2 implies (by monotone convergence):
 Int( 1/(1 - x*y), x=0..1, y=0..1 ) = Sum( 1/k^2, k =1 .. infinity );
==>  Int( 1/(1 - x*y), x=0..1, y=0..1 ) = Pi^2 / 6.

Modular...

vv 13560
February 17 2025
1 1

You have to use LinearAlgebra[Modular]:

restart
A:=Matrix(9,[
0,0,0,-1,1,-1,-1,0,0,
0,-1,0,1,-1,1,0,-1,-1,
0,0,-1,0,0,0,1,1,0,
0,1,0,-1,-1,1,-1,-1,0,
0,0,0,0,0,-1,1,0,-1,
0,0,0,0,0,-1,0,1,1,
0,0,1,-1,1,1,-1,-1,0,
0,0,0,0,0,1,1,-1,0,
0,0,0,0,0,0,0,0,0], datatype=integer[8]):
with(LinearAlgebra[Modular]):
Rank(3,A);
#                               7
B := Copy(3,A):
RowReduce(3,B,9,9,9,'det',0,'rank',0,0,true): B;

            

 

Edit. To obtain a basis for the nullspace explicitly, it is better to use:

with(LinearAlgebra[Modular]):
A1 := Copy(3,A):
r:=MatBasis(3, A1, 9, true): r,A1;
colonbasis, nullspacebasis:= A1[1..r, ..], A1[r+1.., ..];
colonbasis . nullspacebasis^+  mod 3; # check (==> 0 matrix)

Z...

vv 13560
February 02 2025
1 0

OK, I'll take Z(t) = exp(int(y(u),u=0..t))

restart
eq1 := diff(x(t), t)-(1/6)*(6*x(t)^3*y(t)+(2*y(t)^2-2)*x(t)^2+3*y(t)*(z(t)-2)*x(t)-2*y(t)^2+2)*sqrt(3) = 0;
eq2 := diff(y(t), t)-(1/6)*(y(t)-1)*sqrt(3)*(y(t)+1)*(6*x(t)^2+2*y(t)*x(t)+3*z(t)-2) = 0;
eq3 := diff(z(t), t)-(1/3)*z(t)*sqrt(3)*(6*y(t)*x(t)^2+2*x(t)*y(t)^2+3*z(t)*y(t)-2*x(t)-3*y(t)) = 0;
eq4 := diff(s(t), t)-(1/3)*(y(t)-1)*sqrt(3)*(y(t)+1)*(6*x(t)^2+2*y(t)*x(t)+3*z(t)-2)*y(t) = 0;
eq5 := diff(Q(t), t)+sqrt(3)*((4/3-z(t)-2*x(t)^2)*y(t)+(2/3*(1-y(t)^2))*x(t))*Q(t)+2*((2/3)*y(t)+x(t))*P(t)/sqrt(3)-(2/3)*R(t) = 0;   
eq6 := diff(P(t), t)+(sqrt(3)*(1-z(t)-2*x(t)^2)*y(t)+2*(2-y(t)^2)*x(t)/sqrt(3))*P(t)+2*sqrt(3)*x(t)*Q(t)+(1/2)*R(t) = 0;       
eq7 := diff(R(t), t)-sqrt(3)*((3*x(t)^2+(3/2)*z(t)+4)*y(t)-(1/3*(1-3*y(t)^2))*x(t))*R(t)-z(t)*P(t) = 0;
eq8 := diff(T(t), t)-sqrt(3)*((6*x(t)^2+3*z(t)+1)*y(t)-(2*(1-y(t)^2))*x(t))*T(t)-(1-y(t)^2)*(Q(t)-(2/3)*P(t)) = 0;   

eq9 := diff(Z(t), t) = Z(t)*y(t);
syst := eq1, eq2, eq3, eq4, eq5, eq6, eq7, eq8, eq9;
ics := x(0) = .1, y(0) = .9, z(0) = .1, s(0) = .2, Q(0) = .1, P(0) = .9, R(0) = .1, T(0) = .2,  Z(0)=1;
sol1 := dsolve({ics, syst}, {P(t), Q(t), R(t), T(t), s(t), x(t), y(t), z(t), Z(t)}, type = numeric, output = operator);
sol1(0.5);
plots:-odeplot(sol1, [[t, y(t)], [t,Z(t)]], t=0..1, title="y and Z");
plots:-odeplot(sol1, [Z(t), y(t)], t=0..1, title="y vs Z");

      

A "by hand" solution...

vv 13560
January 30 2025
1 0

Take the origin at A. Then the area a(t) of the triangle ABC is the absolute value of the determinant of <B,C>, so a(t) = |m t + n|.

We have a(0) = 2, a(5) = 3, a(10) = ?.
a(0)=2 implies n=±2, and a(5)=3 implies 5m+n=±3 so, a(10) = |10m+n| = |-n±6| = |n±6| ∈ {4,8}.

Solution...

vv 13560
January 30 2025
2 7 
restart;
A := t->[a,sA+vA*t]: B := t->[b,sB+vB*t]: C := t->[c,sC+vC*t]:
area:= t->abs(LinearAlgebra:-Determinant(Matrix([[A(t)[],1],[B(t)[],1],[C(t)[],1]])))/2:
sols := solve([area(0)=2, area(5)=3, area(10)=AREA]):
AREA in {seq}( eval(AREA, sol), sol=sols);

                AREA  ∈  {4, 8}

(so, 2 solutions, AREA=4 and AREA=8).
Nice problem BTW.

CharacteristicPolynomial...

vv 13560
January 29 2025
2 3 
p:=unapply(LinearAlgebra:-CharacteristicPolynomial(A,x), x):
[seq]( simplify(p(evstheory[i])), i=1 .. L^2); nops(%);

        [0, 0, ... , 0]
        81

but very SLOW!

1 2 3 4 5 6 7 Last Page 1 of 118